SQL Server 建立数据库邮件

1、 背景

　　数据库发邮件通知数据库的运行状态（状态能够经过JOB形式获取）和信息，达到预警的效果。

 

2、 基础知识

　　msdb系统数据库保存有关Job，Database Mail，Nodifyication等等之类信息的。MSSQL2005以后的邮件功能，使用了Services Broker进行了队列处理。而后使用外部进程，这个能够在配置成功Mail之后查看任务管理器中的进程。

　　另外 sp_send_dbmail是手动发送邮件的存储过程，咱们必须显示的赋值才能发送。

 

3、 图形界面方式建立数据库邮件

下面就以SSMS的图形界面介绍如何建立数据库邮件；

（Figure1：数据库邮件）

（Figure2：以步骤形式建立）

（Figure3：建立配置文件名）

（Figure4：添加Email账号）

这里设置的Email信息是表示以后就以这个Email账号发送邮件，这里的服务器名称填写的是smtp.126.com，端口为25，你须要经过下面的方式测试这个地址是否能够访问。若是不通有多是你机器防火墙的问题。

（Figure5：测试ping）

（Figure6：测试telnet）

（Figure7：配置文件与邮件对应关系）

这里你能够添加多个Email账号，在失败的时候会使用下一个用户尝试发送。

（Figure8：公共配置文件）

（Figure9：系统尝试，不须要修改）

（Figure10：成功界面）

（Figure11：成功发送邮件）

 

4、 数据库邮件相关脚本

--脚本建立数据库邮件
--1.开启数据库邮件
EXEC sp_configure 'show advanced options',1
RECONFIGURE WITH OVERRIDE
GO
EXEC sp_configure 'database mail xps',1
RECONFIGURE WITH OVERRIDE
GO

--2.建立邮件账户信息
EXEC  msdb..sysmail_add_account_sp
      @ACCOUNT_NAME ='ETLErrorMailLog',--邮件账户名称
      @EMAIL_ADDRESS ='******@126.com',--发件人邮件地址
      @DISPLAY_NAME ='系统管理员',--发件人姓名
      @REPLYTO_ADDRESS =NULL,
      @DESCRIPTION = NULL,
      @MAILSERVER_NAME = 'SMTP.126.COM',--邮件服务器地址
      @MAILSERVER_TYPE = 'SMTP',--邮件协议
      @PORT =25,--邮件服务器端口
      @USERNAME = '******@126.com',--用户名
      @PASSWORD = '******',--密码
      @USE_DEFAULT_CREDENTIALS =0,
      @ENABLE_SSL =0,
      @ACCOUNT_ID = NULL
GO

--3.数据库配置文件
IF EXISTS(SELECT name FROM msdb..sysmail_profile WHERE name=N'ETLErrorProfileLog')
BEGIN
    EXEC msdb..sysmail_delete_profile_sp
    @profile_name='ETLErrorProfileLog'
END

EXEC msdb..sysmail_add_profile_sp
    @profile_name = 'ETLErrorProfileLog',--profile名称
    @description = '数据库邮件配置文件',--profile描述
    @profile_id = null
GO

--4.用户和邮件配置文件相关联
EXEC msdb..sysmail_add_profileaccount_sp
    @profile_name = 'ETLErrorProfileLog',--profile名称
    @account_name = 'ETLErrorMailLog',--account名称
    @sequence_number = 1--account 在profile 中顺序
GO

--5.1发送简单文本的邮件
EXEC msdb..sp_send_dbmail
    @profile_name = 'ETLErrorProfileLog',--profile名称
    @recipients = '******@qq.com',--收件人
    @subject = 'Test title this is test ',--邮件标题
    @body = N'数据库邮件测试',--邮件内容
    @body_format = 'HTML'--邮件格式
GO

--5.2发送包含查询的邮件
EXEC msdb..sp_send_dbmail
    @profile_name = 'ETLErrorProfileLog',
    @recipients = '******@qq.com',
    @subject = '查询结果',
    @query = 'SELECT * FROM msdb.dbo.sysmail_faileditems'
GO

--5.2发送包含附件的邮件
EXEC msdb..sp_send_dbmail
    @profile_name = 'ETLErrorProfileLog',
    @recipients = '******@qq.com',
    @subject = '包含附件',
    @body = '有附件，请查收',
    @file_attachments = 'c:\a.txt'
GO

--5.3发送查询做为附件的邮件
EXEC msdb..sp_send_dbmail
    @profile_name = 'ETLErrorProfileLog',
    @recipients = '******@qq.com',
    @subject = '查询结果',
    @body = '查询结果在附件中',
    @query = 'SELECT * FROM msdb.dbo.sysmail_faileditems',
    @attach_query_result_as_file = 1,
    @query_attachment_filename = 'a.txt'
GO

 

5、 参考文献

MSSQL数据库邮件系列二(SSMS和TSQL)

SQL Server：在 SQL Server 2005 中配置数据库邮件，发送邮件

SQL Server Reporting Services一步步实现邮件订阅

利用SQL SERVER2005发送邮件

SQL Server 监控系列 —— 一

祥解使用 SQL Server 2005/2008 发送数据库邮件

巧妙SQL Server设置 备份状态邮件通知

数据库邮件

数据库邮件消息处理对象

sp_send_dbmail (Transact-SQL)