window脚本批处理BAT文件大型攻略

BAT 批处理脚本 教程

第一章 批处理基础
第一节 经常使用批处理内部命令简介

批处理定义顾名思义批处理文件是将一系列命令按必定的顺序集合为一个可执行的文本文件其扩展名为BAT或者CMD。这些命令统称批处理命令。
小知识能够在键盘上按下Ctrl+C组合键来强行终止一个批处理的执行过程。
了解了大概意思后,咱们正式开始学习.先看一个简单的例子!
@echo off
echo "欢迎来到很是BAT!"
pause
把上面的3条命令保存为文件test.bat或者test.cmd而后执行,
他就会在屏幕上显示如下二行话:
欢迎来到很是BAT!
请按任意键继续. . .
这就是一个简单批处理文件了这个批处理文件一共就用了2条命令 "echo" 和"pause" 还有一个特殊符号"@"
从上面这个简单的批处理中,咱们能够发现其实批处理就是运用一些含有特殊意义的符号和一些完成指定功能的命令组合而成,那么在批处理中有多少这样的特殊符号和功能命令呢咱们如今就来仔细了解一下一些最经常使用的!
(如下内容来源网络,请各位仔细阅读,好进入下节的实例说明)
======================================================
批处理的常见命令未列举的命令还比较多请查阅帮助信息
     一、REM 和 ::
     二、ECHO 和 @
     三、PAUSE
     四、ERRORLEVEL
     五、TITLE
     六、COLOR
     七、mode 配置系统设备
     八、GOTO 和 :
     九、FIND
     十、START
     十一、assoc 和 ftype
     十二、pushd 和 popd
     1三、CALL
     1四、shift
     1五、IF
     1六、setlocal 与 变量延迟
     1七、ATTRIB  显示或更改文件属性

介绍命令
一、REM 和 ::
REM为注释命令通常用来给程序加上注解该命令后的内容不被执行但能回显。
其次, :: 也能够起到rem 的注释做用, 并且更简洁有效; 但有两点须要注意
第一, 任何以冒号:开头的字符行, 在批处理中都被视做标号, 而直接忽略其后的全部内容。
有效标号冒号后紧跟一个以字母数字开头的字符串goto语句能够识别。
无效标号冒号后紧跟一个非字母数字的一个特殊符号goto没法识别的标号能够起到注释做用因此 :: 常被用做注释符号其实 :+ 也可起注释做用。
第二, 与rem 不一样的是, ::后的字符行在执行时不会回显, 不管是否用echo on打开命令行回显状态, 由于命令解释器不认为他是一个有效的命令行, 就此点来看, rem 在某些场合下将比 :: 更为适用; 另外, rem 能够用于 config.sys 文件中。

行内注释格式%注释内容%  不经常使用慎用


二、ECHO 和 @
@字符放在命令前将关闭该命令回显不管此时echo是否为打开状态。
echo命令的做用列举以下
1打开回显或关闭回显功能
    格式:echo [{ on|off }]
    若是想关闭“ECHO OFF”命令行自身的显示则须要在该命令行前加上“@”。
2显示当前ECHO设置状态
    格式:echo
3输出提示信息 
    格式ECHO 信息内容
    上述是ECHO命令常见的三种用法也是你们熟悉和会用的但做为DOS命令淘金者你还应该知道下面的技巧
4关闭DOS命令提示符 
    在DOS提示符状态下键入ECHO OFF可以关闭DOS提示符的显示使屏幕只留下光标直至键入ECHO ON提示符才会从新出现。
5输出空行即至关于输入一个回车 
    格式ECHO
    值得注意的是命令行中的“”要紧跟在ECHO后面中间不能有空格不然“”将被看成提示信息输出到屏幕。另外“”能够用”[\]等任一符号替代。
    命令ECHO输出的回车经DOS管道转向能够做为其它命令的输入好比echo.|time即至关于在TIME命令执行后给出一个回车。因此执行时系统会在显示当前时间后自动返回到DOS提示符状态
6答复命令中的提问 
    格式ECHO 答复语|命令文件名
上述格式能够用于简化一些须要人机对话的命令如CHKDSKFFORMAT Drive:del *.*的操做它是经过DOS管道命令把ECHO命令输出的预置答复语做为人机对话命令的输入。下面的例子就至关于在调用的命令出现人机对话时输入“Y”回车
C:>ECHO Y|CHKDSK/F
C:>ECHO Y|DEL A :*.*
7创建新文件或增长文件内容 
格式ECHO 文件内容>文件名
      ECHO 文件内容>>文件名
例如
C:>ECHO @ECHO OFF>AUTOEXEC.BAT创建自动批处理文件
C:>ECHO C:\CPAV\BOOTSAFE>>AUTOEXEC.BAT向自动批处理文件中追加内容
C:>TYPE AUTOEXEC.BAT显示该自动批处理文件
@ECHO OFF
C:\CPAV\BOOTSAFE
8向打印机输出打印内容或打印控制码 
格式ECHO 打印机控制码>;PRN
      ECHO 打印内容>;PRN
下面的例子是向M1724打印机输入打印控制码。Alt156是按住Alt键在小键盘键入156相似状况依此类推
C:>ECHO +156+42+116>;PRN输入下划线命令FSt
C:>ECHO [email=+155@]+155@>;PRN[/email]输入初始化命令ESC@
C:>ECHO.>;PRN换行
9使喇叭鸣响 
C:>ECHO ^G
“^G”是在dos窗口中用CtrlG或Alt007输入输入多个^G能够产生多声鸣响。使用方法是直接将其加入批处理文件中或作成批处理文件调用。
这里的“^G”属于特殊符号的使用请看本文后面的章节


三、PAUSE
PAUSE玩游戏的人都知道暂停的意思
在这里就是中止系统命令的执行并显示下面的内容。
例
PAUSE
运行显示
请按任意键继续. . .
要显示其余提示语能够这样用
Echo 其余提示语 & pause > nul


四、errorlevel
程序返回码
echo %errorlevel%
每一个命令运行结束能够用这个命令行格式查看返回码
用于判断刚才的命令是否执行成功
默认值为0通常命令执行出错会设 errorlevel 为1


五、title
设置cmd窗口的标题
title 新标题        #能够看到cmd窗口的标题栏变了


六、COLOR
设置默认的控制台前景和背景颜色。
COLOR [attr]
  attr        指定控制台输出的颜色属性
颜色属性由两个十六进制数字指定 -- 第一个为背景第二个则为
前景。每一个数字能够为如下任何值之一:
    0 = 黑色       8 = 灰色
    1 = 蓝色       9 = 淡蓝色
    2 = 绿色       A = 淡绿色
    3 = 湖蓝色     B = 淡浅绿色
    4 = 红色       C = 淡红色
    5 = 紫色       D = 淡紫色
    6 = ***       E = 淡***
    7 = 白色       F = 亮白色
若是没有给定任何参数该命令会将颜色还原到 CMD.EXE 启动时
的颜色。这个值来自当前控制台窗口、/T 开关或
DefaultColor 注册表值。
若是用相同的前景和背景颜色来执行 COLOR 命令COLOR 命令
会将 ERRORLEVEL 设置为 1。
例如: "COLOR fc" 在亮白色上产生亮红色


七、mode 配置系统设备
配置系统设备。
串行口:　　　     MODE COMm[:] [BAUD=b] [PARITY=p] [DATA=d] [STOP=s]
                                [to=on|off] [xon=on|off] [odsr=on|off]
                                [octs=on|off] [dtr=on|off|hs]
                                [rts=on|off|hs|tg] [idsr=on|off]
设备状态:             MODE [device] [/STATUS]
打印重定向:　　 MODE LPTn[:]=COMm[:]
选定代码页:　　 MODE CON[:] CP SELECT=yyy
代码页状态:　　 MODE CON[:] CP [/STATUS]
显示模式:　　     MODE CON[:] [COLS=c] [LINES=n]
击键率:　             MODE CON[:] [RATE=r DELAY=d]
例
mode con cols=113 lines=15 & color 9f
此命令设置DOS窗口大小15行113列


八、GOTO 和 :
GOTO会点编程的朋友就会知道这是跳转的意思。
在批处理中容许以“:XXX”来构建一个标号而后用GOTO XXX跳转到标号:XXX处而后执行标号后的命令。
例
if {%1}=={} goto noparms
if "%2"=="" goto noparms
标签的名字能够随便起可是最好是有意义的字符串啦前加个冒号用来表示这个字符串是标签goto命令就是根据这个冒号:来寻找下一步跳到到那里。最好有一些说明这样你别人看起来才会理解你的意图啊。

