BAT批处理（二）

时间 2019-11-19

标签 bat 批处理繁體版

原文原文链接

在前一篇中已对BAT批处理基础做了一些总结，可是对于BAT批处理还有不少的知识点没有讲解到，好比DOS中的特殊符号；IF、FOR的使用；变量；更多的DOS命令等等。本文在前一篇的基础上继续对BAT批处理相关进行总结。编程

1、经常使用批处理内部命令介绍windows

经常使用批处理内部命令介绍操作系统

一、REM命令行

除了::符号，REM也为注释命令，通常用来给程序加上注解，该命令后的内容不被执行，但能回显。其次, :: 注释做用更简洁有效; 但有两点须要注意：
第一, 任何以冒号:开头的字符行, 在批处理中都被视做标号, 而直接忽略其后的全部内容。
有效标号：冒号后紧跟一个以字母数字开头的字符串，goto语句能够识别。
无效标号：冒号后紧跟一个非字母数字的一个特殊符号，goto没法识别的标号，能够起到注释做用，因此 :: 常被用做注释符号，其实 :+ 也可起注释做用。
第二, 与rem 不一样的是, ::后的字符行在执行时不会回显, 不管是否用echo on打开命令行回显状态, 由于命令解释器不认为他是一个有效的命令行, 就此点来看, rem 在某些场合下将比 :: 更为适用; 另外, rem 能够用于 config.sys 文件中。设计

行内注释格式：%注释内容% （不经常使用，慎用）unix

二、title

设置cmd窗口的标题
title 新标题 #能够看到cmd窗口的标题栏变了

三、COLOR
设置默认的控制台前景和背景颜色。
COLOR [attr]
attr 指定控制台输出的颜色属性
颜色属性由两个十六进制数字指定 -- 第一个为背景，第二个则为前景。每一个数字能够为如下任何值之一:
0 = 黑色 8 = 灰色
1 = 蓝色 9 = 淡蓝色
2 = 绿色 A = 淡绿色
3 = 湖蓝色 B = 淡浅绿色
4 = 红色 C = 淡红色
5 = 紫色 D = 淡紫色
6 = 黄色 E = 淡黄色
7 = 白色 F = 亮白色
若是没有给定任何参数，该命令会将颜色还原到 CMD.EXE 启动时的颜色。这个值来自当前控制台窗口、/T 开关或
DefaultColor 注册表值。
若是用相同的前景和背景颜色来执行 COLOR 命令，COLOR命令会将ERRORLEVEL设置为 1。
例如: "COLOR fc" 在亮白色上产生淡红色

五、start
批处理中调用外部程序的命令（该外部程序在新窗口中运行，批处理程序继续往下执行，不理会外部程序的运行情况），若是直接运行外部程序则必须等外部程序完成后才继续执行剩下的指令。
例：start explorer d:\
调用图形界面打开D盘

六、assoc和ftype
文件关联
assoc 设置'文件扩展名'关联，关联到'文件类型'
ftype 设置'文件类型'关联，关联到'执行程序和参数'
当你双击一个.txt文件时，windows并非根据.txt直接判断用notepad.exe打开而是先判断.txt属于 txtfile '文件类型'，再调用txtfile关联的命令行txtfile=%SystemRoot%\system32\NOTEPAD.EXE %1 。能够在"文件夹选项"→"文件类型"里修改这2种关联

assoc #显示全部'文件扩展名'关联
assoc .txt #显示.txt表明的'文件类型'，结果显示 .txt=txtfile
assoc .doc #显示.doc表明的'文件类型'，结果显示 .doc=Word.Document.8
assoc .exe #显示.exe表明的'文件类型'，结果显示 .exe=exefile
ftype #显示全部'文件类型'关联
ftype exefile #显示exefile类型关联的命令行，结果显示 exefile="%1" %*
assoc .txt=Word.Document.8 #设置.txt为word类型的文档，能够看到.txt文件的图标都变了
assoc .txt=txtfile #恢复.txt的正确关联

ftype exefile="%1" %* #恢复 exefile 的正确关联
若是该关联已经被破坏，能够运行 command.com，再输入这条命令。

七、pushd 和 popd
切换当前目录
@echo off
c: & cd\ & md mp3 #在 C:\ 创建 mp3 文件夹
md d:\mp4 #在 D:\ 创建 mp4 文件夹
cd /d d:\mp4 #更改当前目录为 d:\mp4
pushd c:\mp3 #保存当前目录，并切换当前目录为 c:\mp3
popd #恢复当前目录为刚才保存的 d:\mp4
通常用处不大，在当前目录名不肯定时，会有点帮助。（dos编程中颇有用）

八、再谈CALL

CALL命令能够在批处理执行过程当中调用另外一个批处理，当另外一个批处理执行完后，再继续执行原来的批处理。
CALL command
调用一条批处理命令，和直接执行命令效果同样（特殊状况下不同，见下面的例子），特殊状况下颇有用，好比变量的多级嵌套，见教程后面。在批处理编程中，能够根据必定条件生成命令字符串，用call能够执行该字符串，见例子。
CALL [drive:][path]filename [batch-parameters]
调用的其它批处理程序。filename参数必须具备.bat或.cmd 扩展名。
CALL :label arguments
调用本文件内命令段，至关于子程序。被调用的命令段以标签:label开头，以命令goto :eof结尾。

