DOS批处理高级教程精选(六)

第五章 set命令详解

好久没发贴了,今天来写点讲BAT的新手教学贴!

在上一贴中我简单的介绍了一下SET设置自定义变量的做用,如今我来具体讲一下set的其余功能.

1、用set命令设置自定义变量

显示、设置或删除 cmd.exe 环境变量。
SET [variable=[string]]
variable 指定环境变量名。
string    指定要指派给变量的一系列字符串。
要显示当前环境变量，键入不带参数的 SET。
SET 命令不容许变量名含有等号。

注意：如下用法将清除变量variable的值，使其变成未定义状态。
SET variable=
上面等号后面无任何符号，若是写成SET variable=""，此时变量值并不为空，而是等于两个引号，即""

例子:
@echo off
set var=我是值
echo %var%
pause

请看 set var=我是值 ,这就是BAT直接在批处理中设置变量的方法!
set 是命令   var是变量名 =号右边的"我是值"是变量的值
在批处理中咱们要引用这个变就把var变量名用两个%(百分号)扩起来,如%var%

SET还能够提供一个交互界面,让用户本身输入变量的值,而后咱们在来根据这个值来作相应操做,如今我就来讲说SET的这种语法,只须要加一个"/P"参数就能够了!
SET /P variable=[promptString]

例子:
@echo off
set /p var=请输入变量的值:
echo 您输入了 %var% ~_~
pause

set /p 是命令语法 var是变量名    =号右边的"请输入变量的值: ",这个是提示语,不是变量的值了!
运行后,咱们在提示语后面直接输入1,就会显示一行您输入了 1 ~_~

好了,先回顾到这,如今讲SET其余功能

使用set /?查看SET的帮助咱们发现SET除了我上面讲的
SET [variable=[string]]
SET /P variable=[promptString]
这两种语法外,还有以下几种语法:
SET /A expression
环境变量替换已以下加强:
%PATH:str1=str2%
%PATH:~10,5%
%PATH:~-10%
%PATH:~0,-2%

这机种语法有什么用处呢?下面咱们来一个个讲解他们!

2、用set命令进行简单计算

语法：SET /A expression
/A 命令行开关指定等号右边的字符串为被评估的数字表达式。该表达式
评估器很简单并以递减的优先权顺序支持下列操做:
    ()                  -分组
    ! ~ -               -一元运算符
    * / %               -算数运算符
    + -                 -算数运算符
    << >>               -二进制逻辑移位
    &                   -二进制按位“与”
    ^                   -二进制按位“异”
    |                   -二进制按位“或”
    = *= /= %= += -=    -算数赋值
    &= ^= |= <<= >>=    -二进制运算赋值
    ,                   -表达式分隔符

若是 SET /A 在命令脚本外的命令行执行的，那么它显示该表达式的最后值。
除十六进制有 0x 前缀， 八进制有 0 前缀的，数字值为十进位数字。
所以， 0x12 与 18 和 022相同。请注意八进制公式可能很容易搞混:
08 和 09 是无效的数字，由于 8 和 9 不是有效的八进制位数。

上面这些是系统帮助里的内容,看着是否是有点晕，不要紧我来简单解释一下:
set的/A参数就是让SET能够支持数学符号进行加减等一些数学运算!

注意：通常的运算常为十进制运算，若是数字字符串最左边为0，将被认为是八进制，从而出错。好比，0812之类的数字不能参与十进制运算，转换方法为：10812-10000

例：
set aa=0812
set /a aa=1%aa%-10000
echo %aa%
结果为：812

例：
@echo off
set /p input=请输入计算表达式：
set /a var=%input%
echo 计算结果：%input%=%var%
pause

上面的例子是龙卷风设计的，很好用哟，请看下面几个运算过程：
注意：DOS计算只能进行整数运算，精确到整数

请输入计算表达式：1+9+20+30-10
计算结果：1+9+20+30-10=50
请按任意键继续. . .

请输入计算表达式：10/3    #除法只能精确到整数
计算结果：10/3=3
请按任意键继续. . .

请输入计算表达式：-100+62 #负数
计算结果：-100+62=-38
请按任意键继续. . .