例
@echo off
:start
set /a var+=1
echo %var%
if %var% leq 3 GOTO start
pause
运行显示
1
2
3
4
十、start 命令
批处理中调用外部程序的命令该外部程序在新窗口中运行批处理程序继续往下执行不理会外部程序的运行情况若是直接运行外部程序则必须等外部程序完成后才继续执行剩下的指令
例start explorer d:\
调用图形界面打开D盘


十一、assoc 和 ftype
文件关联
assoc 设置'文件扩展名'关联关联到'文件类型'
ftype 设置'文件类型'关联关联到'执行程序和参数'
当你双击一个.txt文件时windows并非根据.txt直接判断用 notepad.exe 打开
而是先判断.txt属于 txtfile '文件类型'
再调用 txtfile 关联的命令行 txtfile=%SystemRoot%\system32\NOTEPAD.EXE %1
能够在"文件夹选项"→"文件类型"里修改这2种关联
assoc           #显示全部'文件扩展名'关联
assoc .txt      #显示.txt表明的'文件类型'结果显示 .txt=txtfile
assoc .doc      #显示.doc表明的'文件类型'结果显示 .doc=Word.Document.8
assoc .exe      #显示.exe表明的'文件类型'结果显示 .exe=exefile
ftype           #显示全部'文件类型'关联
ftype exefile   #显示exefile类型关联的命令行结果显示 exefile="%1" %* 
assoc .txt=Word.Document.8
设置.txt为word类型的文档能够看到.txt文件的图标都变了
assoc .txt=txtfile
恢复.txt的正确关联

ftype exefile="%1" %*
恢复 exefile 的正确关联
若是该关联已经被破坏能够运行 command.com 再输入这条命令


十二、pushd 和 popd
切换当前目录
@echo off
c: & cd\ & md mp3       #在 C:\ 创建 mp3 文件夹
md d:\mp4               #在 D:\ 创建 mp4 文件夹
cd /d d:\mp4            #更改当前目录为 d:\mp4
pushd c:\mp3            #保存当前目录并切换当前目录为 c:\mp3
popd                    #恢复当前目录为刚才保存的 d:\mp4
通常用处不大在当前目录名不肯定时会有点帮助。dos编程中颇有用


