本身动手应用Groovy实现Gradle的DSL(一) Task定义

转载请注明出处: http://my.oschina.net/u/874727/blog/741610

若有问题能够加Q: 1025250620
 

Groovy是基于JVM的敏捷开发语言之一。因为它的语法特性,经常用来构建领域性的DSL。咱们今天的另一个主角就是经过Groovy所构建出来的一门DSL语言Gradle。若是是用过Apache的ant还有Maven等项目自动化构建工具,相信你听过甚至已经逐渐往Gradle方向转换。因为Gradle使用了Groovy的基本语法,使得结构更加清晰,紧凑,更加方便理解。本篇文章会涉及到一些Groovy的语法（做者假定各位都是了解Groovy语法和使用过Gradle的开发者）。

咱们先来看一下简单的Gradle脚本。咱们知道按照Gradle的既有约定,Gradle的脚本通常写在build.gradle的配置文件中，其中以task为基本单位。

task helloworld {  
        println "helloworld!!"  
}//结构1  
  
task sayHello<< {  
        println "sayHello!!"  
}//结构2  

这里,若是咱们把task理解为方法的话,咱们能够假设task方法所传入的参数就是一个Task对象。咱们先抽象出来一个简单的Task对象(POGO对象)。经过第一个结构:

task helloworld {  
        println "helloworld!!"  
}  

咱们看出Task有一个执行闭包,还有一个基本属性name。而这种结构中“helloworld”能够理解为一个Groovy方法名,而闭包做为这个方法的参数。但因为"helloworld"这个名字是由用户本身定义的,所以须要用到Groovy的MOP知识,调用动态方法。这里咱们用invokeMethod方法来实现。综上咱们所定义的内容咱们先实验一个简单的代码:

def task(Task t) {  
  
}  
  
class Task {  
        def name  
        def closure  
}  
  
def invokeMethod(String name,args) {  
  
        println "call method $name()"  
}  
  
task helloworld {  
        println "helloworld!!"  
}  

咱们经过命令行看到输出:"call method helloworld()"。接下去咱们要为结构1细化Task的构建流程,也就是细化你的invoke方法。咱们使用invokeMethod来动态调用方法的缺点在于方法并非真正的动态注入(若是须要真正的调用可使用metaClass机制),而是经过AOP拦截的方式来拦截调用。当你定义了一个“helloworld”的Task了之后,后面可能还须要用到。那么那个时候你的程序仍是会调用invokeMethod方法来构造。为了不重复构造或者查询异常,咱们须要有一个机制来缓存咱们已经构造好的Task。这里,我定义一个TaskPool数据结构来享元咱们的task。

class TaskPool {  
        def map = [:]  
        def push(String name,Task t) {  
                map.put(name,t)  
        }  
  
        def get(String name) {  
                map.get(name)  
        }  
}  
  
taskPool = new TaskPool()  

invokeMethod方法能够改成:

def invokeMethod(String name,args) {  
        println "call method $name()"  
        t = taskPool.get(name)  
        if (t == null) {  
                if (args[0] instanceof Closure) {  
                        t = new Task(name:name,closure:args[0])  
                }  
        }  
        t  
}  

能够看到,这里实际上我给了一个类型为Task的返回值t。给出这个类型的目的是为了提供给task方法使用。而直到这里,咱们能够把“Task push Pool”这个操做放在Task create后的任意位置,可是我把“Task push Pool”的操做放到task方法中,由于咱们在使用结构2"<<"的时候须要经过另一个动态调用入口。咱们还须要给Task类增长一个execute方法来运行咱们task的闭包参数:

class Task {  
        def name  
        def closure  
        def execute() {  
                println "task $name start >>"  
                closure()  
                println "task $name end <<"  
        }  
}  

 

def task(Task t) {  
        taskPool.push(t.name,t)  
        t.execute()  
}  

好了,咱们赶忙敲一下groovy命令来实验一下咱们的结构1吧:

call method helloworld()  
task helloworld start >>  
helloworld!!  
task helloworld end <<  

你是否获得了跟我同样的结果呢?这样咱们经过groovy来实现告终构1样式的task。那么咱们该如何实现结构2范式呢？

 

咱们来回顾一下结构2范式:

task sayHello<< {  
        println "hello!! david!"  
}  

1.  

task以后咱们仍是要传入一个Task的变量,而"<<"是对象内的操做,这样咱们就不能再把sayHello做为方法,而应该做为一个参数变量来看,而这个参数变量的类型很显然是Task类型。所以咱们先在咱们的Task类中重载咱们的"<<"符号:

class Task {  
        def name  
        def closure  
        def leftShift(c) {  
                this.closure = c  
                this  
        }
        def execute() {  
                println "task $name start >>"  
                closure()  
                println "task $name end <<"  
        }  
}  

而做为参数变量的sayHello咱们须要调用Groovy的另一个动态接口getProperty(String name)。类中全部获取属性的调用都会被这个方法所拦截,咱们按照与invokeMethod相同的模式来实现它:

 

def getProperty(String name) {  
  
        def t = taskPool.get(name)  
        if (t == null) {  
                t = new Task(name:name)  
        }  
        t  
}  

但这样是有问题的,为何呢?由于你的taskPool也是做为你的属性,这种状况下你颇有可能形成递归堆栈溢出,那么该怎么解决呢？

 

因为你的taskPool变量属于你原有属性,所以须要调用你原有的调用过程。因此须要将代码改成:

def getProperty(String name) {  
        def t  
        try {  
                t  = super.getProperty(name)  
        } catch(e) {  
  
                t = taskPool.get(name)  
                if (t == null) {  
                        t = new Task(name:name)  
                }     
        }     
        t     
}  

下面咱们用咱们的两种结构来实验一下咱们定义的DSL吧:

task helloworld {  
        println "helloworld!!"  
}  
task sayHello<< {  
        println "hello!! david!"  
}  

最后输出的结果为:

task helloworld start >>  
helloworld!!  
task helloworld end <<  
  
task sayHello start >>  
hello!! david!  
task sayHello end << 

转载请注明出处: http://my.oschina.net/u/874727/blog/741610

若有问题能够加Q: 1025250620