请输入计算表达式：100%3    ＃求余数
计算结果：100%3=1
请按任意键继续. . .
注意：以上的求余数运算符%在批处理程序中必须写成%%

请输入计算表达式：(25+75)*2/(15+5)   #括号
计算结果：(25+75)*2/(15+5)=10
请按任意键继续. . .

请输入计算表达式：1234567890*9876543210   #范围
无效数字。数字精确度限为 32 位。
计算结果：1234567890*9876543210=
请按任意键继续. . .

注意：上面的计算过程显示，DOS计算只能精确到32位，这个32位是指二进制32位，其中最高位为符号位（0为正，1为负），低位31位为数值。31个1换成十进制为2147483647，因此DOS计算的有效值范围是-2147483648至2147483647，超出该数值范围时计算出错，请看下面的计算过程：

请输入计算表达式：2147483647-1    #最大值减1，值有效
计算结果：2147483647-1=2147483646
请按任意键继续. . .

请输入计算表达式：2147483647+1    #最大值加1，出错，结果为最小值
计算结果：2147483647+1=-2147483648
请按任意键继续. . .

请输入计算表达式：-2147483648-1   #最小值减1，出错，结果为最大值
计算结果：-2147483648-1=2147483647
请按任意键继续. . .

运行set /a a=1+1,b=2+1,c=3+1后会显示一个4,但咱们用
echo %a% %b% %c%后看结果,会发现其余数学运算也有效果!,这就是表达式分隔符"逗"号的
做用!

有时候咱们须要直接在原变量进行加减操做就能够用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
都是同样的结果,在原变量的值上在进行数学运算,不过这样写简单一点
再来一个:
set /a var*=2
其余都这么用,只要帮助里有这个语法!

另外还有一些用逻辑或取余操做符,这些符号,按照上面的使用方法会报错的

好比咱们在CMD里输入set /a var=1 & 1 "与运算",他并不会显示为1,而是报错,
为何?对于这样的"逻辑或取余操做符",咱们须要把他们用双引号引发来,也能够用转义字符^，看例子

set /a var= 1 "&" 1 这样结果就显示出来了,其余逻辑或取余操做符用法
set /a var= 1 "+" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 3 "<<" 2 左移位运算， 3的二进制为11，左移2位为1100，换成十进制就是12，自行验证
set /a var= 4 ">>" 2右移位运算，4的二进制为100，右移动2位为1，结果为1

龙卷风补充：凡是按位计算均需换算成二进制。

思考题：求2的n次方
参考答案：
@echo off
set /p n=请输入2的几回方:
set /a num=1^<^
echo %num%
pause

运行结果：
请输入2的几回方: 3
8
请按任意键继续. . .

请输入2的几回方: 10
1024
请按任意键继续. . .

请输入2的几回方: 15
32768
请按任意键继续. . .

休息一下！

----------------------------
史前超文明谜团
----------------------------
    奥克洛（Oklo）是非洲加蓬共和国一个铀矿的名字，法国有一些工厂使用从加蓬进口的铀矿石。1972年6月7日，法国科学家皮尔里特在用质谱计分析自然丰度的六氟化铀时，惊讶地发现，这批进口铀矿石已被人利用过了。由于这批铀矿石的含铀量至关低，铀矿石的通常含铀量为0.72%，而奥克洛铀矿石的含铀量却不足0.3%，和咱们现有的核反应堆的废料几乎相同。
    这件事引发了法国原子能委员会的高度重视。为此，许多科学家赶赴矿区进行考察研究。不久，奥克洛爆出了一条震惊世界的新闻：这里有一个古老的核反应堆，并且核反应堆的构成很是合理。法国政府宣布的这一发现，震惊了全世界。
    这个核反应堆是由6个区域的大约500吨铀矿石组成，它的输出功率很低，只有10到100千瓦。据考证，该矿成矿年代大约在20亿年前，核反应堆在成矿后不久就开始运转，运转时间长达50万年之久,核反应所产生的废物，并无扩散，而是局限在矿区周围。面对这个保存完整、结构合理的核反应堆，科学家们膛目结舌。
