bat文件if-for语法

BAT语句结构

　　相似于C语言，批处理也有它的语句结构。批处理的语句结构主要有选择结构(if语句)、循环结构(for语句)等。

if语句(选择结构)

　　if语句实现条件判断，包括字符串比较、存在判断、定义判断等。经过条件判断，if语句便可以实现选择功能。

　　一、字符串比较

　　if语句仅可以对两个字符(串)是否相同、前后顺序进行判断等。其命令格式为：

　　IF [not] string1 compare-op string2 command1 [else command2]

　　其中，比较操做符compare-op有如下几类：

　　== - 等于

　　EQU - 等于

　　NEQ - 不等于

　　LSS - 小于

　　LEQ - 小于或等于

　　GTR - 大于

　　GEQ - 大于或等于

　　选择开关/i则不区分字符串大小写；选择not项，则对判断结果进行逻辑非。

　　字符串比较示例：

　　===============================================

　　@echo off

　　set str1=abcd1233

　　set str2=ABCD1234

　　if %str1%==%str2% (echo 字符串相同！) else (echo 字符串不相同！)

　　if /i %str1% LSS %str2% (echo str1^<str2) else (echo str1^>=str2)

　　echo.

　　set /p choice=是否显示当前时间？(y/n)

　　if /i not %choice% EQU n echo 当前时间是：%date% %time%

　　pause>nul

　　===============================================

　　对于最后一个if判断，当咱们输入n或N时的效果是同样的，都不会显示时间。若是咱们取消开关/i，则输入N时，依旧会显示时间。

　　另外请注意一下几个细节：1-echo str1^<str2和echo str1^>=str2；2-echo.。

　　二、存在判断

　　存在判断的功能是判断文件或文件夹是否存在。其命令格式为：

　　IF [NOT] EXIST filename command1 [else command2]

　　===============================================

　　@echo off

　　if exist %0 echo 文件%0是存在的！

　　if not exist %~df0 (

　　echo 文件夹%~df0不存在！

　　) else echo 文件夹%~df0存在！

　　pause>nul

　　===============================================

　　这里注意几个地方：

　　1-存在判断既能够判断文件也能够判断文件夹；

　　2-%0即表明该批处理的全称(包括驱动器盘符、路径、文件名和扩展类型)；

　　3-%~df0是对%0的修正，只保留了其驱动器盘符和路径，详情请参考for /?，属高级批处理范畴；

　　4-注意if语句的多行书写，多行书写要求command1的左括号必须和if在同一行、else必须和command1的右括号同行、command2的左括号必须与else同行、command1和command2均可以有任意多行，即command能够是命令集。

　　三、定义判断

　　定义判断的功能是判断变量是否存在，便是否已被定义。其命令格式为：

　　IF [not] DEFINED variable command1 [else command2]

　　存在判断举例：

　　===============================================

　　@echo off

　　set var=111

　　if defined var (echo var=%var%) else echo var还没有定义！

　　set var=

　　if defined var (echo var=%var%) else echo var还没有定义！

　　pause>nul

　　===============================================

　　对比可知，"set var="能够取消变量，收回变量所占据的内存空间。

for语句(循环结构)

　　for语句能够实现相似于C语言里面的循环结构，固然for语句的功能要更强大一点，经过不一样的开关能够实现更多的功能。for语句有多个开关，不一样开关将会实现不一样的功能。

一、无开关

　　无开关的for语句可以对设定的范围内进行循环，是最基本的for循环语句。其命令格式为：

　　FOR %%variable IN (set) DO command

　　其中，%%variable是批处理程序里面的书写格式，在DOS中书写为%variable，即只有一个百分号(%)；set就是须要咱们设定的循环范围，相似于C语言里面的循环变量；do后面的command就是循环所执行的命令，即循环体。

　　无开关for语句举例：

　　===============================================

　　@echo off

　　for %%i in (a,"b c",d) do echo %%i

　　pause>nul

　　===============================================

二、开关/L

