SQL Server 进制转换函数

1、背景

　　前段时间群里的朋友问了一个问题：“在查询时增长一个递增序列，如：0x00000001，即每个都是36进位(0—9，A--Z)，0x0000000Z后面将是0x00000010，生成一个像下面的映射表“：

（Figure1：效果图）

 

2、十进制转换为十六进制

在网上有不少资料关于使用SQL语句把十进制转换为十六进制的资料，好比：

--方式1
SELECT CONVERT(VARBINARY(50), 23785)

　　执行返回值为0x00005CE9，可是须要注意的是，这本应该返回二进制的，可是二进制估计是阅读起来太麻烦，因此SQL Server 返回了十六进制，若是你想要保存为字符串并非简单把这直接使用CONVERT，相似下面的SQL是不会有返回值的：

SELECT CONVERT(VARCHAR,CONVERT(VARBINARY(50), 23785))

因此网上出现了以下的函数来转换为十六进制的字符串：

--方式2
CREATE FUNCTION Binary2HexStr(@bin VARBINARY(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    DECLARE @re VARCHAR(8000),@i INT
    SELECT @re='',@i=datalength(@bin)
    WHILE @i>0
        SELECT @re=substring('0123456789ABCDEF',substring(@bin,@i,1)/16+1,1)
                +substring('0123456789ABCDEF',substring(@bin,@i,1)%16+1,1)
                +@re
            ,@i=@i-1
    RETURN('0x'+@re)
END
GO

--测试
SELECT dbo.Binary2HexStr(23785)

　　上面的SQL一样返回0x00005CE9，可是此次返回的是字符串了，貌似问题都得以解决了，可是，只要你INT值不超过2147483648，这个问题就会出现了，执行下面的SQL返回的结果如Figure2所示：

SELECT dbo.Binary2HexStr(2147483647)
SELECT dbo.Binary2HexStr(2147483648)

（Figure2：数据对比）

从进制的转换运算出发，改进了宋沄剑写了的SQL脚本，修改参数为BIGINT类型：

--方式3
CREATE FUNCTION BigInt2HexStr(@value BIGINT)
RETURNS VARCHAR(50)
AS
BEGIN
    DECLARE @seq CHAR(16)
    DECLARE @result VARCHAR(50)
    DECLARE @digit CHAR(1)
    
    SET @seq = '0123456789ABCDEF'
    --求十进制的@value除以的余数,找到余数对应十六进制的值
    SET @result = SUBSTRING(@seq, (@value%16)+1, 1)

    WHILE @value > 0
    BEGIN
        SET @digit = SUBSTRING(@seq, ((@value/16)%16)+1, 1)
        SET @value = @value/16
        IF @value <> 0
            SET @result = @digit + @result
    END

    RETURN @result
END
GO

--测试
SELECT dbo.BigInt2HexStr(2147483647)
SELECT dbo.BigInt2HexStr(2147483648)

执行上面的SQL，返回的十六进制如Figure3所示：

（Figure3：数据对比）

　　要想理解上面的函数，你须要理解十进制转换为十六进制的运算规则，假如十进制数23785转为十六进制，计算的公式的步骤为：

1. 23785/16=1486余9，十进制的9对应十六进制的9；
2. 1486/16=92余14，十进制的14对应十六进制的E；
3. 92/16=5余12，十进制的12对应十六进制的C；
4. 5/16=0余5，十进制的5对应十六进制的5；

将余数对应的十六进制倒写，即5CE9，因此十进制23785 = 十六进制0x5CE9

 

3、十进制转换为三十六进制

　　经过上面的例子修改下就能支持十进制到三十六进制的转换了：

--十进制转换为十六进制
CREATE FUNCTION BigIntTo36HexStr(@value BIGINT)
RETURNS VARCHAR(50)
AS
BEGIN
    DECLARE @seq CHAR(36)
    DECLARE @result VARCHAR(50)
    DECLARE @digit CHAR(1)
    
    SET @seq = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
    SET @result = SUBSTRING(@seq, (@value%36)+1, 1)

    WHILE @value > 0
    BEGIN
        SET @digit = SUBSTRING(@seq, ((@value/36)%36)+1, 1)
        SET @value = @value/36
        IF @value <> 0 
            SET @result = @digit + @result
    END 

    RETURN @result
END
GO

--测试
SELECT dbo.BigIntTo36HexStr(35)

执行上面的测试SQL，返回0xZ，测试成功；

 

4、补充说明

　　其实编写Binary2HexStr函数是没有必要的，由于SQL Server提供系统的函数支持转换master.dbo.fn_varbintohexstr或者master.dbo.fn_varbintohexsubstring，例如：

SELECT master.dbo.fn_varbintohexstr(2147483647)
SELECT master.dbo.fn_varbintohexsubstring(1,2147483647,1,0)

不过他们同样存在对十进制数据的转换不能超过2147483648的限制。

 

5、参考文献

SqlServer中varbinary转换成字符串

关于递增序列的问题

进制转换

SQL之36进制转换成10进制数据

SQL Server 中，实现 varbinary 与 varchar 类型之间的数据转换

SQL Server: convert varbinary to varchar