另外，批脚本文本参数参照(%0、%一、等等)已以下改变:
批脚本里的 %* 指出全部的参数(如 %1 %2 %3 %4 %5 ...)
批参数(%n)的替代已被加强。您可使用如下语法:（看不明白的直接运行后面的例子）
%~1 - 删除引号(")，扩充 %1
%~f1 - 将 %1 扩充到一个彻底合格的路径名
%~d1 - 仅将 %1 扩充到一个驱动器号
%~p1 - 仅将 %1 扩充到一个路径
%~n1 - 仅将 %1 扩充到一个文件名
%~x1 - 仅将 %1 扩充到一个文件扩展名
%~s1 - 扩充的路径指含有短名
%~a1 - 将 %1 扩充到文件属性
%~t1 - 将 %1 扩充到文件的日期/时间
%~z1 - 将 %1 扩充到文件的大小
%~$PATH : 1 - 查找列在 PATH 环境变量的目录，并将 %1扩充到找到的第一个彻底合格的名称。若是环境变量名未被定义，或者没有找到文件，此组合键会扩充到空字符串

能够组合修定符来取得多重结果:
%~dp1 - 只将 %1 扩展到驱动器号和路径
%~nx1 - 只将 %1 扩展到文件名和扩展名
%~dp$PATH:1 - 在列在 PATH 环境变量中的目录里查找 %1，并扩展到找到的第一个文件的驱动器号和路径。
%~ftza1 - 将 %1 扩展到相似 DIR 的输出行。
在上面的例子中，%1 和 PATH 能够被其余有效数值替换。
%~ 语法被一个有效参数号码终止。%~ 修定符不能跟 %*使用
注意：参数扩充时不理会参数所表明的文件是否真实存在，均以当前目录进行扩展。

要理解上面的知识，下面的例子很关键。
例：
@echo off
Echo 产生一个临时文件 > tmp.txt
Rem 下行先保存当前目录，再将c:\windows设为当前目录
pushd c:\windows
Call :sub tmp.txt
Rem 下行恢复前次的当前目录
Popd
Call :sub tmp.txt
pause
Del tmp.txt
exit

:sub
Echo 删除引号： %~1
Echo 扩充到路径： %~f1
Echo 扩充到一个驱动器号： %~d1
Echo 扩充到一个路径： %~p1
Echo 扩充到一个文件名： %~n1
Echo 扩充到一个文件扩展名： %~x1
Echo 扩充的路径指含有短名： %~s1
Echo 扩充到文件属性： %~a1
Echo 扩充到文件的日期/时间： %~t1
Echo 扩充到文件的大小： %~z1
Echo 扩展到驱动器号和路径：%~dp1
Echo 扩展到文件名和扩展名：%~nx1
Echo 扩展到相似 DIR 的输出行：%~ftza1
Echo.
Goto :eof

例：
set aa=123456
set cmdstr=echo %aa%
call %cmdstr%
pause

本例中若是不用call，而直接运行%cmdstr%，将显示结果%aa%，而不是123456

九、shift
更改批处理文件中可替换参数的位置。
SHIFT [/n]
若是命令扩展名被启用，SHIFT 命令支持/n 命令行开关；该命令行开关告诉
命令从第n个参数开始移位；n介于零和八之间。
例如：SHIFT /2 #将%3移位到%2，将%4移位到%3，等等；而且不影响 %0 和 %1。

十、if详解

if 三种格式：
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

if语句实现条件判断，包括字符串比较、存在判断、定义判断等。经过条件判断，if语句便可以实现选择功能。
1）．字符串比较
if语句仅可以对两个字符(串)是否相同、前后顺序进行判断等。其命令格式为：
IF [not] string1 compare-op string2 command1 [else command2]

为了防止字符串中含有空格，可用如下格式
if [NOT] {string1}=={string2} command
if [NOT] [string1]==[string2] command
if [NOT] "string1"=="string2" command

其中，比较操做符compare-op有如下几类：
== - 等于
EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于
选择开关/i则不区分字符串大小写；选择not项，则对判断结果进行逻辑非。
字符串比较示例：
@echo off
set str1=abcd1233
set str2=ABCD1234
if %str1%==%str2% (echo 字符串相同！) else (echo 字符串不相同！)
if /i %str1% LSS %str2% (echo str1^<str2) else (echo str1^>=str2)
echo.
set /p choice=是否显示当前时间？(y/n)
if /i not %choice% EQU n echo 当前时间是：%date% %time%
pause>nul
对于最后一个if判断，当咱们输入n或N时的效果是同样的，都不会显示时间。若是咱们取消开关/i，则输入N时，依旧会显示时间。

2）．存在判断
存在判断的功能是判断文件或文件夹是否存在。其命令格式为：
IF [NOT] EXIST filename command1 [else command2]
@echo off
if exist %0 echo 文件%0是存在的！
if not exist %~df0 (echo 文件夹%~df0不存在！) else echo 文件夹%~df0存在！
pause>nul
这里注意几个地方：
1-存在判断既能够判断文件也能够判断文件夹；
2-%0即表明该批处理的全称(包括驱动器盘符、路径、文件名和扩展类型)；
3-%~df0是对%0的修正，只保留了其驱动器盘符和路径，详情请参考for /?，属高级批处理范畴；
4-注意if语句的多行书写，多行书写要求command1的左括号必须和if在同一行、else必须和command1的右括号同行、command2的左括号必须与else同行、command1和command2均可以有任意多行，即command能够是命令集。

3）．定义判断
定义判断的功能是判断变量是否存在，便是否已被定义。其命令格式为：
IF [not] DEFINED variable command1 [else command2]
存在判断举例：
@echo off
set var=111
if defined var (echo var=%var%) else echo var还没有定义！
set var=
if defined var (echo var=%var%) else echo var还没有定义！
pause>nul
对比可知，"set var="能够取消变量，收回变量所占据的内存空间。

4）．结果判断
masm %1.asm
if errorlevel 1 pause & edit %1.asm
link %1.obj
先对源代码进行汇编，若是失败则暂停显示错误信息，并在按任意键后自动进入编辑界面；不然用link程序链接生成的obj文件，这种用法是先判断前一个命令执行后的返回码（也叫错误码，DOS程序在运行完后都有返回码），若是和定义的错误码符合（这里定义的错误码为1），则执行相应的操做（这里相应的操做为pause & edit %1.asm部分）。
另外，和其余两种用法同样，这种用法也能够表示否认。用否认的形式仍表达上面三句的意思，代码变为：
masm %1.asm
if not errorlevel 1 link %1.obj
pause & edit %1.asm

十一、setlocal 与变量延迟
本条内容引用[英雄出品]的批处理教程：
要想进阶，变量延迟是必过的一关！因此这一部分但愿你能认真看。
为了更好的说明问题，咱们先引入一个例子。

例1:
@echo off
set a=4
set a=5 & echo %a%
pause
结果：4

解说：为何是4而不是5呢？在echo以前明明已经把变量a的值改为5了？
让咱们先了解一下批处理运行命令的机制：
批处理读取命令时是按行读取的（另外例如for命令等，其后用一对圆括号闭合的全部语句也看成一行），在处理以前要完成必要的预处理工做，这其中就包括对该行命令中的变量赋值。咱们如今分析一下例1，批处理在运行到这句“set a=5 & echo %a%”以前，先把这一句整句读取并作了预处理——对变量a赋了值，那么%a%固然就是4了！（没有为何，批处理就是这样作的。）
而为了可以感知环境变量的动态变化，批处理设计了变量延迟。简单来讲，在读取了一条完整的语句以后，不当即对该行的变量赋值，而会在某个单条语句执行以前再进行赋值，也就是说“延迟”了对变量的赋值。
那么如何开启变量延迟呢？变量延迟又须要注意什么呢？举个例子说明一下：

例2:
@echo off
setlocal enabledelayedexpansion
set a=4
set a=5 & echo !a!
pause
结果：5

解说：启动了变量延迟，获得了正确答案。变量延迟的启动语句是“setlocal enabledelayedexpansion”，而且变量要用一对叹号“!!”括起来（注意要用英文的叹号），不然就没有变量延迟的效果。
分析一下例2，首先“setlocal enabledelayedexpansion”开启变量延迟，而后“set a=4”先给变量a赋值为4，“set a=5 & echo !a!”这句是给变量a赋值为5并输出（因为启动了变量延迟，因此批处理可以感知到动态变化，即不是先给该行变量赋值，而是在运行过程当中给变量赋值，所以此时a的值就是5了）。
再举一个例子巩固一下。

例3:
@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do (
set a=%%i
echo !a!
)
pause
结果：
1
2
3
4
5

解说：本例开启了变量延迟并用“!!”将变量扩起来，所以获得咱们预期的结果。若是不用变量延迟会出现什
么结果呢？结果是这样的：
ECHO 处于关闭状态。
ECHO 处于关闭状态。
ECHO 处于关闭状态。
ECHO 处于关闭状态。
ECHO 处于关闭状态。
即没有感知到for语句中的动态变化。
提示：在没有开启变量延迟的状况下，某条命令行中的变量改变，必须到下一条命令才能体现。这一点也能够加以利用，看例子。

例：交换两个变量的值，且不用中间变量
@echo off
::目的：交换两个变量的值，可是不使用临时变量
set var1=abc
set var2=123
echo 交换前： var1=%var1% var2=%var2%
set var1=%var2%& set var2=%var1%
echo 交换后： var1=%var1% var2=%var2%
pause

十二、ATTRIB 显示或更改文件属性
ATTRIB [+R|-R] [+A|-A] [+S|-S] [+H|-H] [[drive:] [path] filename] [/S [/D]]
+ 设置属性。
- 清除属性。
R 只读文件属性。
A 存档文件属性。
S 系统文件属性。
H 隐藏文件属性。
[drive:][path][filename]
指定要处理的文件属性。
/S 处理当前文件夹及其子文件夹中的匹配文件。
/D 也处理文件夹。

例：
md autorun
attrib +a +s +h autorun
上面的命令将创建文件夹autorun，而后将其设为存档、系统、隐藏属性。

经常使用特殊符号

1)、@ 命令行回显屏蔽符
2)、% 批处理变量引导符
3)、> 重定向符
4)、>> 重定向符
5)、<、>&、<& 重定向符
6)、| 命令管道符
7)、^ 转义字符
8)、& 组合命令
9)、&& 组合命令
10）、|| 组合命令
11）、"" 字符串界定符
12)、, 逗号
13)、; 分号
14)、() 括号
15)、! 感叹号
16)、批处理中可能会见到的其它特殊标记符: （略）
CR(0D) 命令行结束符
Escape(1B) ANSI转义字符引导符
Space(20) 经常使用的参数界定符
Tab(09) ; = 不经常使用的参数界定符
+ COPY命令文件链接符
* ? 文件通配符
/ 参数开关引导符
: 批处理标签引导符

