用Unity实现两滴水融合（基本实现）

上次用贝塞尔曲线苟了一个是在不怎么样，而且比计算复杂，这次直接用metaball2d做了，效果还算可以

这次是用C#+shader实现的，通过C#给material里传送坐标和设置信息，主要实现都在shader里面。
用shader绘制两个圆很简单，我们真正需要处理的是：两个圆怎样相融的问题。
fragment如下

fixed4 frag (v2f i) : SV_Target
{
	_Pos=_Vector.xy;
	_Pos2=_Vector.zw;
	float temp=0;
	for(int k=-3;k<4;k++){
	 for(int n=-3;n<4;n++){
	  float dis=distance(_Pos.xy,float2(k*_Dim+i.vertex.x,n*_Dim+i.vertex.y));
	  float dis2=distance(_Pos2.xy,float2(k*_Dim+i.vertex.x,n*_Dim+i.vertex.y));
	  float d=min(dis,dis2);
	  temp+=d;
	 }
	}
	temp/=49;
	if(temp<_Dis){
	return _Col;
	}
	return _Back;
}

把两个圆心坐标分别赋值给_Pos和_Pos2 ,
_Dim关系到一个平滑程度的问题，当_Dim为0时：

关于min(),因为每个像素点只能为一个圆心服务，所以我们让它服务于距离它最近的那个圆心
/49是相当于取了一个平局值。
_Dis是用来控制每个圆的大小的，如果超出圆的大小，就返回一个_Noc(背景色或透明)，如果在范围内，就把我们想要的颜色_Col返回。
完整shader代码如下：

Shader "Unlit/metaball2d"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_Dim("_Dim",Float)=2
		_Col("_Col",Color)=(0,0,1,1)
		_Noc("_Noc",Color)=(1,1,1,0)
		_Vector("_Vector",Vector)=(0.2,0.5,0.8,0.5)
		_Dis("_Dis",Float)=1000
		_Size("_Size",Float)=1
	}
	SubShader
	{
		Tags { "RenderType"="Transparent" "IgnoreProjector" = "True" "Queue"="Transparent"}
		Pass
		{
			Tags{"LightMode"="ForwardBase"}
			ZWrite Off
			Blend SrcAlpha OneMinusSrcAlpha
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};
			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};
			sampler2D _MainTex;
			float4 _MainTex_ST;
			float _Dim;
			fixed4 _Col;
	        fixed4 _Noc;
			float2 _Pos;
			float2 _Pos2;
			vector _Vector;
			float _Dis;
			float _Size;
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				_Pos=_Vector.xy;
				_Pos2=_Vector.zw;
				float temp=0;
				for(int k=-3;k<4;k++){
					for(int n=-3;n<4;n++){
						float dis=distance(_Pos.xy,float2(k*_Dim+i.vertex.x,n*_Dim+i.vertex.y));
						float dis2=distance(_Pos2.xy,float2(k*_Dim+i.vertex.x,n*_Dim+i.vertex.y));
						float d=min(dis,dis2);
						temp+=d;
					}
				}
				temp/=49;
				if(temp<_Dis){
					return _Col;
				}
				return _Noc;
			}
			ENDCG
		}
	}
}