智能合约语言 Solidity 教程系列10 - 彻底理解函数修改器

本文首发于深刻浅出区块链社区
原文连接:智能合约语言 Solidity 教程系列10 - 彻底理解函数修改器原文已更新，请读者前往原文阅读

这是Solidity教程系列文章第10篇，带你们彻底理解Solidity的函数修改器。
Solidity系列完整的文章列表请查看分类-Solidity。

写在前面

Solidity 是以太坊智能合约编程语言，阅读本文前，你应该对以太坊、智能合约有所了解，
若是你还不了解，建议你先看以太坊是什么

欢迎订阅区块链技术专栏阅读更全面的分析文章。

函数修改器(Function Modifiers)

函数修改器(Modifiers)能够用来改变一个函数的行为。好比用于在函数执行前检查某种前置条件。

若是熟悉Python的同窗，会发现函数修改器的做用和Python的装饰器很类似。

修改器是一种可被继承合约属性，同时还可被继承的合约重写(override)。下面咱们来看一段示例代码：

pragma solidity ^0.4.11;

contract owned {
    function owned() public { owner = msg.sender; }
    address owner;

    // 定义了一个函数修改器，可被继承
    //  修饰时，函数体被插入到 “_;” 处
    // 不符合条件时，将抛出异常
    modifier onlyOwner {
        require(msg.sender == owner);
        _;
    }
}

contract mortal is owned {
    //  使用继承的`onlyOwner` 
    function close() public onlyOwner {
        selfdestruct(owner);
    }
}

contract priced {
    // 函数修改器可接收参数
    modifier costs(uint price) {
        if (msg.value >= price) {
            _;
        }
    }
}

contract Register is priced, owned {
    mapping (address => bool) registeredAddresses;
    uint price;

    function Register(uint initialPrice) public { price = initialPrice; }

    // 须要提供payable 以接受以太
    function register() public payable costs(price) {
        registeredAddresses[msg.sender] = true;
    }

    function changePrice(uint _price) public onlyOwner {
        price = _price;
    }
}

上面onlyOwner就是定义的一个函数修改器，当用这个修改器区修饰一个函数时，则函数必须知足onlyOwner的条件才能运行，这里的条件是：必须是合约的建立这才能调用函数，不然抛出异常。
咱们在实现一个可管理、增发、兑换、冻结等高级功能的代币文章中就使用了这个函数修改器。

多个修改器

若是同一个函数有多个修改器，他们之间以空格隔开，修饰器会依次检查执行。

在修改器中或函数内的显式的return语句，仅仅跳出当前的修改器或函数。返回的变量会被赋值，但执行流会在前一个修改器后面定义的"_"后继续执行， 如：

contract Mutex {
    bool locked;
    modifier noReentrancy() {
        require(!locked);
        locked = true;
        _;
        locked = false;
    }

    // 防止递归调用
    // return 7 以后，locked = false 依然会执行
    function f() public noReentrancy returns (uint) {
        require(msg.sender.call());
        return 7;
    }
}

修改器的参数能够是任意表达式。在此上下文中，全部的函数中引入的符号，在修改器中都可见。但修改器中引入的符号在函数中不可见，由于它们有可能被重写。

深刻理解修改器的执行次序

再来看一个复杂一点的例子，来深刻理解修改器：

pragma solidity ^0.4.11;


contract modifysample {

    uint a = 10;
    
    modifier mf1 (uint b) {
        uint c = b;
        _;
        c = a;
        a = 11;
    }
    
     modifier mf2 () {
        uint c = a;
        _;
    }
    
    modifier mf3() {
        a = 12;
        return ;
        _;
        a = 13;
    }
    
    function test1() mf1(a) mf2 mf3 public   {
        a = 1;
    }
    
     function test2() public constant returns (uint)   {
        return a;  
    }  
}

上面的智能合约运行test1()以后，状态变量a的值是多少， 是1， 11， 12，仍是13呢？
答案是 11, 你们能够运行下test2获取下a值。

咱们来分析一下 test1， 它扩展以后是这样的：

uint c = b;
        uint c = a;
            a = 12;
            return ;
            _;
            a = 13;
c = a;
a = 11;

这个时候就一目了然了，最后a 为11， 注意第5及第6行是否是执行的。

参考视频

咱们也推出了目前市面上最全的视频教程：深刻详解以太坊智能合约语言Solidity
目前咱们也在招募体验师，能够点击连接了解。

参考文献

官方文档-Function Modifiers

☛ 深刻浅出区块链 - 系统学习区块链，打造最好的区块链技术博客。

☛ 个人知识星球为各位解答区块链技术问题，欢迎加入讨论。

☛ 关注公众号“深刻浅出区块链技术”第一时间获取区块链技术信息。