　含开关/L的for语句，能够根据set里面的设置进行循环，从而实现对循环次数的直接控制。其命令格式为：

　　FOR /L %%variable IN (start,step,end) DO command

　　其中，start为开始计数的初始值，step为每次递增的值，end为结束值。当end小于start时，step须要设置为负数。

　　含开关/L的for语句举例(建立5个文件夹)：

　　===============================================

　　@echo off

　　for /l %%i in (1,2,10) do md %%i

　　pause

　　===============================================

　　上例将新建5个文件夹，文件夹名称依次为一、三、五、七、9。能够发现，%%i的结束值并不是end的值10，而是不大于end的一个数。

三、开关/F

　　含开关/F的for语句具备最强大的功能，它可以对字符串进行操做，也可以对命令的返回值进行操做，还能够访问硬盘上的ASCII码文件，好比txt文档等。其命令格式为：

　　FOR /F ["options"] %%variable IN (set) DO command

　　其中，set为("string"、'command'、file-set)中的一个；options是(eol=c、skip=n、delims=xxx、tokens=x,y,m-n、usebackq)中的一个或多个的组合。各选项的意义参见for /f。通常状况下，使用较多的是skip、tokens、delims三个选项。

　　含开关/F的for语句举例：

　　===============================================

　　@echo off

　　echo **No Options:

　　for /f %%a in ("1,2,10") do echo a=%%a

　　echo **Options tokens ^& delims:

　　for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c

　　pause

　　===============================================

　　@echo off

　　echo 本文件夹里面的文件有：

　　for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (

　　if not "%%a"=="<DIR>" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b

　　)

　　pause

　　===============================================

　　@echo off

　　echo 本文件夹里面的文件有：

　　dir>c:\file.txt

　　for /f "skip=5 tokens=3* delims= " %%a in (c:\file.txt) do (

　　if not "%%a"=="<DIR>" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b

　　)

　　del c:\file.txt

　　pause

　　===============================================

　　对于后面的两个例子，其中options里面的delims= 是能够删除的，由于只要添加了/F开关系统就将delims的值默认为空格。

符号字符串中的最后一个字符星号，

　　那么额外的变量将在最后一个符号解析以后

　　分配并接受行的保留文本。本例中也能够改成4，不过文件名中有空格的文件，只能显示空格之前部分

同时咱们也看到了，for语句的do后面的command也是能够分行的，只须要保证command的左括号和do在同一行就能够了。

四、开关/D或/R

　　含开关/D或/R的for语句是与目录或文件有关的命令，通常状况下不多使用。含开关/R的命令有时候被用于经过遍历文件夹来查找某一个文件或文件夹，故而列举此例。

　　含开关/R的for语句举例(文件夹遍历)：

　　===============================================

　　@echo off

　　setlocal enabledelayedexpansion

　　FOR /R d: %%i IN (.) DO (

　　set dd=%%i

　　set "dd=!dd:~0,-1!"

　　echo !dd!

　　)

　　pause

　　exit

　　===============================================

　　上例便可以罗列出D盘下的全部文件夹，其速度要比命令"tree d:"慢多了，不过其返回结果的实用性则远远超过了tree命令。

　　通常状况下咱们不推荐经过遍历文件夹来查找文件，特别是在查找某些程序(好比QQ.exe)的位置时。推荐经过reg命令查找注册表来查找QQ的路径，以保证查找效率。

　　上例中也出现了几个新面孔，如setlocal、感叹号等。其中，感叹号其实就是变量百分号(%)的强化版。之因此要用!而不用%，是由于在for循环中，当一个变量被屡次赋值时，%dd%所获取的仅仅是dd第一次被赋予的值；要想刷新dd的值，就必须首先经过命令"setlocal enabledelayedexpansion"来开启延迟变量开关，而后用!dd!来获取dd的值。

　　for语句是批处理里面功能最强大、使用最广泛却又最难掌握的一套命令，这也是批处理菜鸟和批处理高手最明显的一个分水岭，一旦掌握了这套命令，那么你就离批处理达人不远了！