Drools规则引擎-若是判断某个对象中的集合是否包含指定的值

规则引擎集合相关处理

在实际生产过程当中，有不少关于集合的处理场景，好比一个Fact对象中包含有一个集合，而须要判断该集合是否包含某个值。而Drools规则引擎也提供了多种处理方式，好比经过from、contains、exists等进行操做，比较。

固然也能够经过function函数来作相应的比较，在个在其余章节讲到过，就不在此赘述。下面重点以几个实例才进行讲解，在具体实践中根据具体状况来进行运用。

实例

省略掉基本的配置，直接看调用代码和规则代码。

测试调用代码：

public class ContainsDemo extends BaseDemo {

    public static void main(String[] args) {

        KieSession kieSession = getKieSession("containsVar");

        Corporation corporation = new Corporation();
        Set<Scope> scopes = new HashSet<>();
        scopes.add(new Scope("P2P"));
        scopes.add(new Scope("金融"));
        scopes.add(new Scope("区块链"));
        corporation.setScopes(scopes);

        Scope scope = new Scope("区块链");

        kieSession.insert(corporation);
        kieSession.insert(scope);

        kieSession.fireAllRules();

    }
}

相关实体类：

@Data
public class Corporation {

    private Set<Scope> scopes;

}

@Data
public class Scope {


    public Scope(String scope){
        this.scope = scope;
    }

    private String scope;

}

而后看一下规则处理：

package com.containsVar

import com.secbro2.drools.entity.Corporation
import com.secbro2.drools.entity.Scope
import java.util.List

rule "containsVar1"

when

    $c: Corporation($scopes:scopes);
    $s: Scope(scope == "P2P") from $scopes;

then

    System.out.println("containsVar1行业类型为：P2P");
end

rule "containsVar2"

when

    $c: Corporation($scopes:scopes);
    exists (Scope(scope == "P2P") from $scopes);
then

    System.out.println("containsVar2行业类型为：P2P");

end


rule "containsVar3"

when
    $s: Scope(scope == "区块链")
    $c: Corporation(scopes contains $s);
then

    System.out.println("containsVar3行业类型为：区块链");

end

rule "containsVar4"

when
    $s: Scope(scope == "区块链")
    exists (Corporation(scopes contains $s));
then

    System.out.println("containsVar4行业类型为：区块链");

end

在上述实例中列举了4中使用方法：

• 第一种，首先获取Fact对象Corporation，并从新定义了它的属性$scopes。而后，经过from关键字来遍历$scopes中的值，得到符合条件的。此时并不须要传入Scope对应的fact对象。
• 第二种，前半部分同第一种方式，是不过没有获取筛选的结果，直接用exists来判断是否存在。
• 第三种，先得到知足条件的Scope的Fact对象，而后再利用此fact对Corporation的fact对象进行筛选，只有知足条件才能够继续。
• 第四种，与第三种效果相同，原理同第二种方式的exists使用。

相关技术视频

CSDN学院：《Drools7规则引擎进阶教程》

CSDN学院：《Drools7规则引擎入门教程》

CSDN学院：《Drools7系列优惠套餐》

原文连接：http://www.choupangxia.com/20...