废话少说，开讲了
1)、@ 命令行回显屏蔽符
这个字符在批处理中的意思是关闭当前行的回显。咱们从前几课知道ECHO OFF能够关闭掉整个批处理命令的回显，但不能关掉ECHO OFF这个命令，如今咱们在ECHO OFF这个命令前加个@，就能够达到全部命令均不回显的要求

2)、% 批处理变量引导符
这个百分号严格来讲是算不上命令的，它只是批处理中的参数而已（多个%一块儿使用的状况除外，之后还将详细介绍)。引用变量用%var%，调用程序外部参数用%1至%9等
%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*为命令行传递给批处理的参数
%0 批处理文件自己，包括完整的路径和扩展名
%1 第一个参数
%9 第九个参数
%* 从第一个参数开始的全部参数
参数%0具备特殊的功能，能够调用批处理自身，以达到批处理自己循环的目的，也能够复制文件自身等等。

例：最简单的复制文件自身的方法
copy %0 d:\wind.bat
小技巧：添加行内注释
%注释内容%（能够用做行内注释，不能出现重定向符号和管道符号）
为何这样呢？此时“注释内容”其实被看成变量，其值是空的，故只起注释做用，不过这种用法容易出现语法错误，通常不用。

3)、> 重定向符
输出重定向命令
这个字符的意思是传递而且覆盖，他所起的做用是将运行的结果传递到后面的范围（后边能够是文件，也能够是默认的系统控制台）在NT系列命令行中，重定向的做用范围由整个命令行转变为单个命令语句，受到了命令分隔符&,&&,||和语句块的制约限制。
好比：
使用命令：echo hello >1.txt将创建文件1.txt，内容为”hello “（注意行尾有一空格）
使用命令：echo hello>1.txt将创建文件1.txt，内容为”hello“（注意行尾没有空格）