--------------
回味无穷的疑问
--------------
    是谁在20亿年前留下了这个古老的核反应堆？是外星人的做品，仍是前一代地球文明的遗迹？20亿年前的反应堆又怎么来解释呢？这个铀矿究竟是怎么回事呢？有人认为这是20亿年前的天外来客的杰做。他们乘坐宇宙飞船来到地球上，选择了奥克洛这个地方建造了原子反应堆，以原子裂变或聚变所释放的能量为能源动力，为他们在地球上的活动提供能量。后来，他们离开了地球，返回了他们的“故里”，就在地球上留下了这座极古老而又神秘的原子反应堆。还有一种推断认为这是史前文明所留下的遗迹。也就是说，20亿年前，在今天咱们叫作奥克洛的地方，可能存在着高度发达的文明，远远超过今天的人类文明。
????选自《世界未解之谜》

3、用set命令进行字符串处理

一、字符串替换

好了，符号说到这，如今说%PATH:str1=str2%
上面语法的意思就是：将字符串变量%PATH%中的str1替换为str2
这个是替换变量值的内容,看例子
@echo off
set a= bbs. verybat. cn
echo 替换前的值: "%a%"
set var=%a: =%
echo 替换后的值: "%var%"
pause

运行显示：（龙卷风添加）
替换前的值: " bbs. verybat. cn"
替换后的值: "bbs.verybat.cn"

对比一下,咱们发现他把变量%a%的空格给替换掉了,从这个例子,咱们就能够发现
%PATH:str1=str2%这个操做就是把变量%PATH%的里的str1所有用str2替换

好比咱们把上面的例子改为这样
@echo off
set a=bbs.verybat.cn
echo 替换前的值: "%a%"
set var=%a:.=伤脑筋%
echo 替换后的值: "%var%"
pause

运行显示：
替换前的值: "bbs.verybat.cn"
替换后的值: "bbs伤脑筋verybat伤脑筋cn"

解释set var=%a:.=伤脑筋%
    set是命令 var是变量名 字a是要进行字符替换的变量的值,"."为要替换的值,
"伤脑筋"为替换后的值!
执行后就会把变量%a%里面的"."所有替换为"伤脑筋"
这就是set的替换字符的很好的功能! 替换功能先讲到这，下面将字符串截取功能

请注意：字符串的替换和截取功能在引用变量的地方都可以，并不必定必需要有set命令
例：
@echo off
set a=bbs.verybat.cn
echo 替换前的值: "%a%"
echo 替换后的值: "%a:.=伤脑筋%"
pause
此例在echo语句中就替换了字符串，效果同样。

二、字符串截取

**********************************************
截取功能统一语法格式为：%a:~[m[,n]]%
**********************************************
方括号表示可选，%为变量标识符，a为变量名，不可少，冒号用于分隔变量名和说明部分，符号～能够简单理解为“偏移”便可，m为偏移量（缺省为0），n为截取长度（缺省为所有）

%PATH:~10,5% 这个什么意思,看例子:

截取功能例子1：
@echo off
set a=bbs.verybat.cn
set var=%a:~1,2%
echo %var%
pause

执行后,咱们会发现只显示了"bs"两个字母,咱们的变量%a%的值不是为bbs.verybat.cn吗？
怎么只显示了第2个字母和第3个字母"bs",分析一结果咱们就能够很容易看出
%PATH:~10,5%就是显示变量PATH里从11位（偏移量10）开始的5个字符!
分析set var=%a:~1,2%
set是命令，var是变量值，a要进行字符操做的变量，"1"从变量"a"第几位开始显示，"2"表示显示几位。
合起来就是把变量a的值从第2位（偏移量1）开始,把2个字符赋予给变量var
这样应该明白了吧~

其余两种语法
%PATH:~-10%
%PATH:~0,-2%
他们也是显示指定变量指定几位的值的意思

%PATH:~-10% 看例子

截取功能例子2：
@echo off
set a=bbs.verybat.cn
set var=%a:~-3%
echo %var%
pause
运行结果：.cn
这个就是把变量a倒数3位的值给变量VAR

固然咱们也能够改为这样
截取功能例子3：
@echo off
set a=bbs.verybat.cn
set var=%a:~3%
echo %var%
pause
运行显示：.verybat.cn
这个就是把变量a的从第3位开始后面所有的值给变量VAR

