带上你的Vim，走！

首发自简书

每一个Vimer都有本身的一个配置，犹如每一个剑客都有本身的一把剑(应该是吧)。（争取）做为一个传说中的全栈开发者，换机器就像换衣服同样频繁；在“异国他乡”的机器上，是否怀念那一套属于你的指法呢？下面会讲一下我在 Windows 上打包Vim的一些经验。带上你的Vim，走！

下面讲到的配置主要出自我自用的Vim配置VimConf，感兴趣的能够参考！

一键装机之Vimrc

Vim的几乎全部配置均可以保存在一个vimrc文件中，所以把vimrc同步起来，直接拷贝到相应位置并指定，则能够恢复相应的Vim配置。因此不少Vimer的作法是创建一个Github仓库保存vimrc，在新的机器上只要Clone该仓库就能够将配置同步到该机器上。

获得配置文件后，还须要将该文件拷贝到对应的位置并应用，且可能还须要其余一些辅助文件。所以，为了一劳永逸，通常都会添加一个初始化脚本进行“一键安装”。而Linux和Windows上配置文件的位置还不太同样，所以，每每就须要各自一个脚本了。

下面讲讲在Clone了配置文件后，Windows下的脚本文件应该干些啥。

首先你得有GVim

where gvim > NUL 2> NUL
if %ERRORLEVEL% NEQ 0 (
    echo GVim is needed >&2
    set /A ret=1
    goto :end
)
for /f "tokens=*" %%i in ('where gvim 2^> NUL') do set vim_folder=%%i
if /I "%vim_folder:~-3%" EQU "bat" (
    findstr /b /c:"set VIM_EXE_DIR=" "!vim_folder!" > tmp\vim_folder.txt 2> NUL
    set /p vim_folder=<tmp\vim_folder.txt
    set vim_folder=!vim_folder:~16!
) else (
    call :get_parent_dir "%vim_folder%" vim_folder
)
if not exist "%vim_folder%\gvim.exe" (
    echo Failed to locate GVim
    set /A ret=1
    goto :end
)
echo Found GVim in %vim_folder%

经过where gvim得到当前GVim可执行文件的路径。有多是一个启动脚本GVim.bat，所以须要进一步分析该脚本，获取GVim的真实路径。

没有GVim就没有一切了，因此必须安装好GVim。

其次你得有Git

where git > NUL 2> NUL

一样，没有Git也就没有一切了，因此必须安装好Git。

更新子模块

个人vimrc中包含了一个配色子模块 Detorte，所以这里须要初始化该模块。

git submodule update --init > NUL 2> NUL

执行后，配置根目录下的detorte目录会包含配色方案的相关文件，下面须要将这些文件拷贝到指定位置。

拷贝配色方案

由于我使用的是本身的配色方案，因此这里须要将其拷贝到指定的位置，以便Vim能检测到该方案。

set detorte_folder=%vimfiles_folder%\colors
xcopy /Y /i detorte\colors %detorte_folder% /s /e > NUL 2> NUL

安装Vundle

我使用的是Vundle进行Vim插件管理，因此为了以后能安装Vim插件，这里须要把Vundle下载并安装好。咱们直接从Vundle的Github上Clone到指定目录%vimfiles_folder%\bundle\Vundle.vim，这样，后面能够直接在Vim中使用Vundle了。

set vundle_repo=https://github.com/VundleVim/Vundle.vim.git
set vundle_folder=%vimfiles_folder%\bundle\Vundle.vim
if not exist %vundle_folder% (
    git clone %vundle_repo% %vundle_folder% > NUL 2> NUL
    if %ERRORLEVEL% NEQ 0 (
        echo Failed to clone Vundle.vim >&2
        set /A ret=1
        goto :end
    )
)

安装小工具

咱们还须要一些小工具来辅助Vim这个大杀器。一个方便的作法是专门使用一个Github仓库来保存这些小工具。

Curl

Vundle须要使用curl.exe来进行插件的搜索，因此咱们须要下载curl.exe。咱们会将这些须要的小工具提早下载并上传到一个Github仓库中，这里call :clone_win_utils会将该仓库下载到一个临时目录中。另外，须要将可执行文件拷贝到Vim的安装目录中，Vim才能检测获得。

if not exist "%vim_folder%\curl.exe" (
    call :clone_win_utils
    if !ERRORLEVEL! NEQ 0 (
        set /A ret=1
        goto :end
    )
    copy /Y %win_utils_folder%\curl.exe "%vim_folder%\" > NUL 2> NUL
    if !ERRORLEVEL! NEQ 0 (
        echo Failed to copy curl.exe, make sure you run this script as Administrator
        set /A ret=1
        goto :end
    )
)

Ag

ag.exe是一个比grep更好用的文件查找工具，在Windows下开发更是让人欲罢不能。另外，Vim的不少插件也会能够经过使用Ag来进行加速。和Curl相似，咱们也是经过提早准备好的仓库下载该工具，而后拷贝到Vim的目录。

