AT&T的汇编格式&X86内联汇编

时间 2019-11-09

标签 at&t 汇编格式 x86 内联繁體版

原文原文链接

AT&T的汇编格式
一　基本语法
语法上主要有如下几个不一样.
★ 寄存器命名原则
AT&T: %eax Intel: eax
★源/目的操做数顺序
AT&T: movl %eax,%ebx Intel: mov ebx,eax
★常数/当即数的格式
AT&T: movl $_value,%ebx Intel: mov eax,_value
把_value的地址放入eax寄存器
AT&T: movl $0xd00d,%ebx Intel: mov ebx,0xd00d
★ 操做数长度标识
AT&T: movw %ax,%bx Intel: mov bx,ax
★寻址方式
AT&T: immed32(basepointer,indexpointer,indexscale)
Intel: [basepointer + indexpointer*indexscale + imm32)
Linux工做于保护模式下，用的是３２位线性地址，因此在计算地址时不用考虑segment:offset的问题．上式中的地址应为：
imm32 + basepointer + indexpointer*indexscale
下面是一些例子：
★直接寻址
AT&T: _booga　; _booga是一个全局的C变量
注意加上$是表示地址引用，不加是表示值引用．
注：对于局部变量，能够经过堆栈指针引用．
Intel: [_booga]
★寄存器间接寻址
AT&T: (%eax)
Intel: [eax]
★变址寻址
AT&T: _variable(%eax)
Intel: [eax + _variable]
AT&T: _array(,%eax,4)
Intel: [eax*4 + _array]
AT&T: _array(%ebx,%eax,8)
Intel: [ebx + eax*8 + _array]
二　基本的行内汇编
?基本的行内汇编很简单，通常是按照下面的格式:
      asm("statements");