%PATH:~0,-2% 例子

截取功能例子4：
@echo off
set a=bbs.verybat.cn
set var=%a:~0,-3%
echo %var%
pause
执行后,咱们发现显示的是"bbs.verybat",少了".cn"
从结果分析,很容易分析出,这是把变量a的值从0位开始,
到倒数第三位之间的值所有赋予给var

若是改为这样

截取功能例子5：
@echo off
set a=bbs.verybat.cn
set var=%a:~2,-3%
echo %var%
pause
运行显示：s.verybat
那么他就是显示从第3位（偏移量2）开始减去倒数三位字符的值,并赋予给变量var

讲得好，例子就是说明问题，为便于记忆，龙卷风小节以下：
a=bbs.verybat.cn
%a:~1,2%   ＝“bs”   偏移量1，从第二位开始向右取2位
%a:~-3%    ＝“.cn” 偏移量负3，即倒数3位（也可理解为留下右边3位），右取所有
%a:~3%     ＝“.verybat.cn” 偏移量3（也可理解为去掉左边3位），右取所有
%a:~0,-3%   ＝“bbs.verybat” 偏移量0，右取长度至负3，即倒数3位
%a:~2,-3%   ＝“s.verybat” 偏移量2，右取长度至负3，即倒数3位

**********************************************
因此，截取功能统一语法格式为：%a:~[m[,n]]%
**********************************************
方括号表示可选，%a%为变量名，不可少，冒号用于分隔变量名和说明部分，符号～能够简单理解为“偏移”便可，m为偏移量（缺省为0），n为截取长度（缺省为所有）
上面所述用法其实至关于vbs函数mid、left、right
%a:~0,n% 至关于函数left(a,n) 取左边n位
%a:~-m% 至关于函数right（a,m） 取右边m位
%a:~m,n% 至关于函数mid(a,m+1,n) 从m+1位开始取n位
%a:~m,-n% 至关于函数mid(a,m+1,len(a)-m-n),从m+1位开始，至倒数n+1位
%a:~m % 至关于函数mid(a,m+1,len(a)-m) 或者right(a,len(a)-m)，从m+1位开始取右边所有。

思考题目：输入任意字符串，求字符串的长度
参考答案：

@echo off
set /p str=请输入任意长度的字符串:
echo 你输入了字符串:"%str%"
call :stringlenth "%str%" num
echo 字符串长度为：%num%
pause
exit

:StringLenth
::---------字符串长度计算子程序
::---------参数%1为字符串(若有空格，请用引号括起来)
::---------参数%2为返回变量名称，不能含空格或特殊字符
::@echo off
set theString=%~1
if not defined theString goto :eof
set Return=0
:StringLenth_continue
set /a Return+=1
set thestring=%thestring:~0,-1%
if defined thestring goto StringLenth_continue
if not "%2"=="" set %2=%Return%
goto :eof

好了set的一些用法,就介绍到这了,但愿对各位有所帮助,时间不早睡觉Zz....

                                              by 伤脑筋

休息休息！

诗曰：　　

　　混沌未分天地乱，茫茫渺渺无人见。　　
　　自从盘古破鸿蒙，开辟从兹清浊辨。　　
　　覆载群生仰至仁，发明万物皆成善。　　
　　欲知造化会元功，须看西游释厄传。　　

    《西游记》是我国著名神话小说，是中华五千年文化的见证之一。唐僧乃大唐高僧玄奘法师，往印度求取佛经，导致中华佛家文化大放异彩。    唐僧：表明古代修行人对佛法的坚决执着之心。虽然唐僧手无缚鸡之力，但他不受金钱、美女、权利的诱惑，面对生死也不改变志向。这些都是古人所推崇的，因此唐僧是师父，其余人再有本事也只能当徒弟了。    悟空：“空”、“无”都是高层次的体现，故悟空本事最大。悟空的兵器为“定海神针”，寓意佛家的“定”。    悟能：层次不高，缺点也多，但有点本事。因其缺点多，故又名“八戒”。    悟净：层次不高，本事不大，仅仅有一个清净之心，故名“悟净”。但清净心也很重要，因此有几回悟空遇难时，乃悟净所救。