Oracle游标解析

本节对Oracle中的游标进行详细讲解。

本节所举实例来源Oracle中scott用户下的emp表dept表：

1、游标：

一、概念：

游标的本质是一个结果集resultset，主要用来临时存储从数据库中提取出来的数据块。

2、游标的分类：

一、显式游标：由用户定义，须要的操做：定义游标、打开游标、提取数据、关闭游标，主要用于对查询语句的处理。

属性：%FOUND        %NOTFOUND        %ISOPEN          %ROWCOUNT

Example:打印emp表的员工信息

DECLARE
  CURSOR emp_cursor IS SELECT empno,ename,job FROM emp;
  v_empno emp.empno%TYPE;
  v_name emp.ename%TYPE;
  v_job emp.job%TYPE;
BEGIN
  OPEN emp_cursor;
  LOOP
    FETCH emp_cursor INTO v_empno,v_name,v_job;
    DBMS_OUTPUT.PUT_LINE('员工号为:'||v_empno||'姓名是'||v_name||'职位：'||v_job);
    EXIT WHEN emp_cursor%NOTFOUND;
  END LOOP;
  CLOSE emp_cursor;
END; 

这里严格按照显示游标的书写规则：DECLARE emp_cursor定义游标OPEN emp_cursor打开游标FETCH emp_cursor INTO...提取数据CLOSE emp_cursor关闭游标,由于提取出来的数据属于多行，因此经过loop循环打印便可。

Example2:检验游标是否打开,若是打开显示提取行数

DECLARE
  CURSOR emp_cursor IS SELECT empno,ename,job FROM emp;
  v_empno emp.empno%TYPE;
  v_name emp.ename%TYPE;
  v_job emp.job%TYPE;
BEGIN
  OPEN emp_cursor;
  LOOP
       FETCH emp_cursor INTO v_empno,v_name,v_job;
       EXIT WHEN emp_cursor%NOTFOUND;
  END LOOP;
  IF emp_cursor%ISOPEN THEN
    DBMS_OUTPUT.PUT_LINE('游标已打开');
    DBMS_OUTPUT.PUT_LINE('读取了'||emp_cursor%ROWCOUNT||'行');
  ELSE
    DBMS_OUTPUT.PUT_LINE('游标没有打开');
  END IF;  
  CLOSE emp_cursor;
END;

经过%ISOPEN属性判断游标是否打开，%ROWCOUNT判断获取行数。

二、隐式游标：由系统定义并为它建立工做区域，而且隐式的定义打开提取关闭，隐式游标的游标名就是'SQL',属性和显示游标相同，主要用于对单行select语句或dml操做进行处理。

Example:又用户输入员工号修改员工工资如成功则打印输出成功标志。

为了尽可能不改变原表，建立新表emp_new和原表数据相同：

CREATE TABLE emp_new
AS
SELECT * FROM emp;

BEGIN
  UPDATE emp_new SET sal = sal+500 WHERE empno=&empno;
  IF SQL%FOUND THEN
    DBMS_OUTPUT.PUT_LINE('成功修改');
    COMMIT;
  ELSE
    DBMS_OUTPUT.PUT_LINE('修改失败');
    ROLLBACK;
  END IF;
END;

这里注意增删改之后要对作的操做进行commit提交，若是操做失败则rollback回滚刚才的操做。

三、参数游标：

在定义游标时加入参数的游标，能够配合游标for循环快速找到须要的数据。这里先讲一下游标for循环

A、游标FOR循环：

隐含的执行了打开提取关闭数据，代码精简不少。Expression:

FOR table_record IN table_cursor LOOP

　　STATEMENT;

END LOOP;

 Example:使用游标For循环打印输出员工信息：

DECLARE
CURSOR emp_cursor IS SELECT empno,ename,job FROM emp;
BEGIN
  FOR emp_record IN emp_cursor LOOP
    DBMS_OUTPUT.PUT_LINE('员工号：'||emp_record.empno||'员工姓名'||emp_record.ename||'员工职位'||emp_record.job);
  END LOOP;
END;

这里游标FOR循环省去了对于取到的数据的变量的命名和赋值，同时若是所有打印则不用写循环条件，代码精简了不少。

若是想让代码更加精简，则能够去掉对游标的声明引入子查询便可，操做以下。

BEGIN
  FOR emp_record IN (SELECT empno,ename,job FROM emp) LOOP
    DBMS_OUTPUT.PUT_LINE('员工号：'||emp_record.empno||'员工姓名'||emp_record.ename||'员工职位'||emp_record.job);
  END LOOP;
END;

代码更加精简，获得的结果相同。和隐式游标是否是有点像，但隐式游标主要用于的是单行select和dml语句的操做，注意2者用法的区别。

下面继续参数游标的实例：

Example：输入部门号打印员工信息：

DECLARE
CURSOR emp_cursor(dno NUMBER)IS SELECT empno,ename,job FROM emp WHERE deptno=dno;
BEGIN
  FOR emp_record IN emp_cursor(&dno) LOOP
    DBMS_OUTPUT.PUT_LINE('员工号'||emp_record.empno||'姓名'||emp_record.ename||'职位'||emp_record.job);
  END LOOP;
END;

 

 

这里既然有参数，那么必然会有对游标的声明，在结合游标FOR循环快速超找所须要的数据。

3、使用游标修改数据的注意事项

一、使用游标修改数据时，为防止他人在本身操做数据时对数据进行修改，oracle提供for update子句进行加锁。

同时在你使用update或delete时，必须使用where current of+name_cursor语句，以及在最后记得提交。若是

是级联操做则可使用for update of 来进行相关表的加锁。

Example1：对职位是PRESIDENT的员工加1000工资，MANAGER的人加500工资

CREATE TABLE emp_new
AS
SELECT * FROM emp;

DECLARE
CURSOR empnew_cursor IS SELECT ename,job FROM emp_new FOR UPDATE;
BEGIN
  FOR empnew_record IN empnew_cursor LOOP
    DBMS_OUTPUT.PUT_LINE('姓名'||empnew_record.ename||'职位'||empnew_record.job);
    IF empnew_record.job='PRESIDENT' THEN
      UPDATE emp_new SET sal=sal+1000 WHERE CURRENT OF empnew_cursor;
    ELSIF empnew_record.job='MANAGER' THEN
      UPDATE emp_new SET sal=sal+500 WHERE CURRENT OF empnew_cursor;
    END IF;
  END LOOP;
  COMMIT;
END;

SELECT * FROM EMP WHERE job in('PRESIDENT','MANAGER');
SELECT * FROM EMP_NEW WHERE job in('PRESIDENT','MANAGER');

能够看到这里工资有了相应的变化。

 

 

至此，Oracle游标解析完毕，总而言之，游标只是做为咱们从数据库中提取出来的一部分数据，咱们针对这个结果集作一系列的操做。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　2018-09-07    16:15:34