动态加载内嵌类库文件的方法

有时候咱们引用了一个小型的类库文件，可是若是发布程序，就须要带一个类库文件，感受有点累赘，那该怎么办？
一些第三方的混淆工具自带类库集成，是一个不错的解决办法。
可是若是我只想使用本身的解决方法，那么能够尝试将类库文件以资源嵌入的方式，集成入程序集内！

可是我在测试这个办法的时候，常常会发现程序没法正确加载类库。
以下面的代码，实际上每次在执行时都会发生错误：

Sub Main()

    Dim dllName As String = "程序命名空间.类库文件.dll"
    Dim dllStream As IO.Stream = Reflection.Assembly.GetEntryAssembly.GetManifestResourceStream(dllName)

    Dim dllbytes(dllStream.Length - 1) As Byte
    dllStream.Read(dllbytes, 0, dllStream.Length)
    dllStream.Close()

    Reflection.Assembly.Load(dllbytes)

    Application.EnableVisualStyles()
    Application.Run(New Main)

End Sub

 

当执行以上代码，程序能够正确加载位于程序集内部的类库文件，在启动时不会发生任何错误。
可是当咱们在窗体内执行类库内的代码，就会发生没法引用类库的错误。
究竟错在了哪里？让我百思不得其解。

---

后来我google了一下问题缘由，发现.NET程序并非在使用时才开始解析并生成本地代码，而是在以前就已经生成了各类对象的引用指针。
可是在引用时，若是发现对象并不存在，则会引起一个 AppDomain.AssemblyResolve 事件，所以能够经过 AssemblyResolve 来在发生类库引用错误时，动态地返回类库程序集实例。

因此咱们只须要将加载事件改动到 AssemblyResolve 中就能够了。

Sub main()
    AddHandler AppDomain.CurrentDomain.AssemblyResolve, AddressOf assresolve

    Application.EnableVisualStyles()
    Application.Run(New Form1)
End Sub

Private Function assresolve(ByVal sender As Object, ByVal args As ResolveEventArgs) As Assembly
    Dim aName As String = New Reflection.AssemblyName(args.Name).FullName
    If aName = "类库完整描述名" Then
        Dim dllName As String = "程序命名空间.类库文件.dll"
        Dim dllStream As IO.Stream = Reflection.Assembly.GetEntryAssembly.GetManifestResourceStream(dllName)
        Dim dllbytes(dllStream.Length - 1) As Byte
        dllStream.Read(dllbytes, 0, dllStream.Length)
        dllStream.Close()
        Return Reflection.Assembly.Load(dllbytes)
    End If

    Return Nothing
End Function

这样，当加载类库发生错误之时，就会自动的加载内嵌的DLL文件到程序中。