Delphi 的接口机制——接口操做的编译器实现过程(2)

接口对象的内存空间

        假设咱们定义了以下两个接口 IIntfA 和 IIntfB，其中 ProcA 和 ProcB 将实现为静态方法，而 VirtA 和 VirtB 将以虚方法实现：

IIntfA = interface
  procedure ProcA;
  procedure VirtA;
end;

IIntfB = interface
  procedure ProcB;
  procedure VirtB;
end;

       而后咱们定义一个 TMyObject 类，它继承自 TInterfacedObject，并实现 IIntfA 和 IIntfB 两个接口：

TMyObject = class(TInterfacedObject, IIntfA, IIntfB)
  FFieldA: Integer;
  FFieldB: Integer;
  procedure ProcA;
  procedure VirtA; virtual;
  procedure ProcB;
  procedure VirtB; virtual;
end;

       而后咱们执行如下代码：

var
  MyObject: TMyObject;
  MyIntf:  IInterface;
  MyIntfA: IIntfA;
  MyIntfB: IIntfB;
begin
  MyObject := TMyObject.Create;  // 建立 TMyObject 对象
  MyIntf  := MyObject;           // 将接口指向 MyObject 对象
  MyIntfA := MyObject;
  MyIntfB := MyObject;
end;

        以上代码的执行过程当中，编译器实现的内存空间状况图以下所示：

        先看最左边一列。MyObject 是对象指针，指向对象数据空间中的 0 偏移处(虚方法表指针)。能够看到 MyIntf/MyIntfA/MyIntfB 三个接口都实现为指针，这三个指针分别指向 MyObject 对象数据空间中一个 4 bytes 的区域。
       中间一列是对象内存空间。能够看到，与不支持接口的对象相比，TMyObject 的对象内存空间中增长了三个字段：IInterface/IIntfB/IIntfA。这些字段也是指针，指向“接口跳转表”的内存地址。注意 MyIntfA/MyIntfB 的存放顺序与 TMyObject 类声明的顺序相反，为何？
       第三列是类的虚方法表，与通常的类(不支持接口的类)一致。
-----------
接口跳转表
-----------
     “接口跳转表”就是一排函数指针，指向实现当前接口的函数地址，这些函数按接口中声明的顺序排列。如今让咱们来看一看所谓的“接口跳转表”有什么用处。
       咱们知道，一个对象在调用类的成员函数的时候，好比执行 MyObject.ProcA，会隐含传递一个 Self 指针给这个成员函数：MyObject.ProcA(Self)。Self 就是对象数据空间的地址。那么编译器如何知道 Self 指针？原来对象指针 MyObject 指向的地址就是 Self，编译器直接取出 MyObject^ 就能够做为 Self。
       在以接口的方式调用成员函数的时候，好比 MyIntfA.ProcA，这时编译器不知道 MyIntfA 到底指向哪一种类型(class)的对象，没法知道 MyIntfA 与 Self 之间的距离(实际上，在上面的例子中 Delphi 编译器知道 MyIntfA 与 Self 之间的距离，只是为了与 COM 的二进制格式兼容，使其它语言也可以使用接口指针调用接口成员函数，必须使用后期的 Self 指针修正)，编译器直接把 MyIntfA 指向的地址设置为 Self。从上图能够看到，MyIntfA 指向 MyObject 对象空间中 $18 偏移地址。这时的 Self 指针固然是错误的，编译器不能直接调用 TMyObject.ProcA，而是调用 IIntfA 的“接口跳转表”中的 ProcA。“接口跳转表”中的 ProcA 的内容就是对 Self 指针进行修正(Self - $18)，而后再调用 TMyObject.ProcA，这时就是正确调用对象的成员函数了。因为每一个类实现接口的顺序不必定相同，所以对于相同的接口在不一样的类中实现，就有不一样的接口跳转表(固然，可能编辑器可以聪明地检查到一些类的“接口跳转表”偏移量相同，也能够共享使用)。
       上面说的是编译器的实现过程，使用“接口跳转表”真正的缘由是 interface 必须支持 COM 的二进制格式标准。下图是从《〈COM 原理与应用〉学习笔记》中摘录的 COM 二进制规格图：

----------------------------------------
对象内存空间中接口跳转指针的初始化
----------------------------------------
       还有一个问题，那就是对象内存空间中的接口跳转指针是如何初始化的。原来，在TObject.InitInstance 中，用 FillChar 清零对象内存空间后，进行的工做就是初始化对象的接口跳转指针：

