UFT开发代码实例：将Excel中的数据保存为数组

一、核心代码 

'读取Excel表格到一个数组的函数
' 输入：
'             sFileName： Excel文件
'             sSheetName：表单名称
' 返回：
'             包含Excel数据的数组
Function ReadFile(sFileName,sSheetName)
       Dim oExcel
       Dim oSheet
       Dim oRange
       Dim arrRange
       On Error Resume Next
           ' 建立Excel应用程序对象
              Set oExcel = CreateObject("Excel.Application")
              If err.Number <> 0 Then
                     MsgBox "未能初始化Excel" & vbCrLf & _
                                 "请确保Excel已安装", vbCritical
                     Exit Function
              End If
       On Error Goto 0
       On Error Resume Next
                     ' 打开Excel文件
                     oExcel.Workbooks.Open(sFileName)
                  If err.Number <> 0 Then
                            MsgBox "未能加载Excel文件" & vbCrLf & _
                                   "请确保Excel文件路径正确或格式正确", vbCritical
                            Exit Function
                     End If
       On Error Goto 0      
       ' 获取表格的使用范围
       Set oSheet = oExcel.Worksheets(sSheetName).UsedRange
       ' 获取从A列到Z列，从第1行到第1000行的范围i中的全部值
       Set oRange = oSheet.Range("A1:Z1000")
       '把Excel数据转换到数组
       arrRange = oRange.Value
       ' 关闭工做簿
       oExcel.WorkBooks.Item(1).Close
       ' 退出Excel
       oExcel.Quit
       Set oExcel = Nothing
    ' 返回包含Excel数据的数组
     ReadFile = arrRange
End Function

arrRange = ReadFile("C:\Documents and Settings\Administrator\桌面\test1.xls","Sheet1") 
'Msgbox UBound (arrRange,1)
'Msgbox UBound (arrRange,2)
' 读取其中一个单元格的数据

For i=1 to 10
	For k = 1 to 2

Msgbox arrRange(i,k)

	Next
Next

二、完整工程

解压后导入UFT中便可。

https://yunpan.cn/cBVx3mFvLgSi8 （提取码：a8d8）