例如：asm("nop"); asm("cli");
?asm　和　__asm__是彻底同样的．
?若是有多行汇编，则每一行都要加上　"＼n＼t"
例如：
asm( "pushl %eax＼n＼t"
"movl $0,%eax＼n＼t"
"popl %eax");
实际上gcc在处理汇编时，是要把asm(...)的内容"打印"到汇编文件中，因此格式控制字符是必要的．
再例如：
asm("movl %eax,%ebx");
asm("xorl %ebx,%edx");
asm("movl $0,_booga);
在上面的例子中，因为咱们在行内汇编中改变了edx和ebx的值，可是因为gcc的特殊的处理方法，即先造成汇编文件，再交给GAS去汇编，因此GAS并不知道咱们已经改变了edx和ebx的值，若是程序的上下文须要edx或ebx做暂存，这样就会引发严重的后果．对于变量_booga也存在同样的问题．为了解决这个问题，就要用到扩展的行内汇编语法．
三　扩展的行内汇编
扩展的行内汇编相似于Watcom.
基本的格式是：
asm ( "statements" : output_regs : input_regs : clobbered_regs);
clobbered_regs指的是被改变的寄存器．
下面是一个例子(为方便起见，我使用全局变量）：
int count=1;
int value=1;
int buf[10];
void main()
{
asm(
"cld ＼n＼t"
"rep ＼n＼t"
"stosl"
:
: "c" (count), "a" (value) , "D" (buf[0])
: "%ecx","%edi" );
}
获得的主要汇编代码为：
movl count,%ecx
movl value,%eax
movl buf,%edi
#APP
cld
rep
stosl
#NO_APP
cld,rep,stos就不用多解释了．这几条语句的功能是向buf中写上count个value值．冒号后的语句指明输入，输出和被改变的寄存器．经过冒号之后的语句，编译器就知道你的指令须要和改变哪些寄存器，从而能够优化寄存器的分配．
其中符号"c"(count)指示要把count的值放入ecx寄存器
相似的还有：
a eax
b ebx
c ecx
d edx
S esi
D edi
I 常数值，(0 - 31)
q,r 动态分配的寄存器
g eax,ebx,ecx,edx或内存变量
A 把eax和edx合成一个64位的寄存器(use long longs)
咱们也可让gcc本身选择合适的寄存器．
以下面的例子：
asm("leal (%1,%1,4),%0"
: "=r" (x)
: "0" (x) );
这段代码实现5*x的快速乘法．
获得的主要汇编代码为：
movl x,%eax
#APP
leal (%eax,%eax,4),%eax
#NO_APP
movl %eax,x
几点说明：
1.使用q指示编译器从eax,ebx,ecx,edx分配寄存器．使用r指示编译器从eax,ebx,ecx,edx,esi,edi分配寄存器．
2.咱们没必要把编译器分配的寄存器放入改变的寄存器列表，由于寄存器已经记住了它们．
3."="是标示输出寄存器，必须这样用．
4.数字%n的用法：
数字表示的寄存器是按照出现和从左到右的顺序映射到用"r"或"q"请求的寄存器．若是咱们要重用"r"或"q"请求的寄存器的话，就可使用它们．
5.若是强制使用固定的寄存器的话，如不用%1,而用ebx,则asm("leal (%%ebx,%%ebx,4),%0"
: "=r" (x)
: "0" (x) );
注意要使用两个%,由于一个%的语法已经被%n用掉了．
下面能够来解释letter 4854-4855的问题：
一、变量加下划线和双下划线有什么特殊含义吗？
加下划线是指全局变量，但个人gcc中加不加都无所谓．
二、以上定义用以下调用时展开会是什么意思？
#define _syscall1(type,name,type1,arg1) ＼
type name(type1 arg1) ＼
{ ＼
long __res; ＼
/* __res应该是一个全局变量　*/
__asm__ volatile ("int $0x80" ＼
/* volatile 的意思是不容许优化，使编译器严格按照你的汇编代码汇编*/
: "=a" (__res) ＼
/* 产生代码　movl %eax, __res */
: "0" (__NR_##name),"b" ((long)(arg1))); ＼
/* 若是我没记错的话，这里##指的是两次宏展开．
　　即用实际的系统调用名字代替"name",而后再把__NR_...展开．
　　接着把展开的常数放入eax，把arg1放入ebx */
if (__res >= 0) ＼
return (type) __res; ＼
errno = -__res; ＼
return -1; ＼
}
[目录]
x86内联汇编
本文提供了在 Linux 平台上使用和构造 x86 内联汇编的归纳性介绍。他介绍了内联汇编及其各类用法的基础知识，提供了一些基本的内联汇编编码指导，并解释了在 Linux 内核中内联汇编代码的一些实例。
若是您是 Linux 内核的开发人员，您会发现本身常常要对与体系结构高度相关的功能进行编码或优化代码路径。您极可能是经过将汇编语言指令插入到 C 语句的中间（又称为内联汇编的一种方法）来执行这些任务的。让咱们看一下 Linux 中内联汇编的特定用法。（咱们将讨论限制在 IA32 汇编。）
[目录]
简述
GNU 汇编程序简述
让咱们首先看一下 Linux 中使用的基本汇编程序语法。GCC（用于 Linux 的 GNU C 编译器）使用 AT&T 汇编语法。下面列出了这种语法的一些基本规则。（该列表确定不完整；只包括了与内联汇编相关的那些规则。）
寄存器命名
寄存器名称有 % 前缀。即，若是必须使用 eax，它应该用做 %eax。
源操做数和目的操做数的顺序
在全部指令中，先是源操做数，而后才是目的操做数。这与将源操做数放在目的操做数以后的 Intel 语法不一样。
mov %eax, %ebx, transfers the contents of eax to ebx.
操做数大小
根据操做数是字节 (byte)、字 (word) 仍是长型 (long)，指令的后缀能够是 b、w 或 l。这并非强制性的；GCC 会尝试经过读取操做数来提供相应的后缀。但手工指定后缀能够改善代码的可读性，并能够消除编译器猜想不正确的可能性。
movb %al, %bl -- Byte move
movw %ax, %bx -- Word move
movl %eax, %ebx -- Longword move
当即操做数
经过使用 $ 指定直接操做数。
movl $0xffff, %eax -- will move the value of 0xffff into eax register.
间接内存引用
任何对内存的间接引用都是经过使用 ( ) 来完成的。
movb (%esi), %al -- will transfer the byte in the memory
pointed by esi into al register
[目录]
内联汇编
内联汇编
GCC 为内联汇编提供特殊结构，它具备如下格式：
asm ( assembler template
      : output operands             (optional)
      : input operands             (optional)
      : list of clobbered registers (optional)
      );
本例中，汇编程序模板由汇编指令组成。输入操做数是充当指令输入操做数使用的 C 表达式。输出操做数是将对其执行汇编指令输出的 C 表达式。
内联汇编的重要性体如今它可以灵活操做，并且可使其输出经过 C 变量显示出来。由于它具备这种能力，因此 "asm" 能够用做汇编指令和包含它的 C 程序之间的接口。
一个很是基本但很重要的区别在于简单内联汇编只包括指令，而扩展内联汇编包括操做数。要说明这一点，考虑如下示例：
内联汇编的基本要素
{
int a=10, b;
asm ("movl %1, %%eax;
      movl %%eax, %0;"
      :"=r"(b)  /* output */
      :"r"(a)    /* input */
      :"%eax"); /* clobbered register */
}
在上例中，咱们使用汇编指令使 "b" 的值等于 "a"。请注意如下几点：
"b" 是输出操做数，由 %0 引用，"a" 是输入操做数，由 %1 引用。
"r" 是操做数的约束，它指定将变量 "a" 和 "b" 存储在寄存器中。请注意，输出操做数约束应该带有一个约束修饰符 "="，指定它是输出操做数。
要在 "asm" 内使用寄存器 %eax，%eax 的前面应该再加一个 %，换句话说就是 %%eax，由于 "asm" 使用 %0、%1 等来标识变量。任何带有一个 % 的数都看做是输入／输出操做数，而不认为是寄存器。
第三个冒号后的修饰寄存器 %eax 告诉将在 "asm" 中修改 GCC %eax 的值，这样 GCC 就不使用该寄存器存储任何其它的值。
movl %1, %%eax 将 "a" 的值移到 %eax 中，movl %%eax, %0 将 %eax 的内容移到 "b" 中。
由于 "b" 被指定成输出操做数，所以当 "asm" 的执行完成后，它将反映出更新的值。换句话说，对 "asm" 内 "b" 所作的更改将在 "asm" 外反映出来。
[目录]
程序模板
汇编程序模板是一组插入到 C 程序中的汇编指令（能够是单个指令，也能够是一组指令）。每条指令都应该由双引号括起，或者整组指令应该由双引号括起。每条指令还应该用一个定界符结尾。有效的定界符为新行 (＼n) 和分号 (;)。 ’＼n’ 后能够跟一个 tab(＼t) 做为格式化符号，增长 GCC 在汇编文件中生成的指令的可读性。指令经过数 %0、%1 等来引用 C 表达式（指定为操做数）。
若是但愿确保编译器不会在 "asm" 内部优化指令，能够在 "asm" 后使用关键字 "volatile"。若是程序必须与 ANSI C 兼容，则应该使用 __asm__ 和 __volatile__，而不是 asm 和 volatile。
[目录]
操做数
C 表达式用做 "asm" 内的汇编指令操做数。在汇编指令经过对 C 程序的 C 表达式进行操做来执行有意义的做业的状况下，操做数是内联汇编的主要特性。
每一个操做数都由操做数约束字符串指定，后面跟用括弧括起的 C 表达式，例如："constraint" (C expression)。操做数约束的主要功能是肯定操做数的寻址方式。
能够在输入和输出部分中同时使用多个操做数。每一个操做数由逗号分隔开。
在汇编程序模板内部，操做数由数字引用。若是总共有 n 个操做数（包括输入和输出），那么第一个输出操做数的编号为 0，逐项递增，最后那个输入操做数的编号为 n-1。总操做数的数目限制在 10，若是机器描述中任何指令模式中的最大操做数数目大于 10，则使用后者做为限制。
[目录]
修饰寄存器列表
若是 "asm" 中的指令指的是硬件寄存器，能够告诉 GCC 咱们将本身使用和修改它们。这样，GCC 就不会假设它装入到这些寄存器中的值是有效值。一般不须要将输入和输出寄存器列为 clobbered，由于 GCC 知道 "asm" 使用它们（由于它们被明确指定为约束）。不过，若是指令使用任何其它的寄存器，不管是明确的仍是隐含的（寄存器不在输入约束列表中出现，也不在输出约束列表中出现），寄存器都必须被指定为修饰列表。修饰寄存器列在第三个冒号以后，其名称被指定为字符串。
至于关键字，若是指令以某些不可预知且不明确的方式修改了内存，则可能将 "memory" 关键字添加到修饰寄存器列表中。这样就告诉 GCC 不要在不一样指令之间将内存值高速缓存在寄存器中。
[目录]
操做数约束
前面提到过，"asm" 中的每一个操做数都应该由操做数约束字符串描述，后面跟用括弧括起的 C 表达式。操做数约束主要是肯定指令中操做数的寻址方式。约束也能够指定：
?是否容许操做数位于寄存器中，以及它能够包括在哪些种类的寄存器中
?操做数是否能够是内存引用，以及在这种状况下使用哪些种类的地址
?操做数是否能够是当即数
约束还要求两个操做数匹配。
经常使用约束
在可用的操做数约束中，只有一小部分是经常使用的；下面列出了这些约束以及简要描述。有关操做数约束的完整列表，请参考 GCC 和 GAS 手册。
寄存器操做数约束 (r)
使用这种约束指定操做数时，它们存储在通用寄存器中。请看下例：
         asm ("movl %%cr3, %0＼n" :"=r"(cr3val));
这里，变量 cr3val 保存在寄存器中，%cr3 的值复制到寄存器上，cr3val 的值从该寄存器更新到内存中。指定 "r" 约束时，GCC 能够将变量 cr3val 保存在任何可用的 GPR 中。要指定寄存器，必须经过使用特定的寄存器约束直接指定寄存器名。
a %eax
b %ebx
c %ecx
d %edx
S %esi
D %edi
内存操做数约束 (m)
当操做数位于内存中时，任何对它们执行的操做都将在内存位置中直接发生，这与寄存器约束正好相反，后者先将值存储在要修改的寄存器中，而后将它写回内存位置中。但寄存器约束一般只在对于指令来讲它们是绝对必需的，或者它们能够大大提升进程速度时使用。当须要在 "asm" 内部更新 C 变量，而您又确实不但愿使用寄存器来保存其值时，使用内存约束最为有效。例如，idtr 的值存储在内存位置 loc 中：
      ("sidt %0＼n" : :"m"(loc));
匹配（数字）约束
在某些状况下，一个变量既要充当输入操做数，也要充当输出操做数。能够经过使用匹配约束在 "asm" 中指定这种状况。
      asm ("incl %0" :"=a"(var):"0"(var));
在匹配约束的示例中，寄存器 %eax 既用做输入变量，也用做输出变量。将 var 输入读取到 %eax，增长后将更新的 %eax 再次存储在 var 中。这里的 "0" 指定第 0 个输出变量相同的约束。即，它指定 var 的输出实例只应该存储在 %eax 中。该约束能够用于如下状况：
?输入从变量中读取，或者变量被修改后，修改写回到同一变量中
?不须要将输入操做数和输出操做数的实例分开
?使用匹配约束最重要的意义在于它们能够致使有效地使用可用寄存器。

示例
通常内联汇编用法示例
如下示例经过各类不一样的操做数约束说明了用法。有如此多的约束以致于没法将它们一一列出，这里只列出了最常用的那些约束类型。
寄存器约束
"asm" 和寄存器约束 "r"
让咱们先看一下使用寄存器约束 r 的 "asm"。咱们的示例显示了 GCC 如何分配寄存器，以及它如何更新输出变量的值。
int main(void)
{
int x = 10, y;
asm ("movl %1, %%eax;
      "movl %%eax, %0;"
      :"=r"(y)  /* y is output operand */
      :"r"(x)    /* x is input operand */
      :"%eax"); /* %eax is clobbered register */
}
在该例中，x 的值复制为 "asm" 中的 y。x 和 y 都经过存储在寄存器中传递给 "asm"。为该例生成的汇编代码以下：
main:
pushl %ebp
movl %esp,%ebp
subl $8,%esp
movl $10,-4(%ebp)
movl -4(%ebp),%edx  /* x=10 is stored in %edx */
#APP /* asm starts here */
movl %edx, %eax    /* x is moved to %eax */
movl %eax, %edx    /* y is allocated in edx and updated */
#NO_APP /* asm ends here */
movl %edx,-8(%ebp)  /* value of y in stack is updated with the value in %edx */
当使用 "r" 约束时，GCC 在这里能够自由分配任何寄存器。在咱们的示例中，它选择 %edx 来存储 x。在读取了 %edx 中 x 的值后，它为 y 也分配了相同的寄存器。
由于 y 是在输出操做数部分中指定的，因此 %edx 中更新的值存储在 -8(%ebp)，堆栈上 y 的位置中。若是 y 是在输入部分中指定的，那么即便它在 y 的临时寄存器存储值 (%edx) 中被更新，堆栈上 y 的值也不会更新。
由于 %eax 是在修饰列表中指定的，GCC 不在任何其它地方使用它来存储数据。
输入 x 和输出 y 都分配在同一个 %edx 寄存器中，假设输入在输出产生以前被消耗。请注意，若是您有许多指令，就不是这种状况了。要确保输入和输出分配到不一样的寄存器中，能够指定 & 约束修饰符。下面是添加了约束修饰符的示例。
int main(void)
{
int x = 10, y;
asm ("movl %1, %%eax;
      "movl %%eax, %0;"
      :"=&r"(y) /* y is output operand, note the & constraint modifier. */
      :"r"(x)    /* x is input operand */
      :"%eax"); /* %eax is clobbered register */
}
如下是为该示例生成的汇编代码，从中能够明显地看出 x 和 y 存储在 "asm" 中不一样的寄存器中。
main:
pushl %ebp
movl %esp,%ebp
subl $8,%esp
movl $10,-4(%ebp)
movl -4(%ebp),%ecx  /* x, the input is in %ecx */
#APP
movl %ecx, %eax
movl %eax, %edx    /* y, the output is in %edx */
#NO_APP
movl %edx,-8(%ebp)
特定寄存器约束的使用
如今让咱们看一下如何将个别寄存器做为操做数的约束指定。在下面的示例中，cpuid 指令采用 %eax 寄存器中的输入，而后在四个寄存器中给出输出：%eax、%ebx、%ecx、%edx。对 cpuid 的输入（变量 "op"）传递到 "asm" 的 eax 寄存器中，由于 cpuid 但愿它这样作。在输出中使用 a、b、c 和 d 约束，分别收集四个寄存器中的值。
      asm ("cpuid"
            : "=a" (_eax),
            "=b" (_ebx),
            "=c" (_ecx),
            "=d" (_edx)
            : "a" (op));
在下面能够看到为它生成的汇编代码（假设 _eax、_ebx 等... 变量都存储在堆栈上）：
movl -20(%ebp),%eax /* store ’op’ in %eax -- input */
#APP
cpuid
#NO_APP
movl %eax,-4(%ebp)  /* store %eax in _eax -- output */
movl %ebx,-8(%ebp)  /* store other registers in
movl %ecx,-12(%ebp)
respective output variables */
movl %edx,-16(%ebp)
strcpy 函数能够经过如下方式使用 "S" 和 "D" 约束来实现：
      asm ("cld＼n
            rep＼n
            movsb"
            : /* no input */
            :"S"(src), "D"(dst), "c"(count));
经过使用 "S" 约束将源指针 src 放入 %esi 中，使用 "D" 约束将目的指针 dst 放入 %edi 中。由于 rep 前缀须要 count 值，因此将它放入 %ecx 中。
在下面能够看到另外一个约束，它使用两个寄存器 %eax 和 %edx 将两个 32 位的值合并在一块儿，而后生成一个64 位的值：
#define rdtscll(val) ＼
__asm__ __volatile__ ("rdtsc" : "=A" (val))
The generated assembly looks like this (if val has a 64 bit memory space).
#APP
rdtsc
#NO_APP
movl %eax,-8(%ebp)  /* As a result of A constraint
movl %edx,-4(%ebp)
%eax and %edx serve as outputs */
Note here that the values in %edx:%eax serve as 64 bit output.
匹配约束
使用匹配约束
在下面将看到系统调用的代码，它有四个参数：
#define _syscall4(type,name,type1,arg1,type2,arg2,type3,arg3,type4,arg4) ＼
type name (type1 arg1, type2 arg2, type3 arg3, type4 arg4) ＼
{ ＼
long __res; ＼
__asm__ volatile ("int $0x80" ＼
: "=a" (__res) ＼
: "0" (__NR_##name),"b" ((long)(arg1)),"c" ((long)(arg2)), ＼
"d" ((long)(arg3)),"S" ((long)(arg4))); ＼
__syscall_return(type,__res); ＼
}
在上例中，经过使用 b、c、d 和 S 约束将系统调用的四个自变量放入 %ebx、%ecx、%edx 和 %esi 中。请注意，在输出中使用了 "=a" 约束，这样，位于 %eax 中的系统调用的返回值就被放入变量 __res 中。经过将匹配约束 "0" 用做输入部分中第一个操做数约束，syscall 号 __NR_##name 被放入 %eax 中，并用做对系统调用的输入。这样，这里的 %eax 既能够用做输入寄存器，又能够用做输出寄存器。没有其它寄存器用于这个目的。另请注意，输入（syscall 号）在产生输出（syscall 的返回值）以前被消耗（使用）。
内存操做数约束
内存操做数约束的使用
请考虑下面的原子递减操做：
      __asm__ __volatile__(
            "lock; decl %0"
            :"=m" (counter)
            :"m" (counter));
为它生成的汇编相似于：
#APP
lock
decl -24(%ebp) /* counter is modified on its memory location */
#NO_APP.
您可能考虑在这里为 counter 使用寄存器约束。若是这样作，counter 的值必须先复制到寄存器，递减，而后对其内存更新。但这样您会没法理解锁定和原子性的所有意图，这些明确显示了使用内存约束的必要性。
修饰寄存器
使用修饰寄存器
请考虑内存拷贝的基本实现。
   asm ("movl $count, %%ecx;
         up: lodsl;
         stosl;
         loop up;"
         :          /* no output */
         :"S"(src), "D"(dst) /* input */
         :"%ecx", "%eax" );  /* clobbered list */

当 lodsl 修改 %eax 时，lodsl 和 stosl 指令隐含地使用它。%ecx 寄存器明确装入 count。但 GCC 在咱们通知它之前是不知道这些的，咱们是经过将 %eax 和 %ecx 包括在修饰寄存器集中来通知 GCC 的。在完成这一步以前，GCC 假设 %eax 和 %ecx 是自由的，它可能决定将它们用做存储其它的数据。请注意，%esi 和 %edi 由 "asm" 使用，它们不在修饰列表中。这是由于已经声明 "asm" 将在输入操做数列表中使用它们。这里最低限度是，若是在 "asm" 内部使用寄存器（不管是明确仍是隐含地），既不出如今输入操做数列表中，也不出如今输出操做数列表中，必须将它列为修饰寄存器。
html

From: http://www.sudu.cn/info/html/edu/20080425/301547.html
linux

Win32与 Linux汇编语法的区别
程序员

汇编语言的优势是速度快，能够直接对硬件进行操做，这对诸如图形处理等关键应用是很是重要的。Linux 是一个用 C 语言开发的操做系统，这使得不少程序员开始忘记在 Linux 中还能够直接使用汇编这一底层语言来优化程序的性能。本文为那些在Linux 平台上编写汇编代码的程序员提供指南，介绍 Linux 汇编语言的语法格式和开发工具，并辅以具体的例子讲述如何开发实用的Linux 汇编程序。

1、简介express

做为最基本的编程语言之一，汇编语言虽然应用的范围不算很广，但重要性却勿庸置疑，由于它可以完成许多其它语言所没法完成的功能。就拿 Linux 内核来说，虽然绝大部分代码是用 C 语言编写的，但仍然不可避免地在某些关键地方使用了汇编代码，其中主要是在 Linux 的启动部分。因为这部分代码与硬件的关系很是密切，即便是 C 语言也会有些力不从心，而汇编语言则可以很好扬长避短，最大限度地发挥硬件的性能。编程

大多数状况下 Linux 程序员不须要使用汇编语言，由于即使是硬件驱动这样的底层程序在 Linux 操做系统中也能够用彻底用 C 语言来实现，再加上 GCC 这一优秀的编译器目前已经可以对最终生成的代码进行很好的优化，的确有足够的理由让咱们能够暂时将汇编语言抛在一边了。但实现状况是 Linux 程序员有时仍是须要使用汇编，或者不得不使用汇编，理由很简单：精简、高效和 libc 无关性。假设要移植 Linux 到某一特定的嵌入式硬件环境下，首先必然面临如何减小系统大小、提升执行效率等问题，此时或许只有汇编语言能帮上忙了。数组

汇编语言直接同计算机的底层软件甚至硬件进行交互，它具备以下一些优势：缓存

可以直接访问与硬件相关的存储器或 I/O 端口；
可以不受编译器的限制，对生成的二进制代码进行彻底的控制；
可以对关键代码进行更准确的控制，避免因线程共同访问或者硬件设备共享引发的死锁；
可以根据特定的应用对代码作最佳的优化，提升运行速度；
可以最大限度地发挥硬件的功能。

同时还应该认识到，汇编语言是一种层次很是低的语言，它仅仅高于直接手工编写二进制的机器指令码，所以不可避免地存在一些缺点：sass

编写的代码很是难懂，很差维护；
很容易产生 bug，难于调试；
只能针对特定的体系结构和处理器进行优化；
开发效率很低，时间长且单调。

Linux 下用汇编语言编写的代码具备两种不一样的形式。第一种是彻底的汇编代码，指的是整个程序所有用汇编语言编写。尽管是彻底的汇编代码，Linux 平台下的汇编工具也吸取了 C 语言的长处，使得程序员可使用 #include、#ifdef 等预处理指令，并可以经过宏定义来简化代码。第二种是内嵌的汇编代码，指的是能够嵌入到C语言程序中的汇编代码片断。虽然 ANSI 的 C 语言标准中没有关于内嵌汇编代码的相应规定，但各类实际使用的 C 编译器都作了这方面的扩充，这其中固然就包括 Linux 平台下的 GCC。app

回页首

2、Linux 汇编语法格式编程语言

绝大多数 Linux 程序员之前只接触过DOS/Windows 下的汇编语言，这些汇编代码都是 Intel 风格的。但在 Unix 和 Linux 系统中，更多采用的仍是 AT&T 格式，二者在语法格式上有着很大的不一样：

在 AT&T 汇编格式中，寄存器名要加上 '%' 做为前缀；而在 Intel 汇编格式中，寄存器名不须要加前缀。例如：

AT&T 格式 Intel 格式

pushl %eax push eax
在 AT&T 汇编格式中，用 '$' 前缀表示一个当即操做数；而在 Intel 汇编格式中，当即数的表示不用带任何前缀。例如：

AT&T 格式 Intel 格式

pushl $1 push 1
AT&T 和 Intel 格式中的源操做数和目标操做数的位置正好相反。在 Intel 汇编格式中，目标操做数在源操做数的左边；而在 AT&T 汇编格式中，目标操做数在源操做数的右边。例如：

AT&T 格式 Intel 格式

addl $1, %eax add eax, 1
在 AT&T 汇编格式中，操做数的字长由操做符的最后一个字母决定，后缀'b'、'w'、'l'分别表示操做数为字节（byte，8 比特）、字（word，16 比特）和长字（long，32比特）；而在 Intel 汇编格式中，操做数的字长是用 "byte ptr" 和 "word ptr" 等前缀来表示的。例如：

AT&T 格式 Intel 格式

movb val, %al mov al, byte ptr val
在 AT&T 汇编格式中，绝对转移和调用指令（jump/call）的操做数前要加上'*'做为前缀，而在 Intel 格式中则不须要。

远程转移指令和远程子调用指令的操做码，在 AT&T 汇编格式中为 "ljump" 和 "lcall"，而在 Intel 汇编格式中则为 "jmp far" 和 "call far"，即：

AT&T 格式	Intel 格式
ljump $section, $offset	jmp far section:offset
lcall $section, $offset	call far section:offset

与之相应的远程返回指令则为：

AT&T 格式	Intel 格式
lret $stack_adjust	ret far stack_adjust

在 AT&T 汇编格式中，内存操做数的寻址方式是

section:disp(base, index, scale)

而在 Intel 汇编格式中，内存操做数的寻址方式为：

section:[base + index*scale + disp]

因为 Linux 工做在保护模式下，用的是 32 位线性地址，因此在计算地址时不用考虑段基址和偏移量，而是采用以下的地址计算方法：

disp + base + index * scale

下面是一些内存操做数的例子：

AT&T 格式	Intel 格式
movl -4(%ebp), %eax	mov eax, [ebp - 4]
movl array(, %eax, 4), %eax	mov eax, [eax*4 + array]
movw array(%ebx, %eax, 4), %cx	mov cx, [ebx + 4*eax + array]
movb $4, %fs:(%eax)	mov fs:eax, 4

回页首

3、Hello World!

真不知道打破这个传统会带来什么样的后果，但既然全部程序设计语言的第一个例子都是在屏幕上打印一个字符串 "Hello World!"，那咱们也以这种方式来开始介绍 Linux 下的汇编语言程序设计。

在 Linux 操做系统中，你有不少办法能够实如今屏幕上显示一个字符串，但最简洁的方式是使用 Linux 内核提供的系统调用。使用这种方法最大的好处是能够直接和操做系统的内核进行通信，不须要连接诸如 libc 这样的函数库，也不须要使用 ELF 解释器，于是代码尺寸小且执行速度快。

Linux 是一个运行在保护模式下的 32 位操做系统，采用 flat memory 模式，目前最经常使用到的是 ELF 格式的二进制代码。一个 ELF 格式的可执行程序一般划分为以下几个部分：.text、.data 和 .bss，其中 .text 是只读的代码区，.data 是可读可写的数据区，而 .bss 则是可读可写且没有初始化的数据区。代码区和数据区在 ELF 中统称为 section，根据实际须要你可使用其它标准的 section，也能够添加自定义 section，但一个 ELF 可执行程序至少应该有一个 .text 部分。下面给出咱们的第一个汇编程序，用的是 AT&T 汇编语言格式：

例1. AT&T 格式

#hello.s 
.data                    # 数据段声明
        msg : .string "Hello, world!\\n" # 要输出的字符串
        len = . - msg                   # 字串长度
.text                    # 代码段声明
.global _start           # 指定入口函数
        
_start:                  # 在屏幕上显示一个字符串
        movl $len, %edx  # 参数三：字符串长度
        movl $msg, %ecx  # 参数二：要显示的字符串
        movl $1, %ebx    # 参数一：文件描述符(stdout) 
        movl $4, %eax    # 系统调用号(sys_write) 
        int  $0x80       # 调用内核功能
        
                         # 退出程序
        movl $0,%ebx     # 参数一：退出代码
        movl $1,%eax     # 系统调用号(sys_exit) 
        int  $0x80       # 调用内核功能

初次接触到 AT&T 格式的汇编代码时，不少程序员都认为太晦涩难懂了，没有关系，在 Linux 平台上你一样可使用 Intel 格式来编写汇编程序：

例2. Intel 格式

; hello.asm 
section .data            ; 数据段声明
        msg db "Hello, world!", 0xA     ; 要输出的字符串
        len equ $ - msg                 ; 字串长度
section .text            ; 代码段声明
global _start            ; 指定入口函数
_start:                  ; 在屏幕上显示一个字符串
        mov edx, len     ; 参数三：字符串长度
        mov ecx, msg     ; 参数二：要显示的字符串
        mov ebx, 1       ; 参数一：文件描述符(stdout) 
        mov eax, 4       ; 系统调用号(sys_write) 
        int 0x80         ; 调用内核功能
                         ; 退出程序
        mov ebx, 0       ; 参数一：退出代码
        mov eax, 1       ; 系统调用号(sys_exit) 
        int 0x80         ; 调用内核功能

上面两个汇编程序采用的语法虽然彻底不一样，但功能却都是调用 Linux 内核提供的 sys_write 来显示一个字符串，而后再调用 sys_exit 退出程序。在 Linux 内核源文件 include/asm-i386/unistd.h 中，能够找到全部系统调用的定义。

回页首

4、Linux 汇编工具

Linux 平台下的汇编工具虽然种类不少，但同 DOS/Windows 同样，最基本的仍然是汇编器、链接器和调试器。

1.汇编器

汇编器（assembler）的做用是将用汇编语言编写的源程序转换成二进制形式的目标代码。Linux 平台的标准汇编器是 GAS，它是 GCC 所依赖的后台汇编工具，一般包含在 binutils 软件包中。GAS 使用标准的 AT&T 汇编语法，能够用来汇编用 AT&T 格式编写的程序：

[xiaowp@gary  code]$ as -o hello.o hello.s

Linux 平台上另外一个常常用到的汇编器是 NASM，它提供了很好的宏指令功能，并可以支持至关多的目标代码格式，包括 bin、a.out、coff、elf、rdf 等。NASM 采用的是人工编写的语法分析器，于是执行速度要比 GAS 快不少，更重要的是它使用的是 Intel 汇编语法，能够用来编译用 Intel 语法格式编写的汇编程序：

[xiaowp@gary  code]$ nasm -f elf hello.asm

2.连接器

由汇编器产生的目标代码是不能直接在计算机上运行的，它必须通过连接器的处理才能生成可执行代码。连接器一般用来将多个目标代码链接成一个可执行代码，这样能够先将整个程序分红几个模块来单独开发，而后才将它们组合(连接)成一个应用程序。 Linux 使用 ld 做为标准的连接程序，它一样也包含在 binutils 软件包中。汇编程序在成功经过 GAS 或 NASM 的编译并生成目标代码后，就可使用 ld 将其连接成可执行程序了：

[xiaowp@gary  code]$ ld -s -o hello hello.o

3.调试器

有人说程序不是编出来而是调出来的，足见调试在软件开发中的重要做用，在用汇编语言编写程序时尤为如此。Linux 下调试汇编代码既能够用 GDB、DDD 这类通用的调试器，也可使用专门用来调试汇编代码的 ALD(Assembly Language Debugger)。

从调试的角度来看，使用 GAS 的好处是能够在生成的目标代码中包含符号表(symbol table)，这样就可使用 GDB 和 DDD 来进行源码级的调试了。要在生成的可执行程序中包含符号表，能够采用下面的方式进行编译和连接：

[xiaowp@gary  code]$ as --gstabs -o hello.o hello.s
[xiaowp@gary  code]$ ld -o hello hello.o

执行 as 命令时带上参数 --gstabs 能够告诉汇编器在生成的目标代码中加上符号表，同时须要注意的是，在用 ld 命令进行连接时不要加上 -s 参数，不然目标代码中的符号表在连接时将被删去。

在 GDB 和 DDD 中调试汇编代码和调试 C 语言代码是同样的，你能够经过设置断点来中断程序的运行，查看变量和寄存器的当前值，并能够对代码进行单步跟踪。图1 是在 DDD 中调试汇编代码时的情景：

图1 用 DDD 中调试汇编程序

汇编程序员一般面对的都是一些比较苛刻的软硬件环境，短小精悍的ALD可能更能符合实际的须要，所以下面主要介绍一下如何用ALD来调试汇编程序。首先在命令行方式下执行ald命令来启动调试器，该命令的参数是将要被调试的可执行程序：

[xiaowp@gary  doc]$ ald hello
Assembly Language Debugger 0.1.3
Copyright (C) 2000-2002 Patrick Alken
hello: ELF Intel 80386 (32 bit), LSB, Executable, Version 1 (current)
Loading debugging symbols...(15 symbols loaded)
ald>

当 ALD 的提示符出现以后，用 disassemble 命令对代码段进行反汇编：

ald> disassemble -s .text
Disassembling section .text (0x08048074 - 0x08048096)
08048074  BA0F000000                 mov edx, 0xf
08048079  B998900408                 mov ecx, 0x8049098
0804807E  BB01000000                 mov ebx, 0x1
08048083  B804000000                 mov eax, 0x4
08048088  CD80                       int 0x80
0804808A  BB00000000                 mov ebx, 0x0
0804808F  B801000000                 mov eax, 0x1
08048094  CD80                       int 0x80

上述输出信息的第一列是指令对应的地址码，利用它能够设置在程序执行时的断点：

ald> break 0x08048088
Breakpoint 1 set for 0x08048088

断点设置好后，使用 run 命令开始执行程序。ALD 在遇到断点时将自动暂停程序的运行，同时会显示全部寄存器的当前值：

ald> run
Starting program: hello
Breakpoint 1 encountered at 0x08048088
eax = 0x00000004 ebx = 0x00000001 ecx = 0x08049098 edx = 0x0000000F
esp = 0xBFFFF6C0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000
ds  = 0x0000002B es  = 0x0000002B fs  = 0x00000000 gs  = 0x00000000
ss  = 0x0000002B cs  = 0x00000023 eip = 0x08048088 eflags = 0x00000246
Flags: PF ZF IF
08048088  CD80                       int 0x80

若是须要对汇编代码进行单步调试，可使用 next 命令：

ald> next
Hello, world!
eax = 0x0000000F ebx = 0x00000000 ecx = 0x08049098 edx = 0x0000000F
esp = 0xBFFFF6C0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000
ds  = 0x0000002B es  = 0x0000002B fs  = 0x00000000 gs  = 0x00000000
ss  = 0x0000002B cs  = 0x00000023 eip = 0x0804808F eflags = 0x00000346
Flags: PF ZF TF IF
0804808F  B801000000                 mov eax, 0x1

若想得到 ALD 支持的全部调试命令的详细列表，可使用 help 命令：

ald> help
Commands may be abbreviated.
If a blank command is entered, the last command is repeated.
Type `help <command>' for more specific information on <command>.
General commands
attach         clear          continue       detach         disassemble
enter          examine        file           help           load
next           quit           register       run            set
step           unload         window         write
Breakpoint related commands
break          delete         disable        enable         ignore
lbreak         tbreak

5、系统调用

即使是最简单的汇编程序，也不免要用到诸如输入、输出以及退出等操做，而要进行这些操做则须要调用操做系统所提供的服务，也就是系统调用。除非你的程序只完成加减乘除等数学运算，不然将很难避免使用系统调用，事实上除了系统调用不一样以外，各类操做系统的汇编编程每每都是很相似的。

在 Linux 平台下有两种方式来使用系统调用：利用封装后的 C 库（libc）或者经过汇编直接调用。其中经过汇编语言来直接调用系统调用，是最高效地使用 Linux 内核服务的方法，由于最终生成的程序不须要与任何库进行连接，而是直接和内核通讯。

和 DOS 同样，Linux 下的系统调用也是经过中断（int 0x80）来实现的。在执行 int 80 指令时，寄存器 eax 中存放的是系统调用的功能号，而传给系统调用的参数则必须按顺序放到寄存器 ebx，ecx，edx，esi，edi 中，当系统调用完成以后，返回值能够在寄存器 eax 中得到。

全部的系统调用功能号均可以在文件 /usr/include/bits/syscall.h 中找到，为了便于使用，它们是用 SYS_<name> 这样的宏来定义的，如 SYS_write、SYS_exit 等。例如，常常用到的 write 函数是以下定义的：

ssize_t write(int fd, const void *buf, size_t count);

该函数的功能最终是经过 SYS_write 这一系统调用来实现的。根据上面的约定，参数 fb、buf 和 count 分别存在寄存器 ebx、ecx 和 edx 中，而系统调用号 SYS_write 则放在寄存器 eax 中，当 int 0x80 指令执行完毕后，返回值能够从寄存器 eax 中得到。

或许你已经发现，在进行系统调用时至多只有 5 个寄存器可以用来保存参数，难道全部系统调用的参数个数都不超过 5 吗？固然不是，例如 mmap 函数就有 6 个参数，这些参数最后都须要传递给系统调用 SYS_mmap：

void  *  mmap(void *start, size_t length, int prot , int flags, int fd, off_t offset);

当一个系统调用所需的参数个数大于 5 时，执行int 0x80 指令时仍需将系统调用功能号保存在寄存器 eax 中，所不一样的只是所有参数应该依次放在一块连续的内存区域里，同时在寄存器 ebx 中保存指向该内存区域的指针。系统调用完成以后，返回值仍将保存在寄存器 eax 中。

因为只是须要一块连续的内存区域来保存系统调用的参数，所以彻底能够像普通的函数调用同样使用栈(stack)来传递系统调用所需的参数。但要注意一点，Linux 采用的是 C 语言的调用模式，这就意味着全部参数必须以相反的顺序进栈，即最后一个参数先入栈，而第一个参数则最后入栈。若是采用栈来传递系统调用所需的参数，在执行int 0x80 指令时还应该将栈指针的当前值复制到寄存器 ebx中。

回页首

6、命令行参数

在 Linux 操做系统中，当一个可执行程序经过命令行启动时，其所需的参数将被保存到栈中：首先是 argc，而后是指向各个命令行参数的指针数组 argv，最后是指向环境变量的指针数据 envp。在编写汇编语言程序时，不少时候须要对这些参数进行处理，下面的代码示范了如何在汇编代码中进行命令行参数的处理：

例3. 处理命令行参数

# args.s
.text
.globl _start
        
_start:
        popl %ecx  # argc
vnext:
        popl %ecx  # argv
        test  %ecx, %ecx      # 空指针代表结束
        jz exit
        movl %ecx, %ebx
        xorl %edx, %edx
strlen:
        movb (%ebx), %al
        inc %edx
        inc %ebx
        test %al, %al
        jnz strlen
        movb $10, -1(%ebx)
        movl $4, %eax        # 系统调用号(sys_write) 
        movl $1, %ebx        # 文件描述符(stdout) 
        int $0x80
        jmp vnext
exit:
        movl $1,%eax         # 系统调用号(sys_exit) 
        xorl %ebx, %ebx      # 退出代码
        int  $0x80
  
        ret

回页首

7、GCC 内联汇编

用汇编编写的程序虽然运行速度快，但开发速度很是慢，效率也很低。若是只是想对关键代码段进行优化，或许更好的办法是将汇编指令嵌入到 C 语言程序中，从而充分利用高级语言和汇编语言各自的特色。但通常来说，在 C 代码中嵌入汇编语句要比"纯粹"的汇编语言代码复杂得多，由于须要解决如何分配寄存器，以及如何与C代码中的变量相结合等问题。

GCC 提供了很好的内联汇编支持，最基本的格式是：

__asm__("asm statements");

例如：

__asm__("nop");

若是须要同时执行多条汇编语句，则应该用"\\n\\t"将各个语句分隔开，例如：

__asm__( "pushl %%eax \\n\\t"
         "movl $0, %%eax \\n\\t"
         "popl %eax");

一般嵌入到 C 代码中的汇编语句很难作到与其它部分没有任何关系，所以更多时候须要用到完整的内联汇编格式：

__asm__("asm statements" : outputs : inputs : registers-modified);

插入到 C 代码中的汇编语句是以":"分隔的四个部分，其中第一部分就是汇编代码自己，一般称为指令部，其格式和在汇编语言中使用的格式基本相同。指令部分是必须的，而其它部分则能够根据实际状况而省略。

在将汇编语句嵌入到C代码中时，操做数如何与C代码中的变量相结合是个很大的问题。GCC采用以下方法来解决这个问题：程序员提供具体的指令，而对寄存器的使用则只需给出"样板"和约束条件就能够了，具体如何将寄存器与变量结合起来彻底由GCC和GAS来负责。

在GCC内联汇编语句的指令部中，加上前缀'%'的数字(如%0，%1)表示的就是须要使用寄存器的"样板"操做数。指令部中使用了几个样板操做数，就代表有几个变量须要与寄存器相结合，这样GCC和GAS在编译和汇编时会根据后面给定的约束条件进行恰当的处理。因为样板操做数也使用'%'做为前缀，所以在涉及到具体的寄存器时，寄存器名前面应该加上两个'%'，以避免产生混淆。

紧跟在指令部后面的是输出部，是规定输出变量如何与样板操做数进行结合的条件，每一个条件称为一个"约束"，必要时能够包含多个约束，相互之间用逗号分隔开就能够了。每一个输出约束都以'='号开始，而后紧跟一个对操做数类型进行说明的字后，最后是如何与变量相结合的约束。凡是与输出部中说明的操做数相结合的寄存器或操做数自己，在执行完嵌入的汇编代码后均不保留执行以前的内容，这是GCC在调度寄存器时所使用的依据。

输出部后面是输入部，输入约束的格式和输出约束类似，但不带'='号。若是一个输入约束要求使用寄存器，则GCC在预处理时就会为之分配一个寄存器，并插入必要的指令将操做数装入该寄存器。与输入部中说明的操做数结合的寄存器或操做数自己，在执行完嵌入的汇编代码后也不保留执行以前的内容。

有时在进行某些操做时，除了要用到进行数据输入和输出的寄存器外，还要使用多个寄存器来保存中间计算结果，这样就不免会破坏原有寄存器的内容。在GCC内联汇编格式中的最后一个部分中，能够对将产生反作用的寄存器进行说明，以便GCC可以采用相应的措施。

下面是一个内联汇编的简单例子：

例4.内联汇编

/* inline.c */
int main()
{
    int a = 10, b = 0;
    __asm__ __volatile__("movl %1, %%eax;\\n\\r"
                         "movl %%eax, %0;"
                         :"=r"(b)      /* 输出 */    
                         :"r"(a)       /* 输入 */
                         :"%eax");     /* 不受影响的寄存器 */
    
    printf("Result: %d, %d\\n", a, b);
}

上面的程序完成将变量a的值赋予变量b，有几点须要说明：

变量b是输出操做数，经过%0来引用，而变量a是输入操做数，经过%1来引用。
输入操做数和输出操做数都使用r进行约束，表示将变量a和变量b存储在寄存器中。输入约束和输出约束的不一样点在于输出约束多一个约束修饰符'='。
在内联汇编语句中使用寄存器eax时，寄存器名前应该加两个'%'，即%%eax。内联汇编中使用%0、%1等来标识变量，任何只带一个'%'的标识符都当作是操做数，而不是寄存器。
内联汇编语句的最后一个部分告诉GCC它将改变寄存器eax中的值，GCC在处理时不该使用该寄存器来存储任何其它的值。
因为变量b被指定成输出操做数，当内联汇编语句执行完毕后，它所保存的值将被更新。

在内联汇编中用到的操做数从输出部的第一个约束开始编号，序号从0开始，每一个约束记数一次，指令部要引用这些操做数时，只需在序号前加上'%'做为前缀就能够了。须要注意的是，内联汇编语句的指令部在引用一个操做数时老是将其做为32位的长字使用，但实际状况可能须要的是字或字节，所以应该在约束中指明正确的限定符：

限定符	意义
"m"、"v"、"o"	内存单元
"r"	任何寄存器
"q"	寄存器eax、ebx、ecx、edx之一
"i"、"h"	直接操做数
"E"和"F"	浮点数
"g"	任意
"a"、"b"、"c"、"d"	分别表示寄存器eax、ebx、ecx和edx
"S"和"D"	寄存器esi、edi
"I"	常数（0至31）

回页首

8、小结

Linux操做系统是用C语言编写的，汇编只在必要的时候才被人们想到，但它倒是减小代码尺寸和优化代码性能的一种很是重要的手段，特别是在与硬件直接交互的时候，汇编能够说是最佳的选择。Linux提供了很是优秀的工具来支持汇编程序的开发，使用GCC的内联汇编可以充分地发挥C语言和汇编语言各自的优势。

linux下的汇编学习体会

From：http://apps.hi.baidu.com/share/detail/16002968

Linux下的汇编程序学习体会（1）

1、为何学习linux下的汇编

Linux的应用领域愈来愈普遍，特别是在嵌入式领域有着得天独厚的优点。涉及到硬件相关的开发天然少不了汇编语言。

大学里学习的汇编都是16位的，与如今32位芯片有些出入。

并且不少AT/T的汇编格式代码也让咱们感到困惑

Linux内核代码由一些核心部分也是用汇编写的。为了读懂linux内核，须要对汇编有必定的了解。本人正是基于这个目的出发，才学习汇编的。

2、硬件和汇编语言

汇编语言根机器语言是一一对应的；因此，不一样型号的机器有不一样的汇编语言，本文全部的论述都是基于X86的体系结构。

Linux汇编按照语法格式能够分为两种inter格式和AT/T格式。前者跟咱们大学里学习的汇编语言格式相近；后者在linux内核代码中获得了普遍的应用。关于这两种格式的详细描述请参考《linux下的汇编程序学习体会（2）》。Linux下还有一个小工具，intel2gas能够把inter格式转换成AT/T格式。本文所涉及的都是AT/T格式的汇编。

3、开发环境

编辑器

Linux下任何一款文本编辑器，vi, emac, etc. 若是喜欢直接写屏，也没什么不妥（男人就要对本身狠一点）。不过本人仍是钟爱vi.

编译器

推荐as, 没啥可说的，看man page吧。

链接器

固然是老牌劲旅ld, (其实我没用过别的)，用法仍是参考man page.

调试器

能够用gdb, 不过康奈尔大学的好事者Patrick Alken先生独立开发了一个ald。本人就是用ald, 这个软件能够从http://ald.sourceforge.net/ 得到，它的编译须要依赖行编辑器readline, readline能够从http://www.gnu.org/ 上找到。

教材

推荐ProgrammingGroundUp, 浅显易懂实用

4、入门实例

先来个感性的认识，用一个Hello World程序把汇编语言的开发过程完整的走一编。

第一步，编辑程序。

用编辑器编译下列程序保存文件名为hello.s

#hello.s

.data # 数据段声明

msg : .string "Hello, world!" # 要输出的字符串

len = . - msg # 字串长度

.text # 代码段声明

.global _start # 指定入口函数

_start: # 在屏幕上显示一个字符串

movl $len, %edx # 参数三：字符串长度

movl $msg, %ecx # 参数二：要显示的字符串

movl $1, %ebx # 参数一：文件描述符(stdout)

movl $4, %eax # 系统调用号(sys_write)

int $0x80 # 调用内核功能

# 退出程序

movl $0, %ebx # 参数一：退出代码

movl $1, %eax # 系统调用号(sys_exit)

int $0x80 # 调用内核功能

第二步，编译

运行命令as –gstabs –o hello.o hello.s 就获得了二进制目标文件hello.o, 参数—gstabs 的意义是保存符号表，以方便未来的调试。

第三步，链接

运行命令ld –o hello hello.o 就输出了可执行程序hello.

第四步，运行

敲入命令./hello, 就看到了输出。

第五步，调试

这个程序工做正常，实际上无需调试。这里只是介绍调试器的使用方法。运行命令ald hello

就进入了调试状态。

Assembly Language Debugger 0.1.7

Copyright (C) 2000-2004 Patrick Alken

hello: ELF Intel 80386 (32 bit), LSB - little endian, Executable, Version 1 (Current)

Loading debugging symbols...(15 symbols loaded)

ald>

用反汇编命令获得程序的代码段

ald> d -s .text

Disassembling section .text (0x08048074 - 0x08048096)

08048074:<_start> BA0E000000 mov edx, 0xe

08048079 B998900408 mov ecx, 0x8049098

0804807E BB01000000 mov ebx, 0x1

08048083 B804000000 mov eax, 0x4

08048088 CD80 int 0x80

0804808A BB00000000 mov ebx, 0x0

0804808F B801000000 mov eax, 0x1

08048094 CD80 int 0x80

设置断点

ald> b 0x0804807E

Breakpoint 1 set for 0x0804807E

运行程序

ald> r

Starting program: hello

Breakpoint 1 encountered at 0x0804807E

eax = 0x00000000 ebx = 0x00000000 ecx = 0x08049098 edx = 0x0000000E

esp = 0xBFFFFCC0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000

ds = 0x007B es = 0x007B fs = 0x0000 gs = 0x0000

ss = 0x007B cs = 0x0073 eip = 0x0804807E eflags = 0x00200212

Flags: AF IF ID

0804807E BB01000000 mov ebx, 0x1

单步运行到结束

ald> n eax = 0x00000000 ebx = 0x00000001 ecx = 0x08049098 edx = 0x0000000E esp = 0xBFFFFCC0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000 ds = 0x007B es = 0x007B fs = 0x0000 gs = 0x0000 ss = 0x007B cs = 0x0073 eip = 0x08048083 eflags = 0x00200312 Flags: AF TF IF ID 08048083 B804000000 mov eax, 0x4 ald> n eax = 0x00000004 ebx = 0x00000001 ecx = 0x08049098 edx = 0x0000000E esp = 0xBFFFFCC0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000 ds = 0x007B es = 0x007B fs = 0x0000 gs = 0x0000 ss = 0x007B cs = 0x0073 eip = 0x08048088 eflags = 0x00200312 Flags: AF TF IF ID 08048088 CD80 int 0x80 ald> n Hello, world!eax = 0x0000000E ebx = 0x00000000 ecx = 0x08049098 edx = 0x0000000E esp = 0xBFFFFCC0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000 ds = 0x007B es = 0x007B fs = 0x0000 gs = 0x0000 ss = 0x007B cs = 0x0073 eip = 0x0804808F eflags = 0x00200312 Flags: AF TF IF ID 04808F B801000000 mov eax, 0x1

AT&T 格式	Intel 格式
movb val, %al	mov al, byte ptr val