function TObject.InitInstance(Instance: Pointer): TObject;
var
  IntfTable: PInterfaceTable;
  ClassPtr: TClass;
  I: Integer;
begin
  FillChar(Instance^, InstanceSize, 0);
  PInteger(Instance)^ := Integer(Self);
  ClassPtr := Self;
  while ClassPtr <> nil do
  begin
    IntfTable := ClassPtr.GetInterfaceTable;
    if IntfTable <> nil then
      for I := 0 to IntfTable.EntryCount-1 do
  with IntfTable.Entries[I] do
  begin
    if VTable <> nil then
      PInteger(@PChar(Instance)[IOffset])^ := Integer(VTable);
  end;
    ClassPtr := ClassPtr.ClassParent;
  end;
  Result := Instance;
end;

----------------------
implements 的实现
----------------------
       Delphi 中可使用 implements 关键字将接口方法委托给另外一个接口或对象来实现。下面以 TMyObject 为基类，考查 implements 的实现方法。

TMyObject = class(TInterfacedObject, IIntfA, IIntfB)
  FFieldA: Integer;
  FFieldB: Integer;
  procedure ProcA;
  procedure VirtA; virtual;
  procedure ProcB;
  procedure VirtB; virtual;
  destructor Destroy; override;
end;

      （1）以接口成员变量实现 implements

TMyObject2 = class(TInterfacedObject, IIntfA)
  FIntfA: IIntfA;
  property IntfA: IIntfA read FIntfA implements IIntfA;
end;

         这时编译器的实现是很是简单的，由于 FIntfA 就是接口指针，这时若是使用接口赋值 MyIntfA := MyObject2 这样的语句调用时，MyIntfA 就直接指向 MyObject2.FIntfA。

      （2）以对象成员变量实现 implements

       以下例，若是一个接口类 TMyObject3 以对象的方式实现 implements (一般应该是这样)，其对象内存空间的排列与TMyObject内存空间状况几乎是同样的：

TMyObject3 = class(TInterfacedObject, IIntfA, IIntfB)
  FMyObject: TMyObject;
  function GetMyObject: TMyObject;
  property MyObject: TMyObject read GetMyObject implements IIntfA, IIntfB;
end;

       不一样的地方在于 TMyObject3 的“接口跳转表”的内容发生了变化。因为 TMyObject3 并无本身实现 IIntfA 和 IIntfB，而是由 FMyObject 对象来实现这两个接口。这时，“接口跳转表”中调用的方法就必须改变为调用 FMyObject 对象的方法。好比下面的代码：

var
  MyObject3: TMyObject3;
  MyIntfA: IIntfA;
begin
  MyObject3:= TMyObject3.Create;
  MyObject3.FMyObject := TMyObject.Create;
  MyIntfA := MyObject3;
  MyIntfA._AddRef;
  MyIntfA.ProcA;
  MyIntfA._Release;
end;

       当执行 MyIntfA._AddRef 语句时，编译器生成的“接口跳转”代码为：

{MyIntfA._AddRef;}
  mov eax,[ebp-$0c]              // eax = MyIntfA^
  push eax                       // MyIntfA^ 设置为 Self
  mov eax,[eax]                  // eax = 接口跳转表地址指针
  call dword ptr [eax+$04]       // 转到接口跳转表

  { “接口跳转段”中的代码 }
  mov eax,[esp+$04]              // [esp+$04] 是接口指针内容 (MyIntfA^)
  add eax,-$14                   // 修正 eax = Self (MyObject2)
  call TMyObject2.GetMyObject
  mov [esp+$04],eax              // 得到 FMyObject 对象，注意 [esp+$04]
  jmp TInterfacedObject._AddRef  // 调用 FMyObject._AddRef

          [esp+$04] 是值得注意的地方。“接口跳转表”中只修正一个参数 Self，其它的调用参数(若是有的话)在执行过程进入“接口跳转表”以前就由编译器设置好了。在这里 _AddRef 是采用 stdcall 调用约定，所以 esp+$04 就是 Self。前面说过，编译器直接把接口指针的内容做为 Self 参数，而后转到“接口跳转表”中对 Self 进行修正，而后才能调用对象方法。上面的汇编代码就是修正 Self 为 FMyObject 并调用 FMyObject 的方法。        能够看到 FMyObject._AddRef 方法增长的是 FMyObject 对象的引用计数，看来 implements 的实现只是简单地把接口传送给对象执行，而要实现 COM 组件聚合，必须使用其它方法。