使用触发器实现记录oracle用户登陆失败信息到alert.log日志文件

前面咱们说了用oracle自带的审计功能能够实现记录用户登陆失败日志到数据表中（连接：http://www.54ok.cn/6778.html）。今天咱们来分享一下如何把用户登陆失败信息记录到alert.log日志文件中。

 

使用sys帐号登陆数据库，而后建立触发器。

 

CREATE OR REPLACE TRIGGER logon_denied_to_alert
  AFTER servererror ON DATABASE
DECLARE
  message   VARCHAR2(168);
  ip        VARCHAR2(15);
  v_os_user VARCHAR2(80);
  v_module  VARCHAR2(50);
  v_action  VARCHAR2(50);
  v_pid     VARCHAR2(10);
  v_sid     NUMBER;
  v_program VARCHAR2(48);
BEGIN
  IF (ora_is_servererror(1017)) THEN

    -- get ip FOR remote connections :
    IF upper(sys_context('userenv', 'network_protocol')) = 'TCP' THEN
      ip := sys_context('userenv', 'ip_address');
    END IF;

    SELECT sid INTO v_sid FROM sys.v_$mystat WHERE rownum < 2;
    SELECT p.spid, v.program
      INTO v_pid, v_program
      FROM v$process p, v$session v
     WHERE p.addr = v.paddr
       AND v.sid = v_sid;

    v_os_user := sys_context('userenv', 'os_user');
    dbms_application_info.read_module(v_module, v_action);

    message := to_char(SYSDATE, 'YYYYMMDD HH24MISS') ||
               ' logon denied from ' || nvl(ip, 'localhost') || ' ' ||
               v_pid || ' ' || v_os_user || ' with ' || v_program || ' – ' ||
               v_module || ' ' || v_action;

    sys.dbms_system.ksdwrt(2, message);

  END IF;
END;

 

尝试使用错误的帐号密码登陆数据库，而后在alert.log日志中就能够查到信息，可是这个日志信息比较简单，只记录了时间，ip和使用的客户端工具，并无记录登陆的帐号是多少。所以对比起审计功能来讲稍微差点。