if not exist "%vim_folder%\ag.exe" (
    call :clone_win_utils
    if !ERRORLEVEL! NEQ 0 (
        set /A ret=1
        goto :end
    )
    copy /Y %win_utils_folder%\ag.exe "%vim_folder%\" > NUL 2> NUL
    if !ERRORLEVEL! NEQ 0 (
        echo Failed to copy ag.exe, make sure you run this script as Administrator
        set /A ret=1
        goto :end
    )
)

Ctags

Ctags就不用多说了，用Vim的都懂！相似的处理方法。

if not exist "%vim_folder%\ctags.exe" (
    call :clone_win_utils
    if !ERRORLEVEL! NEQ 0 (
        set /A ret=1
        goto :end
    )
    copy /Y %win_utils_folder%\ctags.exe "%vim_folder%\" > NUL 2> NUL
    if !ERRORLEVEL! NEQ 0 (
        echo Failed to copy ctags.exe, make sure you run this script as Administrator
        set /A ret=1
        goto :end
    )
)

GNU Global

结合Ctags使用，可以反向查询引用。相似的处理方法。

if not exist "%vim_folder%\gtags.exe" (
    call :clone_win_utils
    if !ERRORLEVEL! NEQ 0 (
        set /A ret=1
        goto :end
    )
    copy /Y %win_utils_folder%\global\ "%vim_folder%\" > NUL 2> NUL
    if !ERRORLEVEL! NEQ 0 (
        echo Failed to copy GNU Global, make sure you run this script as Administrator
        set /A ret=1
        goto :end
    )
)

markdown2ctags.py

这个Python脚本是为了使Tagbar插件支持Markdown语法，从而显示大纲的，在vimrc中会使用到。

copy /Y markdown2ctags.py %vimfiles_folder%\ > NUL 2> NUL

拷贝vimrc

这个不用解释了吧？

set vimrc_file=%USERPROFILE%\_vimrc
copy /Y .vimrc %vimrc_file% > NUL 2> NUL

至此，启动GVim，:VundleInstall安装配置好的插件，就能够好好享受那熟悉的手指健美操了。

一键部署

对于远程桌面的服务器或者不能联网的机器，上面提到的一键安装就显得不是很适用了。其实，咱们能够在已经安装好的机器上，生成一个“绿色”的GVim，带上全部的配置和Vim插件，而后拷贝到别的机器上直接运行便可。win_init.cmd portable会在根目录下生成一个包含GVim的压缩包。下面，咱们详细说一下其中的魔法。

mkdir %vim_portable_folder% 2> NUL

copy /Y .vimrc %vim_portable_folder%\_vimrc > NUL
set /A portable_ret=!portable_ret!+!ERRORLEVEL!

call :get_file_name "%vim_folder%" vim_exe_folder
xcopy /Y /i "%vim_folder%" "%vim_portable_folder%\!vim_exe_folder!" /s /e > NUL
set /A portable_ret=!portable_ret!+!ERRORLEVEL!

call :get_parent_dir "%vim_folder%" vim_install_folder
xcopy /Y /i "!vim_install_folder!\vimfiles" "%vim_portable_folder%\vimfiles" /s /e > NUL
set /A portable_ret=!portable_ret!+!ERRORLEVEL!

xcopy /Y /i "%vimfiles_folder%" "%vim_portable_folder%\vimfiles" /s /e > NUL
set /A portable_ret=!portable_ret!+!ERRORLEVEL!

1. 新建一个目录以存放绿色版的GVim；

2. 拷贝vimrc；

3. 拷贝GVim可执行文件所在的目录（即主程序）；

4. 拷贝GVim的安装目录；

5. 拷贝vimfiles目录，主要是把Vundle安装好的插件和咱们的Detorte配色拷贝上；

好了，如今将这个目录打包好后拷贝到别的机器上就能有一份如出一辙的Vim配置了。

完美主义者

为什么不添加一个启动快捷方式来启动GVim呢？

下面的脚本会生成一个init.cmd脚本。在目的机器上运行该脚本一次，就会往系统盘添加一个启动脚本。

(echo @echo off
     echo setlocal EnableExtensions
     echo set dest_gvim=C:\Windows\gvim.bat
     echo if exist "%%dest_gvim%%" EXIT /B 0
     echo set cur_dir=%%~dp0
     echo if /I "%%cur_dir:~-1%%" EQU "\" set cur_dir=%%cur_dir:~0,-1%%
     echo set exe_dir=%%cur_dir%%\!vim_exe_folder!
     echo echo @echo off ^> %%dest_gvim%%
     echo echo start "" "%%exe_dir%%\gvim.exe" %%%%* ^>^> %%dest_gvim%%
     echo pause
    ) >> "%init_cmd%"

结语

今后，Vimer和Vim幸福地生活在一块儿！

可是，有一天，Vimer又不开心了，据说是要写Markdown笔记？好吧，出门左转：Vim与Markdown，实现键不离手!