4)、>> 重定向符
输出重定向命令
这个符号的做用和>有点相似，但他们的区别是>>是传递并在文件的末尾追加，而>是覆盖用法同上
一样拿1.txt作例子使用命令：
echo hello > 1.txt
echo world >>1.txt
这时候1.txt 内容以下:
hello
world

5)、<、>&、<& 重定向符
这三个命令也是管道命令，但它们通常不经常使用，你只须要知道一下就ok了，固然若是想仔细研究的话，能够本身查一下资料。(本人已查过，网上也查不到相关资料)<，输入重定向命令，从文件中读入命令输入，而不是从键盘中读入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt

这样就能够不等待输入直接修改当前日期
>&，将一个句柄的输出写入到另外一个句柄的输入中。
<&，恰好和>&相反，从一个句柄读取输入并将其写入到另外一个句柄输出中。

经常使用句柄：0、一、2，未定义句柄：3—9
1>nul 表示禁止输出正确的信息
2>nul 表示禁止输出错误信息。

其中的1与2都是表明某个数据流输入输出的地址（NT CMD 称之为句柄，MSDOS称之为设备）。
句柄0：标准输入stdin，键盘输入
句柄1：标准输出stdout，输出到命令提示符窗口（console，代码为CON）
句柄2：标准错误stderr，输出到命令提示符窗口（console，代码为CON）
其中的stdin可被<重定向，stdout可被>、>>重定向。

咱们已经知道读取文本中的内容能够用for命令，但若是只须要读取第一行用for命令就有点麻烦。简单的办法以下:
@echo off
set /p str=<%0
echo %str%
pause

运行显示批处理文件自身的第一行：@echo off

6)、| 命令管道符
格式：第一条命令 | 第二条命令 [| 第三条命令...]
将第一条命令的结果做为第二条命令的参数来使用，记得在unix中这种方式很常见。
例如：
dir c:\|find "txt"
以上命令是：查找C：\全部，并发现TXT字符串。
FIND的功能请用 FIND /? 自行查看
在不使format的自动格式化参数时，我是这样来自动格式化A盘的
echo y|format a: /s /q /v:system
用过format的都知道，再格盘时要输入y来确认是否格盘，这个命令前加上echo y并用|字符来将echo y的结果传给format命令从而达到自动输入y的目的（这条命令有危害性，测试时请慎重）

7)、^ 转义字符
^是对特殊符号<,>,&的前导字符，在命令中他将以上3个符号的特殊功能去掉，仅仅只把他们当成符号而不使用他们的特殊意义。
好比
echo test ^>1.txt
结果则是：test > 1.txt
他没有追加在1.txt里，呵呵。只是显示了出来,另外，此转义字符还能够用做续行符号。
举个简单的例子：
@echo off
echo 英雄^
是^
好^
男人
pause

不用多说，本身试一下就明白了。为何转义字符放在行尾能够起到续行符的做用呢？缘由很简单，由于每行末尾还有一个看不见的符号，即回车符，转义字符位于行尾时就让回车符失效了，从而起到了续行的做用。

8)、& 组合命令
语法：第一条命令 & 第二条命令 [& 第三条命令...]
&、&&、||为组合命令，顾名思义，就是能够把多个命令组合起来当一个命令来执行。这在批处理脚本里是容许的，并且用的很是普遍。由于批处理认行不认命令数目。这个符号容许在一行中使用2个以上不一样的命令，当第一个命令执行失败了，也不影响后边的命令执行。这里&两边的命令是顺序执行的，从前日后执行。
好比：
dir z:\ & dir y:\ & dir c:\
以上命令会连续显示z,y,c盘的内容，不理会该盘是否存在

9)、&& 组合命令
语法：第一条命令 && 第二条命令 [&& 第三条命令...]
用这种方法能够同时执行多条命令，当碰到执行出错的命令后将不执行后面的命令，若是一直没有出错则一直执行完全部命令这个命令和上边的相似，但区别是，第一个命令失败时，后边的命令也不会执行
dir z:\ && dir y:\ && dir c:\

10)、|| 组合命令
语法：第一条命令 || 第二条命令 [|| 第三条命令...]
用这种方法能够同时执行多条命令，当一条命令失败后才执行第二条命令，当碰到执行正确的命令后将不执行后面的命令，若是没有出现正确的命令则一直执行完全部命令；
提示：组合命令和重定向命令一块儿使用必须注意优先级，管道命令的优先级高于重定向命令，重定向命令的优先级高于组合命令
问题：把C盘和D盘的文件和文件夹列出到a.txt文件中。看例：
dir c:\ && dir d:\ > a.txt
这样执行后a.txt里只有D盘的信息！为何？由于组合命令的优先级没有重定向命令的优先级高！因此这句在执行时将本行分红这两部分：dir c:\和dir d:\ > a.txt，而并非如你想的这两部分：dir c:\ && dir d:\和> a.txt。要使用组合命令&&达到题目的要求，必须得这么写：
dir c:\ > a.txt && dir d:\ >> a.txt

