在Spring Boot项目中使用Spock测试框架

本文首发于我的网站：在Spring Boot项目中使用Spock测试框架

Spock框架是基于Groovy语言的测试框架，Groovy与Java具有良好的互操做性，所以能够在Spring Boot项目中使用该框架写优雅、高效以及DSL化的测试用例。Spock经过@RunWith注解与JUnit框架协同使用，另外，Spock也能够和Mockito(Spring Boot应用的测试——Mockito）一块儿使用。

在这个小节中咱们会利用Spock、Mockito一块儿编写一些测试用例（包括对Controller的测试和对Repository的测试），感觉下Spock的使用。

实战

• 根据Building an Application with Spring Boot这篇文章的描述，spring-boot-maven-plugin这个插件同时也支持在Spring Boot框架中使用Groovy语言。
• 在pom文件中添加Spock框架的依赖

<!-- test -->
<dependency>
   <groupId>org.springframework.boot</groupId>
   <artifactId>spring-boot-starter-test</artifactId>
   <scope>test</scope>
</dependency>
<dependency>
   <groupId>org.spockframework</groupId>
   <artifactId>spock-core</artifactId>
   <scope>test</scope></dependency>
<dependency>
   <groupId>org.spockframework</groupId>
   <artifactId>spock-spring</artifactId>
   <scope>test</scope>
</dependency>复制代码

• 在src/test目录下建立groovy文件夹，在groovy文件夹下建立com/test/bookpub包。
• 在resources目录下添加packt-books.sql文件，内容以下所示：

INSERT INTO author (id, first_name, last_name) VALUES (5, 'Shrikrishna', 'Holla');
INSERT INTO book (isbn, title, author, publisher) VALUES ('978-1-78398-478-7', 'Orchestrating Docker', 5, 1);
INSERT INTO author (id, first_name, last_name) VALUES (6, 'du', 'qi');
INSERT INTO book (isbn, title, author, publisher) VALUES ('978-1-78528-415-1', 'Spring Boot Recipes', 6, 1);复制代码

• 在com/test/bookpub目录下建立SpockBookRepositorySpecification.groovy文件，内容是：

package com.test.bookpubimport com.test.bookpub.domain.Author

import com.test.bookpub.domain.Book
import com.test.bookpub.domain.Publisher
import com.test.bookpub.repository.BookRepository
import com.test.bookpub.repository.PublisherRepository
import org.mockito.Mockito
import org.springframework.beans.factory.annotation.Autowired
import org.springframework.boot.test.SpringApplicationContextLoader
import org.springframework.context.ConfigurableApplicationContext
import org.springframework.jdbc.datasource.init.DatabasePopulatorUtils
import org.springframework.jdbc.datasource.init.ResourceDatabasePopulator
import org.springframework.test.context.ContextConfiguration
import org.springframework.test.context.web.WebAppConfiguration
import org.springframework.test.web.servlet.MockMvc
import org.springframework.test.web.servlet.setup.MockMvcBuilders
import spock.lang.Sharedimport spock.lang.Specification
import javax.sql.DataSourceimport javax.transaction.Transactional

import static org.hamcrest.Matchers.containsString;
import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get;
import static org.springframework.test.web.servlet.result.MockMvcResultMatchers.content;
import static org.springframework.test.web.servlet.result.MockMvcResultMatchers.status;

@WebAppConfiguration
@ContextConfiguration(classes = [BookPubApplication.class,
 TestMockBeansConfig.class],loader = SpringApplicationContextLoader.class)
class SpockBookRepositorySpecification extends Specification {
    @Autowired
    private ConfigurableApplicationContext context;
    @Shared
    boolean sharedSetupDone = false;
    @Autowired
    private DataSource ds;
    @Autowired
    private BookRepository bookRepository;
    @Autowired
    private PublisherRepository publisherRepository;
    @Shared
    private MockMvc mockMvc;

    void setup() {
        if (!sharedSetupDone) {
            mockMvc = MockMvcBuilders.webAppContextSetup(context).build();
            sharedSetupDone = true;
        }
        ResourceDatabasePopulator populator = new 
               ResourceDatabasePopulator(context.getResource("classpath:/packt-books.sql"));
        DatabasePopulatorUtils.execute(populator, ds);
    }

    @Transactional
    def "Test RESTful GET"() {
        when:
        def result = mockMvc.perform(get("/books/${isbn}"));
  
        then:
        result.andExpect(status().isOk()) 
       result.andExpect(content().string(containsString(title)));

       where:
       isbn              | title
      "978-1-78398-478-7"|"Orchestrating Docker"
      "978-1-78528-415-1"|"Spring Boot Recipes"
    }

    @Transactional
    def "Insert another book"() {
      setup:
      def existingBook = bookRepository.findBookByIsbn("978-1-78528-415-1")
      def newBook = new Book("978-1-12345-678-9", "Some Future Book",
              existingBook.getAuthor(), existingBook.getPublisher())

      expect:
      bookRepository.count() == 3

      when:
      def savedBook = bookRepository.save(newBook)

      then:
      bookRepository.count() == 4
      savedBook.id > -1
  }
}复制代码

• 执行测试用例，测试经过
• 接下来试验下Spock如何与mock对象一块儿工做，以前的文章中咱们已经在TestMockBeansConfig类中定义了PublisherRepository的Spring Bean，以下所示，因为@Primary的存在，使得在运行测试用例时Spring Boot优先使用Mockito框架模拟出的实例。

@Configuration
@UsedForTesting
public class TestMockBeansConfig {
    @Bean
    @Primary
    public PublisherRepository createMockPublisherRepository() {
        return Mockito.mock(PublisherRepository.class);
    }
}复制代码

• 在BookController.java中添加getBooksByPublisher接口，代码以下所示：

@Autowired
public PublisherRepository publisherRepository;

@RequestMapping(value = "/publisher/{id}", method = RequestMethod.GET)
public List<Book> getBooksByPublisher(@PathVariable("id") Long id) {
    Publisher publisher = publisherRepository.findOne(id);
    Assert.notNull(publisher);
    return publisher.getBooks();
}复制代码

• 在SpockBookRepositorySpecification.groovy文件中添加对应的测试用例，

def "Test RESTful GET books by publisher"() {
    setup:
    Publisher publisher = new Publisher("Strange Books")
    publisher.setId(999)
    Book book = new Book("978-1-98765-432-1",
            "Mytery Book",
            new Author("Jhon", "Done"),
            publisher)
    publisher.setBooks([book])
    Mockito.when(publisherRepository.count()).
            thenReturn(1L);
    Mockito.when(publisherRepository.findOne(1L)).
            thenReturn(publisher)

    when:
    def result = mockMvc.perform(get("/books/publisher/1"))

    then:
    result.andExpect(status().isOk())
    result.andExpect(content().string(containsString("Strange Books")))

    cleanup:
    Mockito.reset(publisherRepository)
}复制代码

• 运行测试用例，发现能够测试经过，在控制器将对象转换成JSON字符串装入HTTP响应体时，依赖Jackson库执行转换，可能会有循环依赖的问题——在模型关系中，一本书依赖一个出版社，一个出版社有包含多本书，在执行转换时，若是不进行特殊处理，就会循环解析。咱们这里经过@JsonBackReference注解阻止循环依赖。

分析

能够看出，经过Spock框架能够写出优雅而强大的测试代码。

首先看SpockBookRepositorySpecification.groovy文件，该类继承自Specification类，告诉JUnit这个类是测试类。查看Specification类的源码，能够发现它被@RunWith(Sputnik.class)注解修饰，这个注解是链接Spock与JUnit的桥梁。除了引导JUnit，Specification类还提供了不少测试方法和mocking支持。

Note：关于Spock的文档见这里：Spock Framework Reference Documentation

根据《单元测试的艺术》一书中提到的，单元测试包括：准备测试数据、执行待测试方法、判断执行结果三个步骤。Spock经过setup、expect、when和then等标签将这些步骤放在一个测试用例中。

• setup：这个块用于定义变量、准备测试数据、构建mock对象等；
• expect：通常跟在setup块后使用，包含一些assert语句，检查在setup块中准备好的测试环境
• when：在这个块中调用要测试的方法；
• then : 通常跟在when后使用，尽能够包含断言语句、异常检查语句等等，用于检查要测试的方法执行后结果是否符合预期；
• cleanup：用于清除setup块中对环境作的修改，即将当前测试用例中的修改回滚，在这个例子中咱们对publisherRepository对象执行重置操做。

Spock也提供了setup()和cleanup()方法，执行一些给全部测试用例使用的准备和清除动做，例如在这个例子中咱们使用setup方法：（1）mock出web运行环境，能够接受http请求；（2）加载packt-books.sql文件，导入预约义的测试数据。web环境只须要Mock一次，所以使用sharedSetupDone这个标志来控制。

经过@Transactional注解能够实现事务操做，若是某个方法被该注解修饰，则与之相关的setup()方法、cleanup()方法都被定义在一个事务内执行操做：要么所有成功、要么回滚到初始状态。咱们依靠这个方法保证数据库的整洁，也避免了每次输入相同的数据。

Spring Boot 1.x系列

1. Spring Boot的自动配置、Command-line-Runner
2. 了解Spring Boot的自动配置
3. Spring Boot的@PropertySource注解在整合Redis中的使用
4. Spring Boot项目中如何定制HTTP消息转换器
5. Spring Boot整合Mongodb提供Restful接口
6. Spring中bean的scope
7. Spring Boot项目中使用事件派发器模式
8. Spring Boot提供RESTful接口时的错误处理实践
9. Spring Boot实战之定制本身的starter
10. Spring Boot项目如何同时支持HTTP和HTTPS协议
11. 自定义的Spring Boot starter如何设置自动配置注解
12. Spring Boot项目中使用Mockito

***本号专一于后端技术、JVM问题排查和优化、Java面试题、我的成长和自我管理等主题，为读者提供一线开发者的工做和成长经验，期待你能在这里有所收获。