Windows下MySQL自动备份的batch脚本

   在Unix系统环境中能够经过各类Unix shell结合cron任务实现对MySQL的自动备份，那在Windows下要如何实现呢，其实很简单只要写好自定义的batch脚本在结合taskschd.msc（任务计划程序），就能够实现，最近须要修改调优Windows环境下的MySQL就顺便写了一个使用mysqldump作逻辑备份的batch脚本，以下：

@echo off
::mysql_backup.bat
set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set now=%Date:~0,4%%Date:~5,2%%Date:~8,2%%hour%%Time:~3,2%%Time:~6,2%
::主机ip
set host=127.0.0.1
::端口
set port=3306
::用户
set username=root
::密码
set password=youpassword
::要备份数据库的名字，若是有多个库请用空格分隔
set databasename=database1 database2
:: MySQL Bin 目录
:: 若是在安装配置时添加 MySQL Bin 目录到了环境变量(PATH) ，此处能够留空
set MYSQL=D:\mysql-5.5.57-winx64\bin\
::配置SQL备份路径
set DIR=D:\backup\db\
:: 建立备份MySQL的备份目录
if not exist %DIR% (
    mkdir %DIR% 2>nul
)

if not exist %DIR% (
    echo Backup path: %DIR% not exists, create dir failed.
    goto exit
)

echo start mysqldump ...

for %%i in (%databasename%) do (
    %MYSQL%mysqldump -h%host% -P%port% -u%username% -p%password% %%i > %DIR%%%i-%now%.sql 2>nul
)

echo end mysqldump
::记录主库状态，且作日志记录
%MYSQL%mysql -h%host% -P%port% -u%username% -p%password% -Bse "select now();show master status\G" > %DIR%MySQL_status-%now%.log
echo delete files before 60 days
::删除60天前的备份
forfiles /p "D:\backup\db" /m *.* /d -60 /c "cmd /c del @file /f"

:exit

在写好batch脚本后最后再在taskschd.msc中添加天天定时触发执行，具体的配置方法以下：

这里须要注意的是，这里必定要勾选上使用最高权限运行，以避免形成运行失败

这里触发条件选择天天一次，具体时间能够视实际生产环境判断，开始任务则为按预约计划

在这里填上batch脚本的路径以及初始目录，其中须要注意的是必定须要配置初始目录，否则没有把batch脚本添加入PATH环境变量中该任务会找不到batch脚本从而执行失败

条件这里能够根据实际状况选择

这里必定须要勾选 容许按需运行任务，其余的时间就实际状况而定，最后在确认保存后输入用户密码这样天天系统就会自动作mysqldump逻辑备份。