这样，依据优先级高低，DOS将把这句话分红如下两部分：dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的几句的差异比较特殊，值得好好研究体会一下。固然这里还能够利用&命令（本身想一下道理哦）：
dir c:\ > a.txt & dir d:\ >> a.txt
[这个也能够用 dir c:\;d:\ >>a.txt 来实现]

11)、"" 字符串界定符
双引号容许在字符串中包含空格，进入一个特殊目录能够用以下方法。
cd "program files"
cd progra~1
cd pro*
以上三种方法均可以进入program files这个目录。

12)、, 逗号
逗号至关于空格，在某些状况下“,”能够用来当作空格使。
好比
dir,c:\

13)、; 分号
分号，当命令相同时，能够将不一样目标用；来隔离，但执行效果不变，如执行过程当中发生错误，则只返回错误报告，但程序仍会执行。（有人说不会继续执行，其实测试一下就知道了）
好比：
dir c:\;d:\;e:\;z:\
以上命令至关于
dir c:\
dir d:\
dir e:\
dir f:\
若是其中z盘不存在，运行显示：系统找不到指定的路径。而后终止命令的执行。
例：dir c:\;d:\;e:\1.txt
以上命令至关于
dir c:\
dir d:\
dir e:\1.txt
其中文件e:\1.txt不存在，但e盘存在，有错误提示，但命令仍会执行。

为何？若是目标路径不存在，则终止执行；若是路径存在，仅文件不存在，则继续执行。
就说这些了!各位有什么意见请回贴!有什么疑问请到BAT交流区发贴!下一节改进!

14)、() 括号
小括号在批处理编程中有特殊的做用，左右括号必须成对使用，括号中能够包括多行命令，这些命令将被当作一个总体，视为一条命令行。括号在for语句和if语句中常见，用来嵌套使用循环或条件语句，其实括号()也能够单独使用，请看例子。
例：
命令：echo 1 & echo 2 & echo 3
能够写成：
(
echo 1
echo 2
echo 3
)

上面两种写法效果同样，这两种写法都被视为是一条命令行。
注意：这种多条命令被视为一条命令行时，若是其中有变量，就涉及到变量延迟的问题。

15)、! 感叹号
没啥说的，在变量延迟问题中，用来表示变量，即%var%应该表示为!var!，请看前面的setlocal命令介绍。

循环：for命令详解

讲FOR以前呢,咋先告诉各位新手朋友,若是你有什么命令不懂,直接在CMD下面输入:name /? 这样的格式来看系统给出的帮助文件,好比for /? 就会把FOR命令的帮助所有显示出来!固然许多菜鸟都看不懂....因此才会有那么多批处理文章!!!!俺也照顾菜鸟,把FOR命令用我本身的方式说明下!
正式开始:

1)、基本格式
FOR %%variable IN (set) DO command [command-parameters]
%%variable 指定一个单一字母表示可替换的参数。
(set) 指定一个或一组文件。可使用通配符。
command 指定对每一个文件执行的命令。
command-parameters 为特定命令指定参数或命令行开关。

参数:FOR有4个参数: /d /l /r /f
他们的做用我在下面用例子解释,如今开始讲每一个参数的意思。

2)、参数 /d
FOR /D %%variable IN (set) DO command [command-parameters]
若是集中包含通配符，则指定与目录名匹配，而不与文件名匹配。
若是 Set (也就是我上面写的 "相关文件或命令") 包含通配符（* 和 ?），将对与 Set 相匹配的每一个目录（而不是指定目录中的文件组）执行指定的 Command。
这个参数主要用于目录搜索,不会搜索文件,看这样的例子
@echo off
for /d %%i in (c:\*) do echo %%i
pause
运行会把C盘根目录下的所有目录名字打印出来,而文件名字一个也不显示!
在来一个,好比咱们要把当前路径下文件夹的名字只有1-3个字母的打出来
@echo off
for /d %%i in (???) do echo %%i
pause
这样的话若是你当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了
这里解释下*号和?号的做用,*号表示任意N个字符,而?号只表示任意一个字符
知道做用了,给你们个思考题目!
@echo off
for /d %%i in (window?) do echo %%i
pause
保存到C盘下执行,会显示什么呢?本身看吧! 显示：windows
/D参数只能显示当前目录下的目录名字,这个你们要注意!

3)、参数 /R
FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树，指向每一个目录中的FOR 语句。若是在 /R 后没有指定目录，则使用当前目录。若是集仅为一个单点(.)字符，则枚举该目录树。

递归
上面咱们知道,/D只能显示当前路径下的目录名字,那么如今这个/R也是和目录有关,他能干吗呢?放心他比/D强大多了!
他能够把当前或者你指定路径下的文件名字所有读取,注意是文件名字,有什么用看例子!
请注意2点：
一、set中的文件名若是含有通配符(？或*)，则列举/R参数指定的目录及其下面的所用子目录中与set相符合的全部文件，无相符文件的目录则不列举。
二、相反，若是set中为具体文件名，不含通配符，则枚举该目录树（即列举该目录及其下面的全部子目录），而无论set中的指定文件是否存在。这与前面所说的单点（.）枚举目录树是一个道理，单点表明当前目录，也可视为一个文件。