1三、CALL
CALL命令能够在批处理执行过程当中调用另外一个批处理当另外一个批处理执行完后再继续执行原来的批处理
CALL command
调用一条批处理命令和直接执行命令效果同样特殊状况下颇有用好比变量的多级嵌套见教程后面。在批处理编程中能够根据必定条件生成命令字符串用call能够执行该字符串见例子。
CALL [drive:][path]filename [batch-parameters]
调用的其它批处理程序。filename 参数必须具备 .bat 或 .cmd 扩展名。
CALL :label arguments
调用本文件内命令段至关于子程序。被调用的命令段以标签:label开头
以命令goto :eof结尾。
另外批脚本文本参数参照(%0、%一、等等)已以下改变:
     批脚本里的 %* 指出全部的参数(如 %1 %2 %3 %4 %5 ...)
     批参数(%n)的替代已被加强。您可使用如下语法:看不明白的直接运行后面的例子
         %~1         - 删除引号(")扩充 %1
         %~f1        - 将 %1 扩充到一个彻底合格的路径名
         %~d1        - 仅将 %1 扩充到一个驱动器号
         %~p1        - 仅将 %1 扩充到一个路径
         %~n1        - 仅将 %1 扩充到一个文件名
         %~x1        - 仅将 %1 扩充到一个文件扩展名
         %~s1        - 扩充的路径指含有短名
         %~a1        - 将 %1 扩充到文件属性
         %~t1        - 将 %1 扩充到文件的日期/时间
         %~z1        - 将 %1 扩充到文件的大小
         %~$PATH : 1 - 查找列在 PATH 环境变量的目录并将 %1
                       扩充到找到的第一个彻底合格的名称。若是环境
                       变量名未被定义或者没有找到文件此组合键会
                       扩充到空字符串
    能够组合修定符来取得多重结果:
        %~dp1       - 只将 %1 扩展到驱动器号和路径
        %~nx1       - 只将 %1 扩展到文件名和扩展名
        %~dp$PATH:1 - 在列在 PATH 环境变量中的目录里查找 %1
                       并扩展到找到的第一个文件的驱动器号和路径。
        %~ftza1     - 将 %1 扩展到相似 DIR 的输出行。
    在上面的例子中%1 和 PATH 能够被其余有效数值替换。
%~ 语法被一个有效参数号码终止。%~ 修定符不能跟 %*使用
注意参数扩充时不理会参数所表明的文件是否真实存在均以当前目录进行扩展
要理解上面的知识下面的例子很关键。
例
@echo off
Echo 产生一个临时文件 > tmp.txt
Rem 下行先保存当前目录再将c:\windows设为当前目录
pushd c:\windows
Call :sub tmp.txt
Rem 下行恢复前次的当前目录
Popd
Call :sub tmp.txt
pause
Del tmp.txt
exit
:sub
Echo 删除引号 %~1
Echo 扩充到路径 %~f1
Echo 扩充到一个驱动器号 %~d1
Echo 扩充到一个路径 %~p1 
Echo 扩充到一个文件名 %~n1
Echo 扩充到一个文件扩展名 %~x1
Echo 扩充的路径指含有短名 %~s1 
Echo 扩充到文件属性 %~a1 
Echo 扩充到文件的日期/时间 %~t1 
Echo 扩充到文件的大小 %~z1 
Echo 扩展到驱动器号和路径%~dp1
Echo 扩展到文件名和扩展名%~nx1
Echo 扩展到相似 DIR 的输出行%~ftza1
Echo.
Goto :eof
例
set aa=123456
set cmdstr=echo %aa%
call %cmdstr%
pause
本例中若是不用call而直接运行%cmdstr%将显示结果%aa%而不是123456

1四、shift
更改批处理文件中可替换参数的位置。
SHIFT [/n]
若是命令扩展名被启用SHIFT 命令支持/n 命令行开关该命令行开关告诉
命令从第 n 个参数开始移位n 介于零和八之间。例如:
    SHIFT /2
会将 %3 移位到 %2将 %4 移位到 %3等等而且不影响 %0 和 %1。
1五、IF
IF 条件判断语句语法格式以下
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
下面逐一介绍更详细的分析请看后面章节。

(1) IF [NOT] ERRORLEVEL number command
IF ERRORLEVEL这个句子必须放在某一个命令的后面执行命令后由IF ERRORLEVEL 来判断命令的返回值。
Number的数字取值范围0~255判断时值的排列顺序应该由大到小。返回的值大于等于指定的值时条件成立
例
@echo off
dir c:
rem退出代码为>=1就跳至标题1处执行>=0就跳至标题0处执行
IF ERRORLEVEL 1 goto 1
IF ERRORLEVEL 0 goto 0
Rem 上面的两行不可交换位置不然失败了也显示成功。
:0
echo 命令执行成功
Rem 程序执行完毕跳至标题exit处退出
goto exit
:1
echo 命令执行失败
Rem 程序执行完毕跳至标题exit处退出
goto exit
:exit
pause
运行显示命令执行成功
(2) IF [NOT] string1==string2 command
string1和string2都为字符的数据英文内字符的大小写将看做不一样这个条件中的等于号必须是两个绝对相等的意思
条件相等后即执行后面的command
检测当前变量的值作出判断为了防止字符串中含有空格可用如下格式
if [NOT] {string1}=={string2} command
if [NOT] [string1]==[string2] command
if [NOT] "string1"=="string2" command
这种写法实际上将括号或引号当成字符串的一部分了只要等号左右两边一致就好了好比下面的写法就不行
if {string1}==[string2] command

(3) IF [NOT] EXIST filename command
EXIST filename为文件或目录存在的意思
echo off
IF EXIST autoexec.bat echo 文件存在
IF not EXIST autoexec.bat echo 文件不存在
这个批处理你们能够放在C盘和D盘分别执行看看效果



1六、setlocal 与 变量延迟
本条内容引用[英雄出品]的批处理教程
要想进阶变量延迟是必过的一关因此这一部分但愿你能认真看。
为了更好的说明问题咱们先引入一个例子。
例1:
@echo off
set a=4
set a=5 & echo %a%
pause
结果4
解说为何是4而不是5呢在echo以前明明已经把变量a的值改为5了
让咱们先了解一下批处理运行命令的机制
批处理读取命令时是按行读取的另外例如for命令等其后用一对圆括号闭合的全部语句也看成一行在处理以前要完成必要的预处理工做这其中就包括对该行命令中的变量赋值。咱们如今分析一下例1批处理在运行到这句“set a=5 & echo %a%”以前先把这一句整句读取并作了预处理——对变量a赋了值那么%a%固然就是4了没有为何批处理就是这样作的。
而为了可以感知环境变量的动态变化批处理设计了变量延迟。简单来讲在读取了一条完整的语句以后不当即对该行的变量赋值而会在某个单条语句执行以前再进行赋值也就是说“延迟”了对变量的赋值。
那么如何开启变量延迟呢变量延迟又须要注意什么呢举个例子说明一下
例2:
@echo off
setlocal enabledelayedexpansion
set a=4
set a=5 & echo !a!
pause 
结果5
解说启动了变量延迟获得了正确答案。变量延迟的启动语句是“setlocal enabledelayedexpansion”而且变量要用一对叹号“!!”括起来注意要用英文的叹号不然就没有变量延迟的效果。
分析一下例2首先“setlocal enabledelayedexpansion”开启变量延迟而后“set a=4”先给变量a赋值为
4“set a=5 & echo !a!”这句是给变量a赋值为5并输出因为启动了变量延迟因此批处理可以感知到动态变化即不是先给该行变量赋值而是在运行过程当中给变量赋值所以此时a的值就是5了。
再举一个例子巩固一下。
例3:
@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do (
set a=%%i
echo !a!
)
pause
结果
1
2
3
4
5
解说本例开启了变量延迟并用“!!”将变量扩起来所以获得咱们预期的结果。若是不用变量延迟会出现什
么结果呢结果是这样的
ECHO 处于关闭状态。
ECHO 处于关闭状态。
ECHO 处于关闭状态。
ECHO 处于关闭状态。
ECHO 处于关闭状态。
即没有感知到for语句中的动态变化。
提示在没有开启变量延迟的状况下某条命令行中的变量改变必须到下一条命令才能体现。这一点也能够加以利用看例子。
例交换两个变量的值且不用中间变量
@echo off
::目的交换两个变量的值可是不使用临时变量
::Code by JM 2007-1-24 [email=CMD@XP]CMD@XP[/email]
::出处http://www.cn-dos.net/forum/viewthread.php?tid=27078
set var1=abc
set var2=123
echo 交换前 var1=%var1% var2=%var2%
set var1=%var2%& set var2=%var1%
echo 交换后 var1=%var1% var2=%var2%
pause

1七、ATTRIB  显示或更改文件属性
ATTRIB [+R|-R] [+A|-A] [+S|-S] [+H|-H] [[drive:] [path] filename] [/S [/D]]
  +   设置属性。
  -    清除属性。
  R   只读文件属性。
  A   存档文件属性。
  S   系统文件属性。
  H   隐藏文件属性。
  [drive:][path][filename]
      指定要处理的文件属性。
  /S  处理当前文件夹及其子文件夹中的匹配文件。
  /D  也处理文件夹。

例
md autorun
attrib +a +s +h autorun
上面的命令将创建文件夹autorun而后将其设为存档、系统、隐藏属性
第二节 经常使用特殊符号
    一、@  命令行回显屏蔽符
    二、%  批处理变量引导符
    三、>   重定向符
    四、>>  重定向符
    五、<、>&、<& 重定向符
    六、|  命令管道符
    七、^  转义字符
    八、&  组合命令
    九、&& 组合命令
    十、||  组合命令
    十一、""  字符串界定符
    十二、, 逗号
    1三、; 分号
    1四、() 括号
    1五、! 感叹号
    1六、批处理中可能会见到的其它特殊标记符: 略
        CR(0D) 命令行结束符 
        Escape(1B) ANSI转义字符引导符 
        Space(20) 经常使用的参数界定符 
        Tab(09) ; = 不经常使用的参数界定符 
        + COPY命令文件链接符 
        * ? 文件通配符 
        / 参数开关引导符 
        : 批处理标签引导符 

废话少说开讲了
一、@  命令行回显屏蔽符
这个字符在批处理中的意思是关闭当前行的回显。咱们从前几课知道
ECHO OFF能够关闭掉整个批处理命令的回显但不能关掉ECHO OFF这个命令如今咱们在ECHO OFF这个命令前加个@就能够达到全部命令均不回显的要求

二、%  批处理变量引导符
这个百分号严格来讲是算不上命令的它只是批处理中的参数而已多个%一块儿使用的状况除外之后还将详细介绍。
引用变量用%var%调用程序外部参数用%1至%9等等
%0  %1  %2  %3  %4  %5  %6  %7  %8  %9  %*为命令行传递给批处理的参数
%0 批处理文件自己包括完整的路径和扩展名
%1 第一个参数
%9 第九个参数
%* 从第一个参数开始的全部参数
参数%0具备特殊的功能能够调用批处理自身以达到批处理自己循环的目的也能够复制文件自身等等。
例最简单的复制文件自身的方法
copy %0 d:\wind.bat
小技巧添加行内注释
%注释内容%能够用做行内注释不能出现重定向符号和管道符号
为何这样呢此时“注释内容”其实被看成变量其值是空的故只起注释做用不过这种用法容易出现语法错误通常不用。

三、>   重定向符
输出重定向命令
这个字符的意思是传递而且覆盖他所起的做用是将运行的结果传递到后面的范围后边能够是文件也能够是默认的系统控制台
    在NT系列命令行中重定向的做用范围由整个命令行转变为单个命令语句受到了命令分隔符&,&&,||和语句块的制约限制。
好比
使用命令echo hello >1.txt将创建文件1.txt内容为”hello “注意行尾有一空格
使用命令echo hello>1.txt将创建文件1.txt内容为”hello“注意行尾没有空格

四、>>  重定向符
输出重定向命令
这个符号的做用和>有点相似但他们的区别是>>是传递并在文件的末尾追加而>是覆盖
用法同上
一样拿1.txt作例子
使用命令
echo hello > 1.txt
echo world >>1.txt
这时候1.txt 内容以下:
hello
world

五、<、>&、<& 重定向符
这三个命令也是管道命令但它们通常不经常使用你只须要知道一下就ok了固然若是想仔细研究的话能够本身查一下资料。(本人已查过网上也查不到相关资料)
<输入重定向命令从文件中读入命令输入而不是从键盘中读入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
这样就能够不等待输入直接修改当前日期
>&将一个句柄的输出写入到另外一个句柄的输入中。
<&恰好和>&相反从一个句柄读取输入并将其写入到另外一个句柄输出中。
经常使用句柄0、一、2未定义句柄3—9
1>nul 表示禁止输出正确的信息
2>nul 表示禁止输出错误信息。
其中的1与2都是表明某个数据流输入输出的地址NT CMD 称之为句柄MSDOS称之为设备。
句柄0标准输入stdin键盘输入
句柄1标准输出stdout输出到命令提示符窗口console代码为CON
句柄2标准错误stderr输出到命令提示符窗口console代码为CON
其中的stdin可被<重定向stdout可被>、>>重定向。
咱们已经知道读取文本中的内容能够用for命令但若是只须要读取第一行用for命令就有点麻烦。简单的办法以下:
@echo off
set /p str=<%0
echo %str%
pause
运行显示批处理文件自身的第一行@echo off

六、|  命令管道符
格式第一条命令 | 第二条命令 [| 第三条命令...]
将第一条命令的结果做为第二条命令的参数来使用记得在unix中这种方式很常见。
例如
dir c:\|find "txt"
以上命令是查找C\全部并发现TXT字符串。
FIND的功能请用 FIND /? 自行查看
在不使format的自动格式化参数时我是这样来自动格式化A盘的
echo y|format a: /s /q /v:system
用过format的都知道再格盘时要输入y来确认是否格盘这个命令前加上echo y并用|字符来将echo y的结果传给format命令
从而达到自动输入y的目的
这条命令有危害性测试时请慎重


七、^  转义字符
^是对特殊符号<,>,&的前导字符在命令中他将以上3个符号的特殊功能去掉仅仅只把他们当成符号而不使用他们的特殊意义。
好比
echo test ^>1.txt
结果则是test > 1.txt
他没有追加在1.txt里呵呵。只是显示了出来
另外此转义字符还能够用做续行符号。
举个简单的例子
@echo off
echo 英雄^
是^
好^
男人
pause
不用多说本身试一下就明白了。
为何转义字符放在行尾能够起到续行符的做用呢缘由很简单由于每行末尾还有一个看不见的符号即回车符转义字符位于行尾时就让回车符失效了从而起到了续行的做用。


八、&  组合命令
语法第一条命令 & 第二条命令 [& 第三条命令...]
&、&&、||为组合命令顾名思义就是能够把多个命令组合起来当一个命令来执行。这在批处理脚本里是容许的并且用的很是普遍。由于批处理认行不认命令数目。
这个符号容许在一行中使用2个以上不一样的命令当第一个命令执行失败了也不影响后边的命令执行。
这里&两边的命令是顺序执行的从前日后执行。
好比
dir z:\ & dir y:\ & dir c:\
以上命令会连续显示z,y,c盘的内容不理会该盘是否存在


九、&& 组合命令
语法第一条命令 && 第二条命令 [&& 第三条命令...]
用这种方法能够同时执行多条命令当碰到执行出错的命令后将不执行后面的命令若是一直没有出错则一直执行完全部命令
这个命令和上边的相似但区别是第一个命令失败时后边的命令也不会执行
dir z:\ && dir y:\ && dir c:\


十、||  组合命令
语法第一条命令 || 第二条命令 [|| 第三条命令...]
用这种方法能够同时执行多条命令当一条命令失败后才执行第二条命令当碰到执行正确的命令后将不执行后面的命令若是没有出现正确的命令则一直执行完全部命令

提示组合命令和重定向命令一块儿使用必须注意优先级
管道命令的优先级高于重定向命令重定向命令的优先级高于组合命令
问题把C盘和D盘的文件和文件夹列出到a.txt文件中。看例
dir c:\ && dir d:\ > a.txt
这样执行后a.txt里只有D盘的信息为何由于组合命令的优先级没有重定向命令的优先级高因此这句在执行时将本行分红这两部分dir c:\和dir d:\ > a.txt而并非如你想的这两部分dir c:\ && dir d:\和> a.txt。要使用组合命令&&达到题目的要求必须得这么写
dir c:\ > a.txt && dir d:\ >> a.txt
这样依据优先级高低DOS将把这句话分红如下两部分dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的几句的差异比较特殊值得好好研究体会一下。
固然这里还能够利用&命令本身想一下道理哦
dir c:\ > a.txt & dir d:\ >> a.txt
[这个也能够用 dir c:\;d:\ >>a.txt 来实现]

十一、""  字符串界定符
双引号容许在字符串中包含空格进入一个特殊目录能够用以下方法
cd "program files"
cd progra~1
cd pro*
以上三种方法均可以进入program files这个目录


十二、, 逗号
逗号至关于空格在某些状况下“,”能够用来当作空格使
好比
dir,c:\

1三、; 分号
分号当命令相同时能够将不一样目标用来隔离但执行效果不变如执行过程当中发生错误则只返回错误报告但程序仍会执行。有人说不会继续执行其实测试一下就知道了
好比
dir c:\;d:\;e:\;z:\
以上命令至关于
dir c:\
dir d:\
dir e:\
dir f:\
若是其中z盘不存在运行显示系统找不到指定的路径。而后终止命令的执行。
例dir c:\;d:\;e:\1.txt
以上命令至关于
dir c:\
dir d:\
dir e:\1.txt
其中文件e:\1.txt不存在但e盘存在有错误提示但命令仍会执行。

为何若是目标路径不存在则终止执行若是路径存在仅文件不存在则继续执行。
就说这些了!各位有什么意见请回贴!有什么疑问请到BAT交流区发贴!下一节改进!


1四、() 括号
小括号在批处理编程中有特殊的做用左右括号必须成对使用括号中能够包括多行命令这些命令将被当作一个总体视为一条命令行。
    括号在for语句和if语句中常见用来嵌套使用循环或条件语句其实括号()也能够单独使用请看例子。
例
命令echo 1 & echo 2 & echo 3
能够写成
(
echo 1
echo 2
echo 3
)
上面两种写法效果同样这两种写法都被视为是一条命令行。
注意这种多条命令被视为一条命令行时若是其中有变量就涉及到变量延迟的问题。


1五、! 感叹号
没啥说的在变量延迟问题中用来表示变量即%var%应该表示为!var!请看前面的setlocal命令介绍。

第二章 DOS循环for命令详解

讲FOR以前呢,咋先告诉各位新手朋友,若是你有什么命令不懂,直接在CMD下面输入:
name /? 这样的格式来看系统给出的帮助文件,好比for /? 就会把FOR命令的帮助所有显示出来!固然许多菜鸟都看不懂....因此才会有那么多批处理文章!!!!俺也照顾菜鸟,把FOR命令用我本身的方式说明下!
正式开始:

1、基本格式
FOR %%variable IN (set) DO command [command-parameters]
  %%variable  指定一个单一字母表示可替换的参数。
  (set)      指定一个或一组文件。可使用通配符。
  command    指定对每一个文件执行的命令。
  command-parameters
             为特定命令指定参数或命令行开关。



参数:FOR有4个参数 /d   /l   /r   /f   他们的做用我在下面用例子解释
如今开始讲每一个参数的意思

2、参数 /d
FOR /D %%variable IN (set) DO command [command-parameters]
    若是集中包含通配符则指定与目录名匹配而不与文件
    名匹配。
若是 Set (也就是我上面写的 "相关文件或命令") 包含通配符* 和 ?将对与 Set 相匹配的每一个目录而不是指定目录中的文件组执行指定的 Command。
这个参数主要用于目录搜索,不会搜索文件,看这样的例子
@echo off
for /d %%i in (c:\*) do echo %%i
pause
运行会把C盘根目录下的所有目录名字打印出来,而文件名字一个也不显示!
在来一个,好比咱们要把当前路径下文件夹的名字只有1-3个字母的打出来
@echo off
for /d %%i in (???) do echo %%i
pause
这样的话若是你当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了
这里解释下*号和?号的做用,*号表示任意N个字符,而?号只表示任意一个字符
知道做用了,给你们个思考题目!
@echo off
for /d %%i in (window?) do echo %%i
pause
保存到C盘下执行,会显示什么呢?本身看吧! 显示windows
/D参数只能显示当前目录下的目录名字,这个你们要注意!


3、参数 /R
FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
    检查以 [drive:]path 为根的目录树指向每一个目录中的
    FOR 语句。若是在 /R 后没有指定目录则使用当前
目录。若是集仅为一个单点(.)字符则枚举该目录树。

递归
上面咱们知道,/D只能显示当前路径下的目录名字,那么如今这个/R也是和目录有关,他能干吗呢?放心他比/D强大多了!
他能够把当前或者你指定路径下的文件名字所有读取,注意是文件名字,有什么用看例子!
请注意2点
    一、set中的文件名若是含有通配符(或*)则列举/R参数指定的目录及其下面的所用子目录中与set相符合的全部文件无相符文件的目录则不列举。
    二、相反若是set中为具体文件名不含通配符则枚举该目录树即列举该目录及其下面的全部子目录而无论set中的指定文件是否存在。这与前面所说的单点.枚举目录树是一个道理单点表明当前目录也可视为一个文件。
例
@echo off
for /r c:\ %%i in (*.exe) do echo %%i
pause
我们把这个BAT保存到D盘随便哪里而后执行,我会就会看到,他把C盘根目录,和每一个目录的子目录下面所有的EXE文件都列出来了!!!!
例
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
参数不同了吧!这个命令前面没加那个C:\也就是搜索路径,这样他就会以当前目录为搜索路径,好比你这个BAT你把他放在d:\test目录下执行,那么他就会把D:\test目录和他下面的子目录的所有EXE文件列出来!!!
例
@echo off
for /r c:\ %%i in (boot.ini) do echo %%i
pause
运行本例发现枚举了c盘全部目录为了只列举boot.ini存在的目录可改为下面这样
@echo off
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i
pause
用这条命令搜索文件真不错。。。。。。
这个参数你们应该理解了吧!仍是满好玩的命令!


4、参数 /L
FOR /L %%variable IN (start,step,end) DO command [command-parameters]
    该集表示以增量形式从开始到结束的一个数字序列。
    所以(1,1,5) 将产生序列 1 2 3 4 5(5,-1,1) 将产生
    序列 (5 4 3 2 1)。
使用迭代变量设置起始值 (Start#)而后逐步执行一组范围的值直到该值超过所设置的终止值 (End#)。/L 将经过对 Start# 与 End# 进行比较来执行迭代变量。若是 Start# 小于 End#就会执行该命令。若是迭代变量超过 End#则命令解释程序退出此循环。还可使用负的 Step# 以递减数值的方式逐步执行此范围内的值。例如(1,1,5) 生成序列 1 2 3 4 5而 (5,-1,1) 则生成序列 (5 4 3 2 1)。语法是
看着这说明有点晕吧!我们看例子就不晕了!
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存执行看效果,他会打印从1 2 3 4 5  这样5个数字
(1,1,5)这个参数也就是表示从1开始每次加1直到5终止!
等会晕,就打印个数字有P用...好的知足你们,看这个例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
执行后是否是吓了一跳,怎么多了5个CMD窗口,呵呵!若是把那个 (1,1,5)改为 (1,1,65535)会有什么结果,我先告诉你们,会打开65535个CMD窗口....这么多你不死机算你强!
固然咱们也能够把那个start cmd改为md %%i 这样就会创建指定个目录了!!!名字为1-65535
看完这个被我赋予破坏性质的参数后,咱们来看最后一个参数
5、参数 /F
\迭代及文件解析
使用文件解析来处理命令输出、字符串及文件内容。使用迭代变量定义要检查的内容或字符串并使用各类options选项进一步修改解析方式。使用options令牌选项指定哪些令牌应该做为迭代变量传递。请注意在没有使用令牌选项时/F 将只检查第一个令牌。
文件解析过程包括读取输出、字符串或文件内容将其分红独立的文本行以及再将每行解析成零个或更多个令牌。而后经过设置为令牌的迭代变量值调用 for 循环。默认状况下/F 传递每一个文件每一行的第一个空白分隔符号。跳过空行。

详细的帮助格式为
FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]
    带引号的字符串"options"包括一个或多个
    指定不一样解析选项的关键字。这些关键字为:
        eol=c           - 指一个行注释字符的结尾(就一个)
        skip=n          - 指在文件开始时忽略的行数。
        delims=xxx      - 指分隔符集。这个替换了空格和跳格键的
                          默认分隔符集。
        tokens=x,y,m-n  - 指每行的哪个符号被传递到每一个迭代
                          的 for 自己。这会致使额外变量名称的分配。m-n
                          格式为一个范围。经过 nth 符号指定 mth。若是
                          符号字符串中的最后一个字符星号
                          那么额外的变量将在最后一个符号解析以后
                          分配并接受行的保留文本。经测试该参数最多
                          只能区分31个字段。
        usebackq        - 使用后引号键盘上数字1左面的那个键`。
                        未使用参数usebackq时file-set表示文件但不能含有空格
                            双引号表示字符串即"string"
                            单引号表示执行命令即'command'
                          使用参数usebackq时file-set和"file-set"都表示文件
                          当文件路径或名称中有空格时就能够用双引号括起来
                            单引号表示字符串即'string'
                            后引号表示命令执行即`command`

以上是用for /?命令得到的帮助信息直接复制过来的。
晕惨了!我这就举个例子帮助你们来理解这些参数!

For命令例1****************************************
@echo off
rem 首先创建临时文件test.txt
echo ;注释行,这是临时文件,用完删除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt
运行显示结果
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
请按任意键继续. . .
为何会这样?我来解释
eol=;          分号开头的行为注释行
tokens=1,3*    将每行第1段,第3段和剩余字段分别赋予变量%%i%%j%%k
delims=,-     减号后有一空格以逗号减号和空格为分隔符空格必须放在最后

For命令例2****************************************
@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause
运行将显示test.txt所有内容包括注释行不解释了哈。

For命令例3****************************************
另外/F参数还能够以输出命令的结果看这个例子
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
这样你本机所有账号名字就出来了把扩号内的内容用两个单引号引发来就表示那个当命令执行,FOR会返回命令的每行结果,加那个"delims=" 是为了让我空格的行能整行显示出来,不加就只显示空格左边一列!

基本上讲完了FOR的基本用法了...若是你看过FOR的系统帮助,你会发现他下面还有一些特定义的变量,这些我先不讲.你们因该都累了吧!你不累我累啊....
所谓文武之道一张一弛现休息一下。






第三章 FOR命令中的变量
FOR命令中有一些变量,他们的用法许多新手朋友还不太了解,今天给你们讲解他们的用法!

先把FOR的变量所有列出来:
     ~I          - 删除任何引号(")扩展 %I
     %~fI        - 将 %I 扩展到一个彻底合格的路径名
     %~dI        - 仅将 %I 扩展到一个驱动器号
     %~pI        - 仅将 %I 扩展到一个路径
     %~nI        - 仅将 %I 扩展到一个文件名
     %~xI        - 仅将 %I 扩展到一个文件扩展名
     %~sI        - 扩展的路径只含有短名
     %~aI        - 将 %I 扩展到文件的文件属性
     %~tI        - 将 %I 扩展到文件的日期/时间
     %~zI        - 将 %I 扩展到文件的大小
     %~$PATH:I   - 查找列在路径环境变量的目录并将 %I 扩展
                   到找到的第一个彻底合格的名称。若是环境变量名
                   未被定义或者没有找到文件此组合键会扩展到
                   空字符串

咱们能够看到每行都有一个大写字母"I",这个I其实就是咱们在FOR带入的变量,咱们FOR语句代入的变量名是什么,这里就写什么.
好比:FOR /F  %%z IN ('set') DO @echo %%z
这里咱们代入的变量名是z那么咱们就要把那个I改为z,例如%~fI改成%~fz
至于前面的%~p这样的内容就是语法了!

好开始讲解:

1、 ~I          - 删除任何引号(")扩展 %I
这个变量的做用就如他的说明,删除引号!
咱们来看这个例子:
首先创建临时文件temp.txt内容以下
"1111
"2222"
3333"
"4444"44
"55"55"55
可创建个BAT文件代码以下:
@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt
rem 上面创建临时文件注意不成对的引号要加转义字符^重定向符号前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo  %%~i
pause
del temp.txt
执行后,咱们看CMD的回显以下:
1111           #字符串前的引号被删除了
2222           #字符串首尾的引号都被删除了
3333"          #字符串前无引号后面的引号保留
4444"44        #字符串前面的引号删除了而中间的引号保留
55"55"55       #字符串前面的引号删除了而中间的引号保留
请按任意键继续. . .
和以前temp.txt中的内容对比一下,咱们会发现第一、二、5行的引号都消失了,这就是删除引号~i的做用了!
删除引号规则以下(BAT兄补充!)
一、若字符串首尾同时存在引号则删除首尾的引号
二、若字符串尾不存在引号则删除字符串首的引号
三、若是字符串中间存在引号或者只在尾部存在引号则不删除。
龙卷风补充无头不删有头连尾删。


2、 %~fI        - 将 %I 扩展到一个彻底合格的路径名
看例子:
把代码保存放在随便哪一个地方,我这里就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~fi
pause
执行后显示内容以下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
当我把代码中的 %%~fi直接改为%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%i
pause
执行后就会显示如下内容
test.bat
test.vbs
经过对比,咱们很容易就看出没有路径了,这就是"将 %I 扩展到一个彻底合格的路径名"的做用
也就是若是%i变量的内容是一个文件名的话,他就会把这个文件所在的绝对路径打印出来,而不仅单单打印一个文件名,本身动手动实验下就知道了!


3、 %~dI        - 仅将 %I 扩展到一个驱动器号
看例子:
代码以下,我仍是放到桌面执行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~di
pause
执行后我CMD里显示以下
C:
C:
我桌面就两个文件test.bat,test.vbs,%%~di做用是,若是变量%%i的内容是一个文件或者目录名,他就会把他这文件
或者目录所在的盘符号打印出来!


4、 %~pI        - 仅将 %I 扩展到一个路径
这个用法和上面同样,他只打印路径不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~pi
pause
我就不打结果了,你们本身复制代码看结果吧,下面几个都是这么个用法,代码给出来,你们本身看结果吧!


5、 %~nI        - 仅将 %I 扩展到一个文件名
只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ni
pause


6、 %~xI        - 仅将 %I 扩展到一个文件扩展名
只打印文件的扩展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~xi
pause


7、 %~sI        - 扩展的路径只含有短名
打印绝对短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~si
pause


8、 %~aI        - 将 %I 扩展到文件的文件属性
打印文件的属性
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ai
pause


9、 %~tI        - 将 %I 扩展到文件的日期/时间
打印文件创建的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ti
pause

10、 %~zI        - 将 %I 扩展到文件的大小
打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~zi
pause
上面例子中的"delims=="能够改成"delims="即不要分隔符


11、 %~$PATH:I - 查找列在路径环境变量的目录并将 %I 扩展
                   到找到的第一个彻底合格的名称。若是环境变量名
                   未被定义或者没有找到文件此组合键会扩展到
                   空字符串
这是最后一个,和上面那些都不同,我单独说说!

而后在把这些代码保存为批处理,放在桌面。
@echo off
FOR /F "delims=" %%i IN (“notepad.exe”) DO echo  %%~$PATH:i
pause
龙卷风补充上面代码显示结果为C:\WINDOWS\system32\notepad.exe
他的意思就在PATH变量里指定的路径里搜索notepad.exe文件若是有notepad.exe则会把他所在绝对路径打印出来没有就打印一个错误

好了,FOR的的变量就介绍到这了!
                                 
第四章 批处理中的变量
批处理中的变量,我把他分为两类,分别为"系统变量"和"自定义变量"
咱们如今来详解这两个变量!

1、系统变量
他们的值由系统将其根据事先定义的条件自动赋值,也就是这些变量系统已经给他们定义了值,
不须要咱们来给他赋值,咱们只须要调用而以!  我把他们所有列出来!

%ALLUSERSPROFILE% 本地 返回“全部用户”配置文件的位置。
%APPDATA% 本地 返回默认状况下应用程序存储数据的位置。
%CD% 本地 返回当前目录字符串。
%CMDCMDLINE% 本地 返回用来启动当前的 Cmd.exe 的准确命令行。
%CMDEXTVERSION% 系统 返回当前的“命令处理程序扩展”的版本号。
%COMPUTERNAME%  系统 返回计算机的名称。
%COMSPEC%  系统 返回命令行解释器可执行程序的准确路径。
%DATE%  系统 返回当前日期。使用与 date /t 命令相同的格式。由 Cmd.exe 生成。有关
date 命令的详细信息请参阅 Date。
%ERRORLEVEL%  系统 返回上一条命令的错误代码。一般用非零值表示错误。
%HOMEDRIVE%  系统 返回链接到用户主目录的本地工做站驱动器号。基于主目录值而设置。用
户主目录是在“本地用户和组”中指定的。
%HOMEPATH%  系统 返回用户主目录的完整路径。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。
%HOMESHARE%  系统 返回用户的共享主目录的网络路径。基于主目录值而设置。用户主目录是
在“本地用户和组”中指定的。
%LOGONSERVER%  本地 返回验证当前登陆会话的域控制器的名称。
%NUMBER_OF_PROCESSORS%  系统 指定安装在计算机上的处理器的数目。
%OS%  系统 返回操做系统名称。Windows 2000 显示其操做系统为 Windows_NT。
%PATH% 系统 指定可执行文件的搜索路径。
%PATHEXT% 系统 返回操做系统认为可执行的文件扩展名的列表。
%PROCESSOR_ARCHITECTURE%  系统 返回处理器的芯片体系结构。值x86 或 IA64 基于
Itanium
%PROCESSOR_IDENTFIER% 系统 返回处理器说明。
%PROCESSOR_LEVEL%  系统 返回计算机上安装的处理器的型号。
%PROCESSOR_REVISION% 系统 返回处理器的版本号。
%PROMPT% 本地 返回当前解释程序的命令提示符设置。由 Cmd.exe 生成。
%RANDOM% 系统 返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。
%SYSTEMDRIVE% 系统 返回包含 Windows server operating system 根目录即系统根目录
的驱动器。
%SYSTEMROOT%  系统 返回 Windows server operating system 根目录的位置。
%TEMP% 和 %TMP% 系统和用户 返回对当前登陆用户可用的应用程序所使用的默认临时目录。
有些应用程序须要 TEMP而其余应用程序则须要 TMP。
%TIME% 系统 返回当前时间。使用与 time /t 命令相同的格式。由 Cmd.exe 生成。有关
time 命令的详细信息请参阅 Time。
%USERDOMAIN% 本地 返回包含用户账户的域的名称。
%USERNAME% 本地 返回当前登陆的用户的名称。
%USERPROFILE% 本地 返回当前用户的配置文件的位置。
%WINDIR% 系统 返回操做系统目录的位置。

这么多系统变量,咱们如何知道他的值是什么呢?
在CMD里输入  echo %WINDIR%
这样就能显示一个变量的值了!
举个实际例子,好比咱们要复制文件到当前账号的启动目录里就能够这样
copy d:\1.bat "%USERPROFILE%\「开始」菜单\程序\启动\"
%USERNAME% 本地 返回当前登陆的用户的名称。  注意有空格的目录要用引号引发来

另外还有一些系统变量,他们是表明一个意思,或者一个操做!
他们分别是%0 %1 %2 %3 %4 %5 ......一直到%9 还有一个%*
%0 这个有点特殊,有几层意思,先讲%1-%9的意思.
%1 返回批处理的第一个参数
%2 返回批处理的第二个参数
%3-%9依此推类
反回批处理参数?到底怎么个返回法?
咱们看这个例子,把下面的代码保存为test.BAT而后放到C盘下
@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4
进入CMD,输入cd c:\
而后输入 test.bat 我是第一个参数 我是第二个参数  我是第三个参数  我是第四个参数
注意中间的空格,咱们会看到这样的结果:
我是第一个参数 我是第二个参数 我是第三个参数 我是第四个参数
我是第一个参数
我是第二个参数
我是第三个参数
我是第四个参数
对比下代码,%1就是”我是第一个参数”  %2就是”我是第二个参数”
怎么样理解了吧!

这些%1和%9可让批处理也能带参数运行,大大提升批处理功能!

还有一个%*  他是什么呢?他的做用不是很大,只是返回参数而已,不过他是一次返回所有参数的值,不用在输入%1 %2来肯定一个个的

例子
@echo off
echo %*
一样保存为test.bat 放到C盘
进入CMD,输入cd c:\
而后输入 test.bat 我是第一个参数 我是第二个参数  我是第三个参数  我是第四个参数
能够看到他一次把所有参数都显示出来了

好如今开始讲那个比较特殊的%0

%0  这个不是返回参数的值了,他有两层意思!
第一层意思:返回批处理所在绝对路径
例子:
@echo off
echo %0
pause
保存为test.BAT放在桌面运行,会显示以下结果
"C:\Documents and Settings\Administrator\桌面\test.bat"
他把当前批处理执行的所在路经打印出来了,这就是返回批处理所在绝对路径的意思
第二层意思:无限循环执行BAT
例子:
@echo off
net user
%0
保存为BAT执行,他就会无限循环执行net user这条命令,直到你手动中止.
龙卷风补充其实%0就是第一参数%1前面那个参数固然就是批处理文件名包括路径。
以上就是批处理中的一些系统变量,另外还有一些变量,他们也表示一些功能,
FOR命令中的那些就是,FOR变量已经说过,就不讲了.


2、自定义变量
故名思意,自定义变量就是由咱们来给他赋予值的变量
要使用自定义变量就得使用set命令了,看例子.
@echo off
set var=我是值
echo %var%
pause
保存为BAT执行,咱们会看到CMD里返回一个  "我是值"
var为变量名,=号右变的是要给变量的值
这就是最简单的一种设置变量的方法了
若是咱们想让用户手工输入变量的值,而不是在代码里指定,能够用用set命令的/p参数
例子:
@echo off
set /p var=请输入变量的值
echo %var%
pause
var变量名  =号右边的是提示语,不是变量的值
变量的值由咱们运行后本身用键盘输入! 

1、交互界面设计

没啥说的看看高手设计的菜单界面吧
@echo off
cls
title 终极多功能修复
:menu
cls
color 0A
echo.
echo                 ==============================
echo                 请选择要进行的操做而后按回车
echo                 ==============================
echo.
echo              1.网络修复及上网相关设置,修复IE,自定义屏蔽网站
echo.
echo              2.病毒专杀工具端口关闭工具,关闭自动播放
echo.
echo              3.清除全部多余的自启动项目修复系统错误
echo.
echo              4.清理系统垃圾,提升启动速度
echo.
echo              Q.退出
echo.
echo.
:cho
set choice=
set /p choice=          请选择:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 选择无效请从新输入
echo.
goto cho
只要学完本教程前面的章节上面的程序应该能看懂了。





2、if…else…条件语句

前面已经谈到DOS条件语句主要有如下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
加强用法IF [/I] string1 compare-op string2 command
加强用法中加上/I就不区分大小写了!
加强用法中还有一些用来判断数字的符号

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于


上面的command命令均可以用小括号来使用多条命令的组合包括else子句组合命令中能够嵌套使用条件或循环命令。

例如:

    IF EXIST filename (
        del filename
    ) ELSE (
        echo filename missing
    )

也可写成
if exist filename (del filename) else (echo filename missing)
但这种写法不适合命令太多或嵌套命令的使用。


3、循环语句

一、指定次数循环
FOR /L %variable IN (start,step,end) DO command [command-parameters]

组合命令
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
) 

二、对某集合执行循环语句。
FOR %%variable IN (set) DO command [command-parameters]

  %%variable  指定一个单一字母可替换的参数。
  (set)      指定一个或一组文件。可使用通配符。
  command   对每一个文件执行的命令可用小括号使用多条命令组合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

    检查以 [drive:]path 为根的目录树指向每一个目录中的
    FOR 语句。若是在 /R 后没有指定目录则使用当前
目录。若是集仅为一个单点(.)字符则枚举该目录树。

同前面同样command能够用括号来组合
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

三、条件循环
    上面的循环结构是用for命令来实现的for命令循环有一个缺点就是整个循环被看成一条命令语句涉及到变量延迟的问题。
    利用goto语句和条件判断dos能够实现条件循环很简单啦看例子

例
@echo off
set var=0
rem ************循环开始了
:continue
set /a var+=1
echo 第%var%次循环
if %var% lss 100 goto continue
rem ************循环结束了
echo 循环执行完毕
pause

例
@echo off
set var=100
rem ************循环开始了
:continue
echo 第%var%次循环
set /a var-=1
if %var% gtr 0 goto continue
rem ************循环结束了
echo 循环执行完毕
pause





4、子程序

在批处理程序中能够调用外部可运行程序好比exe程序也可调用其余批处理程序这些也能够看做子程序可是不够方便若是被调用的程序不少就显得不够简明了很繁琐。
   在windowsXP中批处理能够调用本程序中的一个程序段至关于子程序这些子程序通常放在主程序后面。

子程序调用格式
  CALL :label arguments

子程序语法
  :label
  command1
  command2
  ......
  commandn
  goto :eof

在子程序段中参数%0指标签:label

子过程通常放在最后而且注意在主程序最后要加上exit或跳转语句避免错误的进入子过程。

子程序和主程序中的变量都是全局变量其做用范围都是整个批处理程序。

传至子程序的参数在call语句中指定在子程序中用%一、%2至%9的形式调用而子程序返回主程序的数据只需在调用结束后直接引用就能够了固然也能够指定返回变量请看下面的例子。

子程序例1
@echo off
call :sub return 你好
echo 子程序返回值%return%
pause

:sub
set %1=%2
goto :eof
运行结果你好



子程序例2设计一个求多个整数相加的子程序
@echo off
set sum=0
call :sub sum 10 20 35
echo 数据求和结果%sum%
pause

:sub
rem 参数1为返回变量名称
set /a %1=%1+%2
shift /2
if not "%2"=="" goto sub
goto :eof

运行结果65

5、用ftp命令实现自动下载

ftp是经常使用的下载工具ftp界面中有40多个经常使用命令本身学习了不介绍了。这里介绍如何用dos命令行调用ftp命令实现ftp自动登陆并上传下载并自动退出ftp程序。
其实能够将ftp命令组合保存为一个文本文件而后用如下命令调用便可。

ftp  -n -s:[[drive:]path]filename

上面的filename为ftp命令文件包括登陆IP地址用户名、密码、操做命令等
例
open 90.52.8.3   打开ip
user iware       用户为iware
password8848    密码
bin             二进制传输模式
prompt
cd tmp1         切换至iware用户下的tmp1目录
pwd
lcd d:\download   本地目录
mget *          下载tmp1目录下的全部文件
bye             退出ftp




6、用7-ZIP实现命令行压缩和解压功能

语法格式详细状况见7-zip帮助文件看得头晕能够跳过用到再学
7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每一个命令都有不一样的参数<switch>,请看帮助文件
<base_archive_name>为压缩包名称
<arguments>为文件名称支持通配符或文件列表

其中7z是至命令行压缩解压程序7z.exe<command>是7z.exe包含的命令列举以下

a Adds files to archive. 添加至压缩包
a命令可用参数
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -sfx (create SFX)
  -si (use StdIn)
  -so (use StdOut)
  -ssw (Compress shared files)
  -t (Type of archive)
  -u (Update)
  -v (Volumes)
  -w (Working Dir)
  -x (Exclude) 

b Benchmark 

d Deletes files from archive. 从压缩包中删除文件
d命令可用参数
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -u (Update)
  -w (Working Dir)
  -x (Exclude) 

e Extract解压文件至当前目录或指定目录
e命令可用参数
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries) 

l Lists contents of archive.
t Test 
u Update 

x eXtract with full paths用文件的完整路径解压至当前目录或指定目录
x命令可用参数
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries) 




7、调用VB******程序

使用 Windows 脚本宿主能够在命令提示符下运行脚本。C******.exe 提供了用于设置脚本属性的命令行开关。


用法C****** 脚本名称 [脚本选项...] [脚本参数...]

选项
//B         批模式不显示脚本错误及提示信息
//D         启用 Active Debugging
//E:engine  使用执行脚本的引擎
//H:C****** 将默认的脚本宿主改成 C******.exe
//H:W****** 将默认的脚本宿主改成 W******.exe 默认
//I         交互模式默认与 //B 相对)
//Job:xxxx  执行一个 WSF 工做
//Logo      显示徽标默认
//Nologo    不显示徽标执行时不显示标志
//S         为该用户保存当前命令行选项
//T:nn      超时设定秒容许脚本运行的最长时间
//X         在调试器中执行脚本
//U         用 Unicode 表示来自控制台的重定向 I/O


“脚本名称”是带有扩展名和必需的路径信息的脚本文件名称如d:\admin\vb******s\chart.vbs。
“脚本选项和参数”将传递给脚本。脚本参数前面有一个斜杠 (/)。每一个参数都是可选的但不能在未指定脚本名称的状况下指定脚本选项。若是未指定参数则 C****** 将显示 C****** 语法和有效的宿主参数。




8、将批处理转化为可执行文件

因为批处理文件是一种文本文件任何人均可以对其进行随便编辑不当心就会把里面的命令破坏掉因此若是将其转换成.com格式的可执行文件不只执行效率会大大提升并且不会破坏原来的功能更能将优先级提到最高。Bat2Com就能够完成这个转换工做。
小知识在DOS环境下可执行文件的优先级由高到低依次为.com>.exe>.bat>.cmd即若是在同一目录下存在文件名相同的这四类文件当只键入文件名时DOS执行的是name.com若是须要执行其余三个文件则必须指定文件的全名如name.bat。

这是一个只有5.43K大小的免费绿色工具能够运行在纯DOS或DOS窗口的命令行中用法Bat2Com
FileName这样就会在同一目录下生成一个名为FileNme.com的可执行文件执行的效果和原来的.bat文件同样。

9、时间延迟

本条参考引用[英雄]教程
什么是时间延迟顾名思义就是执行一条命令后延迟一段时间再进行下一条命令。
延迟的应用见下节“模拟进度条”。
一、利用ping命令延时
例
  @echo off
  echo 延时前%time%
  ping /n 3 127.0.0.1 >nul
  echo 延时后%time%
  pause 
解说用到了ping命令的“/n”参数表示要发送多少次请求到指定的ip。本例中要发送3次请求到本机的ip127.0.0.1。127.0.0.1可简写为127.1。“>nul”就是屏蔽掉ping命令所显示的内容。

二、利用for命令延时
例
  @echo off
  echo 延时前%time%
  for /l %%i in (1,1,5000) do echo %%i>nul
  echo 延时后%time%
  pause
解说原理很简单就是利用一个计次循环并屏蔽它所显示的内容来达到延时的目的。

三、利用vbs延迟函数精确度毫秒偏差1000毫秒内

例
    @echo off
    echo %time%
    call :delay 5000
    echo %time%
    pause
    exit

    :delay
    echo W******.Sleep %1>delay.vbs
    C****** //B delay.vbs
    del delay.vbs
    goto :eof

运行显示
10:44:06.45
10:44:11.95
请按任意键继续. . .

上面的运行结果显示实际延时了5500毫秒多出来的500毫秒时创建和删除临时文件所耗费的时间。偏差在一秒以内。


四、仅用批处理命令实现任意时间延迟精确度10毫秒偏差50毫秒内

仅用批处理命令就能够实现延迟操做。

例

@echo off
set /p delay=请输入需延迟的毫秒数
set TotalTime=0
set NowTime=%time%
::读取起始时间时间格式为13:01:05.95
echo 程序开始时间%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::读取起始时间的分钟数
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::将起始时间的秒数转为毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 读取如今时间的分钟数
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::将如今时间的秒数转为毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序结束时间%time%
echo 设定延迟时间%delay%毫秒
echo 实际延迟时间%TotalTime%毫秒
pause

运行显示

   请输入需延迟的毫秒数6000
   程序开始时间15:32:16.37
   程序结束时间15:32:22.37
   设定延迟时间6000毫秒
   实际延迟时间6000毫秒
   请按任意键继续. . .

实现原理首先设定要延迟的毫秒数而后用循环累加时间直到累加时间大于等于延迟时间。

偏差windows系统时间只能精确到10毫秒因此理论上有可能存在10毫秒偏差。
      经测试当延迟时间大于500毫秒时上面的延迟程序通常不存在偏差。当延迟时间小于500毫秒时可能有几十毫秒偏差为何由于延迟程序自己也是有运行时间的同时系统时间只能精确到10毫秒。

为了方便引用可将上面的例子改成子程序调用形式

@echo off
echo 程序开始时间%Time%
call :delay 10
echo 实际延迟时间%totaltime%毫秒
echo 程序结束时间%time%
pause
exit

::-----------如下为延时子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::读取起始时间时间格式为13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof






10、模拟进度条

下面给出一个模拟进度条的程序。若是将它运用在你本身的程序中可使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo  程序正在初始化. . . 
echo.
echo  ┌──────────────────────────────────────┐
set/p=  ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo   100%%
echo  └──────────────────────────────────────┘
pause

解说“set /p a=■<nul”的意思是只显示提示信息“■”且不换行也不需手工输入任何信息这样可使每一个“■”在同一行逐个输出。“ping /n 0 127.1>nul”是输出每一个“■”的时间间隔即每隔多少时间输出一个“■”。





11、特殊字符的输入及应用

开始 -> 运行 -> 输入cmd -> edit -> ctrl+p意思是容许输入特殊字符-> 按ctrl+a将会显示笑脸图案。

若是要继续输入特殊字符请再次按ctrl+p而后ctrl+某个字母

以上是特殊字符的输入方法选自[英雄]教程很管用的。也就是用编辑程序edit输入特殊字符而后保存为一文本文件再在windows下打开此文件复制其中的特殊符号便可。

一些简单的特殊符号能够在dos命令窗口直接输入并用重定向保存为文本文件。
例
C:>ECHO ^G>temp.txt
“^G”是用CtrlG或Alt007输入输入多个^G能够产生多声鸣响。


特殊字符的应用也颇有意思这里仅举一例退格键

退格键表示删除左边的字符此键不能在文档中正常输入但能够经过edit编辑程序录入并复制出来。即“”。

利用退格键能够设计闪烁文字效果



例文字闪烁
@echo off
:start
set/p=床前明月光<nul
::显示文字光标停于行尾
ping -n 0 127.0.0.1>nul
::设置延迟时间
set /p a=<nul
:: 输出一些退格符将光标置于该行的最左端退格符的数量能够本身调整。
set /p a=                               <nul
::输出空格将以前输出的文字覆盖掉。
set /p a=<nul
::再次输出退格符将光标置于该行的最左端这里的退格符数量必定不能比前面的空格数少。
::不然光标不能退到最左端。
goto start


例输出唐诗一首每行闪动屡次
@echo off
setlocal enabledelayedexpansion

set str=床前明月光 疑是地上霜 举头望明月 低头思故乡
::定义字符串str
for %%i in (%str%) do (
rem 因为str中含有空格则以空格为分隔符将str中的每个部分依次赋给变量%%i。
        set char=%%i
        echo.
        echo.
        for /l %%j in (0,1,5) do (
                set/p=!char:~%%j,1!<nul
  rem 依次取出变量char中的每个字符并显示。
                ping -n 0 127.0.0.1>nul
  rem 设置输出每一个字符的时间延迟。
        )
call :hero %%i
)
pause>nul
exit

:hero
for /l %%k in (1,1,10) do (
ping /n 0 127.0.0.1>nul
set /p a=<nul
set /p a=                               <nul
set /p a=<nul
ping /n 0 127.0.0.1>nul
set /p a=%1<nul
)
::文字闪动
goto :eof

12、随机数%random%的应用技巧

%RANDOM% 系统变量 返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。

2的15次方等于32768上面的032767实际就是15位二进制数的范围。

那么如何获取100之内的随机数呢很简单将%RANDOM%按100进行求余运算便可见例子。

例生成5个100之内的随机数
  @echo off
  setlocal enabledelayedexpansion
  for /L %%i in (1 1 5) do (
     set /a randomNum=!random!%%100
     echo 随机数!randomNum!
  )
  pause
运行结果每次运行不同
随机数91
随机数67
随机数58
随机数26
随机数20
请按任意键继续. . .

求余数运算set /a randomNum=!random!%%100中的100能够是132768之间的任意整数。

总结利用系统变量%random%求余数运算%%字符串处理等能够实现不少随机处理。


思考题目生成给定位数的随机密码
解答思路将26个英文字母或10数字以及其它特殊字符组成一个字符串随机抽取其中的若干字符。

参考答案1简单
@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2% 
pause
exit

:randomPassword
::---------生成随机密码
::---------%1为密码长度%2及之后为返回变量名称
::---------for命令最多只能区分31个字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof





参考答案2最优
@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit

:randomPassword
::---------生成随机密码
::---------%1为密码长度%2及之后为返回变量名称
::---------goto循环、变量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循环
:randomPassword1
set /a numof=%random%%%36
call set return=%return%%%wordset:~%numof%,1%%
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循环
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof



说明本例涉及到变量嵌套和命令嵌套的应用见后。





十3、变量嵌套 与 命令嵌套

    和其它编程语言相比dos功能显得相对简单要实现比较复杂的功能须要充分运用各类技巧变量嵌套与命令嵌套就是此类技巧之一。

先复习一下前面的“字符串截取”的关键内容

**********************************************
截取功能统一语法格式为%a:~[m[,n]]%
**********************************************
方括号表示可选%为变量标识符a为变量名不可少冒号用于分隔变量名和说明部分符号能够简单理解为“偏移”便可m为偏移量缺省为0n为截取长度缺省为所有。

百分号若是须要当成单一字符必须写成%%

以上是dos变量处理的通用格式若是其中的m、n为变量那么这种状况就是变量嵌套了。

好比设变量word为“abcdefghij”变量num为“123456789”
%word:~4,1%为e其中4能够从变量num中取值即%num:~3,1%写成组合形式以下
%word:~%num:~3,1%,1% 经测试这种写法不能正确执行写成%word:~(%num:~3,1%),1%一样不行那么怎么实现这种变量嵌套呢这就必须结合命令嵌套。

什么是命令嵌套呢简单的说首先用一条dos命令生成一个字符串而这个字符串是另外一条dos命令用call语句调用字符串将其执行从而获得最终结果。

例用call语句实现命令嵌套
@echo off
set str1=aaa echo ok bbb
echo 初始字符串%str1%
echo 生成命令字符串以下
echo %str1:~4,7%
echo 运行命令字符串生成最终结果为
call %str1:~4,7%
pause

运行显示
初始字符串aaa echo ok bbb
生成命令字符串以下
echo ok
运行命令字符串生成最终结果为
ok
请按任意键继续. . .