如何在 AHK 下载网络内容到文件或变量

如今早已经是网络时代了，彻底单机而不须要联网的软件不多了。某些时候，用 AHK 写个脚本也是须要去网络获取数据的。

下载网络内容到本地文件

有些时候咱们须要把一个网页、图片、音频等文件下载到本地，再作后续处理。在其余编程语言可能就比较麻烦了，好比先下载网络内容到一个字符串变量，而后建立一个文件，将字符串写入，再保存文件。而 AHK 内置的 UrlDownloadToFile 命令就是为这个场景量身定作的。

UrlDownloadToFile, URL, Filename

能够看到，这个命令的用法很是简单，第一个参数是文件的网络地址，第二个参数是文件的本地地址。若是第二个参数不是完整路径，文件会被下载到当前脚本的工做目录，通常状况就是脚本自身的目录。

好比我想下载 AHK 官网的 Logo 图片到 C:test.png，就能够这样：

UrlDownloadToFile, http://ahkscript.org/logos/ahk_logo.png, C:\test.png

是否是很是简单。除了 HTTP，UrlDownloadToFile 还支持 HTTPS 和 FTP 协议。

下载网络内容到字符串变量

但有些状况，咱们并不须要将网络内容保存到文件里，而是直接使用，好比直接显示在控件里。虽然也能够先写到文件再读出来，但这样作不只画蛇添足，有额外的开销，还须要考虑共用临时文件、临时文件没被删除等问题。

AHK 并无命令能够直接将网络内容下载到字符串变量，但能够使用 COM 对象 WinHttp.WinHttpRequest.5.1，官方文档中有一个例子，用起来倒也不是很麻烦。

whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
; Open() 的第三个参数表明同步或者异步，如今不用过多关注，true 就能够了
; 之后咱们会仔细了解同步和异步
whr.Open("GET", "https://autohotkey.com/download/1.1/version.txt", true)
whr.Send()
whr.WaitForResponse()
version := whr.ResponseText
MsgBox, % version

这样就能够用 MsgBox 将从网络获取到的一个字符串弹出来了。但比起 UrlDownloadToFile 仍是麻烦了很多，若是须要常常使用，仍是很不方便的，这就须要封装成一个函数来使用，好比这样：

UrlDownloadToVar(url)
{
    static whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
    whr.Open("GET", url, true)
    whr.Send()
    whr.WaitForResponse()
    return whr.ResponseText
}

和刚才的代码差很少，但我这里 whr 是 static 类型的，由于只须要初始化一次就能够了，调用 ComObjCreate() 是有开销的。

但有些时候咱们并不仅须要传入一个 URL，能够还包含一些 HTTP Headers，并且使用 POST 方式访问，这就须要再改造下这个函数，好比这样：

UrlDownloadToVar(url, headers = "")
{
    static whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
    whr.Open("POST", url, true)

    if (headers != "")
    {
        for key, value in headers
        {
            whr.SetRequestHeader(key, value)
        }
    }

    whr.Send()
    whr.WaitForResponse()
    return whr.ResponseText
}

用起来也很方便，好比我要使用 POST 方式访问 test.org，携带两个 HTTP Headers，key1:value1 和 key2:value2：

result := UrlDownloadToVar("http://test.org"
    , { "key1" : "value1", "key2" : "value2" })

若是须要设置更多参数，好比超时时间，就须要查下 WinHttp.WinHttpRequest.5.1 的文档了，基本上均可以找到本身想要的功能。

付费解决 Windows、Linux、Shell、C、C++、AHK、Python、JavaScript、Lua 等领域相关问题，灵活订价，欢迎咨询，微信 ly50247。