如今, Delphi 的多线程已经很是易用了!

先看一个非多线程的例子, 代码执行时不能进行其它操做(譬如拖动窗体):

{自定义方法: 在窗体上绘制...}
procedure MyMethod;
var
  i: Integer;
begin
  for i := 0 to 500000 do
  begin
    Form1.Canvas.Lock;
    Form1.Canvas.TextOut(10, 10, IntToStr(i));
    Form1.Canvas.Unlock;
  end;
end;

{调用上面的自定义方法}
procedure TForm1.Button1Click(Sender: TObject);
begin
  MyMethod;
end;

修改成多线程(只修改一行代码):

procedure MyMethod;
var
  i: Integer;
begin
  for i := 0 to 500000 do
  begin
    Form1.Canvas.Lock;
    Form1.Canvas.TextOut(10, 10, IntToStr(i));
    Form1.Canvas.Unlock;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread(MyMethod).Start; //!!!
end;

代码分析: 

一、TThread 如今增长了许多 class 方法(直接经过类名调用的方法), TThread.CreateAnonymousThread() 就是比较有用的一个. 

二、顾名思义, CreateAnonymousThread 是创建匿名线程对象, 它的参数是咱们须要在线程中执行的方法. 

三、但 CreateAnonymousThread 创建线程后是挂起的, 须要手动运行它; 后面的 Start 方法就是用来唤醒线程的. 

四、(之前)唤醒线程还能够使用 Resume 方法或 Suspended 属性(Suspended := False;); 但它们即将被废弃了, 如今应使用 Start 来启动线程.

---

CreateAnonymousThread 的参数类型 TProc 是匿名方法(reference), 因此代码能够简写为:

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread( //直接写入方法体
    procedure
    var
      i: Integer;
    begin
      for i := 0 to 500000 do
      begin
        Canvas.Lock;
        Canvas.TextOut(10, 10, IntToStr(i));
        Canvas.Unlock;
      end;
    end //此处无分号
  ).Start;
end;

延时执行:

var
  myThread: TThread;

procedure TForm1.FormCreate(Sender: TObject);
begin
  myThread := TThread.CreateAnonymousThread(
    procedure
    var
      i: Integer;
    begin
      for i := 0 to 500000 do
      begin
        Canvas.Lock;
        Canvas.TextOut(10, 10, IntToStr(i));
        Canvas.Unlock;
      end;
    end
  );
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  myThread.Start;
end;