例：
@echo off
for /r c:\ %%i in (*.exe) do echo %%i
pause
我们把这个BAT保存到D盘随便哪里而后执行,我会就会看到,他把C盘根目录,和每一个目录的子目录下面所有的EXE文件都列出来了!!!!

例：
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
参数不同了吧!这个命令前面没加那个C:\也就是搜索路径,这样他就会以当前目录为搜索路径,好比你这个BAT你把他放在d:\test目录下执行,那么他就会把D:\test目录和他下面的子目录的所有EXE文件列出来!!!

例：
@echo off
for /r c:\ %%i in (boot.ini) do echo %%i
pause
运行本例发现枚举了c盘全部目录，为了只列举boot.ini存在的目录，可改为下面这样：
@echo off
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i
pause
用这条命令搜索文件真不错。。。。。。
这个参数你们应该理解了吧!仍是满好玩的命令!

4)、参数 /L
FOR /L %%variable IN (start,step,end) DO command [command-parameters]
该集表示以增量形式从开始到结束的一个数字序列。
所以，(1,1,5) 将产生序列 1 2 3 4 5，(5,-1,1) 将产生序列 (5 4 3 2 1)。
使用迭代变量设置起始值 (Start#)，而后逐步执行一组范围的值，直到该值超过所设置的终止值 (End#)。/L 将经过对 Start# 与 End# 进行比较来执行迭代变量。若是 Start# 小于 End#，就会执行该命令。若是迭代变量超过 End#，则命令解释程序退出此循环。还可使用负的 Step# 以递减数值的方式逐步执行此范围内的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 则生成序列 (5 4 3 2 1)。语法是：
看着这说明有点晕吧!我们看例子就不晕了!
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存执行看效果,他会打印从1 2 3 4 5 这样5个数字，(1,1,5)这个参数也就是表示从1开始每次加1直到5终止!
等会晕,就打印个数字有P用...好的知足你们,看这个例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
执行后是否是吓了一跳,怎么多了5个CMD窗口,呵呵!若是把那个 (1,1,5)改为 (1,1,65535)会有什么结果,我先告诉你们,会打开65535个CMD窗口....这么多你不死机算你强!
固然咱们也能够把那个start cmd改为md %%i 这样就会创建指定个目录了!!!名字为1-65535
看完这个被我赋予破坏性质的参数后,咱们来看最后一个参数。

5)、参数 /F
迭代及文件解析
使用文件解析来处理命令输出、字符串及文件内容。使用迭代变量定义要检查的内容或字符串，并使用各类options选项进一步修改解析方式。使用options令牌选项指定哪些令牌应该做为迭代变量传递。请注意：在没有使用令牌选项时，/F 将只检查第一个令牌。
文件解析过程包括读取输出、字符串或文件内容，将其分红独立的文本行以及再将每行解析成零个或更多个令牌。而后经过设置为令牌的迭代变量值，调用 for 循环。默认状况下，/F 传递每一个文件每一行的第一个空白分隔符号。跳过空行。
详细的帮助格式为：
FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]
带引号的字符串"options"包括一个或多个
指定不一样解析选项的关键字。这些关键字为：
eol=c --- 指一个行注释字符的结尾(就一个)
skip=n --- 指在文件开始时忽略的行数。
delims=xxx --- 指分隔符集。这个替换了空格和跳格键的默认分隔符集。
tokens=x,y,m-n --- 指每行的哪个符号被传递到每一个迭代的 for 自己。这会致使额外变量名称的分配。m-n格式为一个范围。经过 nth 符号指定 mth。若是符号字符串中的最后一个字符星号，那么额外的变量将在最后一个符号解析以后分配并接受行的保留文本。经测试，该参数最多只能区分31个字段。
usebackq --- 使用后引号（键盘上数字1左面的那个键`）。

未使用参数usebackq时：

file-set表示文件，但不能含有空格
双引号表示字符串，即"string"
单引号表示执行命令，即'command'
使用参数usebackq时：file-set和"file-set"都表示文件
当文件路径或名称中有空格时，就能够用双引号括起来
单引号表示字符串，即'string'
后引号表示命令执行，即`command`
以上是用for /?命令得到的帮助信息，直接复制过来的。
晕惨了!我这就举个例子帮助你们来理解这些参数!

For命令例1：****************************************
@echo off
rem 首先创建临时文件test.txt
echo ;注释行,这是临时文件,用完删除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt
运行显示结果：
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
请按任意键继续. . .
为何会这样?我来解释：
eol=; 分号开头的行为注释行
tokens=1,3* 将每行第1段,第3段和剩余字段分别赋予变量%%i，%%j，%%k
delims=,- （减号后有一空格）以逗号减号和空格为分隔符，空格必须放在最后

For命令例2：****************************************
@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause
运行将显示test.txt所有内容，包括注释行，不解释了哈。

For命令例3：****************************************
另外/F参数还能够以输出命令的结果看这个例子
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
这样你本机所有账号名字就出来了把扩号内的内容用两个单引号引发来就表示那个当命令执行,FOR会返回命令的每行结果,加那个"delims=" 是为了让我空格的行能整行显示出来,不加就只显示空格左边一列!

基本上讲完了FOR的基本用法了...若是你看过FOR的系统帮助,你会发现他下面还有一些特定义的变量,这些我先不讲.你们因该都累了吧!你不累我累啊....
所谓文武之道，一张一弛，现休息一下。

FOR命令中的变量

FOR命令中有一些变量,他们的用法许多新手朋友还不太了解,今天给你们讲解他们的用法!
先把FOR的变量所有列出来:
~I - 删除任何引号(")，扩展 %I
%~fI - 将 %I 扩展到一个彻底合格的路径名
%~dI - 仅将 %I 扩展到一个驱动器号
%~pI - 仅将 %I 扩展到一个路径
%~nI - 仅将 %I 扩展到一个文件名
%~xI - 仅将 %I 扩展到一个文件扩展名
%~sI - 扩展的路径只含有短名
%~aI - 将 %I 扩展到文件的文件属性
%~tI - 将 %I 扩展到文件的日期/时间
%~zI - 将 %I 扩展到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩展到找到的第一个彻底合格的名称。若是环境变量名未被定义，或者没有找到文件，此组合键会扩展到空字符串

咱们能够看到每行都有一个大写字母"I",这个I其实就是咱们在FOR带入的变量,咱们FOR语句代入的变量名是什么,这里就写什么.
好比:FOR /F %%z IN ('set') DO @echo %%z
这里咱们代入的变量名是z那么咱们就要把那个I改为z,例如 %~fI改成%~fz
至于前面的%~p这样的内容就是语法了!

好开始讲解:

1)、 ~I - 删除任何引号(")，扩展 %I
这个变量的做用就如他的说明,删除引号!
咱们来看这个例子:
首先创建临时文件temp.txt，内容以下
"1111
"2222"
3333"
"4444"44
"55"55"55
可创建个BAT文件代码以下:
@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt
rem 上面创建临时文件，注意不成对的引号要加转义字符^，重定向符号前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo %%~i
pause
del temp.txt

执行后,咱们看CMD的回显以下:
1111 #字符串前的引号被删除了
2222 #字符串首尾的引号都被删除了
3333" #字符串前无引号，后面的引号保留
4444"44 #字符串前面的引号删除了，而中间的引号保留
55"55"55 #字符串前面的引号删除了，而中间的引号保留
请按任意键继续. . .
和以前temp.txt中的内容对比一下,咱们会发现第一、二、5行的引号都消失了,这就是删除引号~i的做用了!
删除引号规则以下(BAT兄补充!)
一、若字符串首尾同时存在引号，则删除首尾的引号；
二、若字符串尾不存在引号，则删除字符串首的引号；
三、若是字符串中间存在引号，或者只在尾部存在引号，则不删除。
龙卷风补充：无头不删，有头连尾删。

2)、 %~fI - 将 %I 扩展到一个彻底合格的路径名
看例子:
把代码保存放在随便哪一个地方,我这里就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~fi
pause
执行后显示内容以下:
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
当我把代码中的 %%~fi直接改为%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%i
pause
执行后就会显示如下内容：
test.bat
test.vbs
经过对比,咱们很容易就看出没有路径了,这就是"将 %I 扩展到一个彻底合格的路径名"的做用
也就是若是%i变量的内容是一个文件名的话,他就会把这个文件所在的绝对路径打印出来,而不仅单单打印一个文件名,本身动手动实验下就知道了!

3)、 %~dI - 仅将 %I 扩展到一个驱动器号
看例子:
代码以下,我仍是放到桌面执行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~di
pause
执行后我CMD里显示以下
C:
C:
我桌面就两个文件test.bat,test.vbs,%%~di做用是,若是变量%%i的内容是一个文件或者目录名,他就会把他这文件
或者目录所在的盘符号打印出来!

4)、 %~pI - 仅将 %I 扩展到一个路径
这个用法和上面同样,他只打印路径不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~pi
pause
我就不打结果了,你们本身复制代码看结果吧,下面几个都是这么个用法,代码给出来,你们本身看结果吧!

5)、 %~nI - 仅将 %I 扩展到一个文件名
只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ni
pause

6)、 %~xI - 仅将 %I 扩展到一个文件扩展名
只打印文件的扩展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~xi
pause

7)、 %~sI - 扩展的路径只含有短名
打印绝对短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~si
pause

8)、 %~aI - 将 %I 扩展到文件的文件属性
打印文件的属性
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ai
pause

9)、 %~tI - 将 %I 扩展到文件的日期/时间
打印文件创建的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ti
pause

10)、 %~zI - 将 %I 扩展到文件的大小
打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~zi
pause
上面例子中的"delims=="能够改成"delims="，即不要分隔符

11)、 %~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩展到找到的第一个彻底合格的名称。若是环境变量名未被定义，或者没有找到文件，此组合键会扩展到空字符串。

这是最后一个,和上面那些都不同,我单独说说!

而后在把这些代码保存为批处理,放在桌面。
@echo off
FOR /F "delims=" %%i IN (“notepad.exe”) DO echo %%~$PATH:i
pause

龙卷风补充：上面代码显示结果为C:\WINDOWS\system32\notepad.exe
他的意思就在PATH变量里指定的路径里搜索notepad.exe文件，若是有notepad.exe则会把他所在绝对路径打印出来，没有就打印一个错误！

好了,FOR的的变量就介绍到这了!

批处理中的变量

批处理中的变量,我把他分为两类,分别为"系统变量"和"自定义变量"。
咱们如今来详解这两个变量!

1)、系统变量
他们的值由系统将其根据事先定义的条件自动赋值,也就是这些变量系统已经给他们定义了值,
不须要咱们来给他赋值,咱们只须要调用而以! 我把他们所有列出来!

%ALLUSERSPROFILE% 本地返回“全部用户”配置文件的位置。
%APPDATA% 本地返回默认状况下应用程序存储数据的位置。
%CD% 本地返回当前目录字符串。
%CMDCMDLINE% 本地返回用来启动当前的 Cmd.exe 的准确命令行。
%CMDEXTVERSION% 系统返回当前的“命令处理程序扩展”的版本号。
%COMPUTERNAME% 系统返回计算机的名称。
%COMSPEC% 系统返回命令行解释器可执行程序的准确路径。
%DATE% 系统返回当前日期。使用与 date /t 命令相同的格式。由 Cmd.exe 生成。有关date 命令的详细信息，请参阅 Date。
%ERRORLEVEL% 系统返回上一条命令的错误代码。一般用非零值表示错误。
%HOMEDRIVE% 系统返回链接到用户主目录的本地工做站驱动器号。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。
%HOMEPATH% 系统返回用户主目录的完整路径。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。
%HOMESHARE% 系统返回用户的共享主目录的网络路径。基于主目录值而设置。用户主目录是在“本地用户和组”中指定的。
%LOGONSERVER% 本地返回验证当前登陆会话的域控制器的名称。
%NUMBER_OF_PROCESSORS% 系统指定安装在计算机上的处理器的数目。
%OS% 系统返回操做系统名称。Windows 2000 显示其操做系统为 Windows_NT。
%PATH% 系统指定可执行文件的搜索路径。
%PATHEXT% 系统返回操做系统认为可执行的文件扩展名的列表。
%PROCESSOR_ARCHITECTURE% 系统返回处理器的芯片体系结构。值：x86 或 IA64 基于Itanium
%PROCESSOR_IDENTFIER% 系统返回处理器说明。
%PROCESSOR_LEVEL% 系统返回计算机上安装的处理器的型号。
%PROCESSOR_REVISION% 系统返回处理器的版本号。
%PROMPT% 本地返回当前解释程序的命令提示符设置。由 Cmd.exe 生成。
%RANDOM% 系统返回 0 到 32767 之间的任意十进制数字。由 Cmd.exe 生成。
%SYSTEMDRIVE% 系统返回包含 Windows server operating system 根目录（即系统根目录）的驱动器。
%SYSTEMROOT% 系统返回 Windows server operating system 根目录的位置。
%TEMP% 和 %TMP% 系统和用户返回对当前登陆用户可用的应用程序所使用的默认临时目录。有些应用程序须要 TEMP，而其余应用程序则须要 TMP。
%TIME% 系统返回当前时间。使用与 time /t 命令相同的格式。由 Cmd.exe 生成。有关time 命令的详细信息，请参阅 Time。
%USERDOMAIN% 本地返回包含用户账户的域的名称。
%USERNAME% 本地返回当前登陆的用户的名称。
%USERPROFILE% 本地返回当前用户的配置文件的位置。
%WINDIR% 系统返回操做系统目录的位置。

这么多系统变量,咱们如何知道他的值是什么呢?
在CMD里输入 echo %WINDIR%
这样就能显示一个变量的值了!
举个实际例子,好比咱们要复制文件到当前账号的启动目录里就能够这样
copy d:\1.bat "%USERPROFILE%\「开始」菜单\程序\启动\"
%USERNAME% 本地返回当前登陆的用户的名称。
注意有空格的目录要用引号引发来

另外还有一些系统变量,他们是表明一个意思,或者一个操做!
他们分别是%0 %1 %2 %3 %4 %5 ......一直到%9 还有一个%*
%0 这个有点特殊,有几层意思,先讲%1-%9的意思.
%1 返回批处理的第一个参数
%2 返回批处理的第二个参数
%3-%9依此推类
反回批处理参数?到底怎么个返回法?
咱们看这个例子,把下面的代码保存为test.BAT而后放到C盘下
@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4
进入CMD,输入cd c:\
而后输入 test.bat 我是第一个参数我是第二个参数我是第三个参数我是第四个参数
注意中间的空格,咱们会看到这样的结果:
我是第一个参数我是第二个参数我是第三个参数我是第四个参数
我是第一个参数
我是第二个参数
我是第三个参数
我是第四个参数
对比下代码,%1就是”我是第一个参数” %2就是”我是第二个参数”。
怎么样理解了吧!
这些%1和%9可让批处理也能带参数运行,大大提升批处理功能!
还有一个%* 他是什么呢?他的做用不是很大,只是返回参数而已,不过他是一次返回所有参数的值,不用在输入%1 %2来肯定一个个的

例子
@echo off
echo %*
一样保存为test.bat 放到C盘
进入CMD,输入cd c:\
而后输入 test.bat 我是第一个参数我是第二个参数我是第三个参数我是第四个参数
能够看到他一次把所有参数都显示出来了。好，如今开始讲那个比较特殊的%0

%0 这个不是返回参数的值了,他有两层意思!
第一层意思:返回批处理所在绝对路径
例子:
@echo off
echo %0
pause
保存为test.BAT放在桌面运行,会显示以下结果
"C:\Documents and Settings\Administrator\桌面\test.bat"
他把当前批处理执行的所在路经打印出来了,这就是返回批处理所在绝对路径的意思
第二层意思:无限循环执行BAT
例子:
@echo off
net user
%0
保存为BAT执行,他就会无限循环执行net user这条命令,直到你手动中止。
龙卷风补充：其实%0就是第一参数%1前面那个参数，固然就是批处理文件名（包括路径）。
以上就是批处理中的一些系统变量,另外还有一些变量,他们也表示一些功能,FOR命令中的那些就是,FOR变量已经说过,就不讲了。

2)、自定义变量
故名思意,自定义变量就是由咱们来给他赋予值的变量。
要使用自定义变量就得使用set命令了,看例子。
@echo off
set var=我是值
echo %var%
pause
保存为BAT执行,咱们会看到CMD里返回一个 "我是值"
var为变量名,=号右变的是要给变量的值。

这就是最简单的一种设置变量的方法了。若是咱们想让用户手工输入变量的值,而不是在代码里指定,能够用用set命令的/p参数例子:@echo offset /p var=请输入变量的值echo %var%pausevar变量名 =号右边的是提示语,不是变量的值。变量的值由咱们运行后本身用键盘输入!